AppleScript: Jak otworzyć plik w TextEdit, bez wysuwania innych okien TextEdit na wierzch?

Mam następujący kod AppleScript, który otwiera określony plik w TextEdit w oknie z określonymi granicami:

set targetFilepath to "/Users/Me/Desktop/My Fruit Log.txt"
tell application "TextEdit"
    activate
    open targetFilepath
    set bounds of front window to {279, 111, 1180, 719}
end tell

Problem z tym kodem polega na tym, że jeśli mam otwarte inne pliki TextEdit, kod przeniesie również inne dokumenty na pierwszy plan. Chciałbym jednak, aby tylko ten jeden, konkretny plik tekstowy został przeniesiony na pierwszy plan.

Kod nie spowoduje przeniesienia zminimalizowanego okna TextEdit na przód, ale przeniesie wszystkie ukryte, niezminimalizowane okna TextEdit na przód.

Kiedy usuwam activatewiersz z kodu:

tell application "TextEdit"
    open targetFilepath
    set bounds of front window to {279, 111, 1180, 719}
end tell

plik jest otwarty, ale jego okno nie jest przenoszone na pierwszy plan.

_{OS X El Capitan, wersja 10.11.6.}

Oto wizualna reprezentacja tego, co opisałem powyżej. Miałem zero okien zminimalizowane na moim komputerze, gdy te zrzuty ekranu zostały wykonane.

Tak wygląda mój ekran przed uruchomieniem AppleScript :

Tak chcę, aby mój ekran wyglądał po uruchomieniu AppleScript :

Oto jak obecnie wygląda mój ekran po uruchomieniu AppleScript :

W celu pełnego ujawnienia mój kod przesuwa także położenie kursora TextEdit po otwarciu pliku. Nie wiem, czy wpłynęłoby to na potencjalne rozwiązanie, ale oto dodatkowy kod, który następuje po powyższym fragmencie ( xjest liczbą całkowitą, która jest wcześniej przypisywana):

tell application "TextEdit" to activate
    tell application "System Events" to tell process "TextEdit"
        repeat x times
            key code 125
        end repeat
    end tell
end tell

Myślę, że masz problem z tym, że źle zrozumiałeś, co się właściwie dzieje. Pozwól mi spróbować wyjaśnić ...

Pierwsze pytanie, na które należy odpowiedzieć, to dlaczego okna nie były widoczne na pierwszym zrzucie ekranu? Oczywiście plik My Fruit Log.txt nie był widoczny, ponieważ nie był jeszcze otwarty (tzn. Skrypt jeszcze się nie uruchomił). Ale co z innymi oknami? Istnieją tylko trzy możliwości:

1. TextEdit tak naprawdę nie działał (dlatego nie ma okien). To byłoby oczywiste - więc nie potrzeba więcej dyskusji.
2. TextEdit działał, ale był ukryty (dlatego wszystkie okna są ukryte). Oznacza to po prostu, że ukryłeś TextEdit przed widokiem. Uruchomienie skryptu powoduje, że jest on ponownie widoczny (wraz ze wszystkimi jego oknami, z wyjątkiem tych, które można zminimalizować).
3. TextEdit działał, ale wszystkie okna zostały zminimalizowane. Oznacza to po prostu, że TextEdit jest uruchomiony, ale żadne okna nie są widoczne, ponieważ zostały zminimalizowane. Uruchomienie skryptu powoduje, że sama aplikacja jest ponownie widoczna i na pierwszym planie, ale wszystkie zminimalizowane okna pozostają zminimalizowane.

W twoim scenariuszu jest prawie pewne, że zastosowanie ma Opcja 2. Tak więc, chociaż nie jest to, co chcesz usłyszeć, twój skrypt działa tak, jak powinien w macOS. Jedyny sposób mogę myśleć o chwili obecnej, aby osiągnąć to, co chcesz w sposób praktyczny, jest zapewnienie, że skrypt minimalizuje wszystkie inne okna, z wyjątkiem jednego, że właśnie otwarty. Na przykład można to osiągnąć za pomocą następującego kodu:

set targetFilepath to "/Users/Me/Desktop/My Fruit Log.txt"
tell application "TextEdit"
    activate
    open targetFilepath
    tell (windows whose id is not (get id of front window) and visible is true)
        set miniaturized to true
    end tell
    set bounds of front window to {279, 111, 1180, 719}
end tell

Jak widać, właśnie dodałem dwie linie kodu. Myślę, że są dość zrozumiałe - po prostu mówią TextEdit, aby zminimalizować każde okno, które spełnia te dwa warunki (1. nie jest to okno przednie i 2. jest widoczne).

Mam nadzieję, że to zadziała dla Ciebie - ale jeśli nie, może ktoś wymyśli lepsze rozwiązanie.

Co powiesz na to?

tell application "TextEdit"

    set fWin to front window -- Since you're already using 'front window'
    repeat with w in every window
        set visible of w to false
    end repeat

    -- set visible of window id 189 to true (frontmost on my mac now)
    set visible of fWin to true
    activate
end tell

Jestem pewien, że istnieją inne metody identyfikacji okien. Możesz także zrobić coś takiego… gdzie używana jest lista okien od drugiej do ostatniej.

tell application "TextEdit"
    -- Assuming that front window should be visible…
    set winList to (windows 2 thru -1)
    repeat with w in winList
        set visible of w to false
    end repeat

    activate
end tell

Kluczowym terminem jest tutaj „widoczny”.