Usuń wpisy z tablicy, aby ją posortować i zmaksymalizować sumę elementów

13

Wyzwanie to polega od testu wstępnego na zamknięty kurs bezpieczeństwa cybernetycznego. W każdym razie nie ma to nic wspólnego z cyberbezpieczeństwem, służy jedynie przetestowaniu umiejętności logicznych i kodowania uczniów.

Zadanie

Napisz program, który usuwa wpisy z tablicy, dzięki czemu pozostałe wartości są sortowane w ściśle malejącej kolejności, a ich suma jest zmaksymalizowana spośród wszystkich innych możliwych sekwencji malejących.

Wejście i wyjście

Wejście będzie tablica wartości całkowitych bezwzględnie większy niż 0i wszystkie różnią się między sobą . Możesz wybrać, czy chcesz czytać dane wejściowe z pliku, wiersza poleceń czy standardowego wejścia.

Wyjściowa będzie posortowana malejąca podgrupa wejściowa, której suma jest większa niż jakakolwiek inna możliwa pod-tablica posortowana malejąco.

Uwaga: [5, 4, 3, 2] to subarray z [5, 4, 1, 3, 2], nawet jeśli 4i 3nie sąsiadują. Tylko dlatego, że 1pękło.

Rozwiązanie Bruteforce

Najprostszym rozwiązaniem byłoby oczywiście powtórzenie wszystkich możliwych kombinacji podanej tablicy i poszukiwanie posortowanej z największą sumą, która byłaby w Pythonie :

import itertools

def best_sum_desc_subarray(ary):
    best_sum_so_far = 0
    best_subarray_so_far = []
    for k in range(1, len(ary)):
        for comb in itertools.combinations(ary, k):
            if sum(comb) > best_sum_so_far and all(comb[j] > comb[j+1] for j in range(len(comb)-1)):
                best_subarray_so_far = list(comb)
                best_sum_so_far = sum(comb)
    return best_subarray_so_far

Niestety, ponieważ sprawdzenie czy tablica jest posortowana i obliczenie sumy na jego elementów jest i od tej operacji zostaną wykonane razy do od do , czas asymptotycznej złożoności będzie

Wyzwanie

Twoim celem jest osiągnięcie lepszej złożoności czasu niż brutalna siła powyżej. Rozwiązanie o najmniejszej asymptotycznej złożoności czasu jest zwycięzcą wyzwania. Jeśli dwa rozwiązania mają tę samą asymptotyczną złożoność czasową, zwycięzcą zostanie ten o najmniejszej asymptotycznej złożoności przestrzennej.

Uwaga: Możesz rozważyć czytanie, pisanie i porównywanie atomów nawet na dużych liczbach.

Uwaga: Jeśli istnieją dwa lub więcej rozwiązań, zwróć jedno z nich.

Przypadki testowe

Input:  [200, 100, 400]
Output: [400]

Input:  [4, 3, 2, 1, 5]
Output: [4, 3, 2, 1]

Input:  [50, 40, 30, 20, 10]
Output: [50, 40, 30, 20, 10]

Input:  [389, 207, 155, 300, 299, 170, 158, 65]
Output: [389, 300, 299, 170, 158, 65]

Input:  [19, 20, 2, 18, 13, 14, 8, 9, 4, 6, 16, 1, 15, 12, 3, 7, 17, 5, 10, 11]
Output: [20, 18, 16, 15, 12, 7, 5]

Input:  [14, 12, 24, 21, 6, 10, 19, 1, 5, 8, 17, 7, 9, 15, 23, 20, 25, 11, 13, 4, 3, 22, 18, 2, 16]
Output: [24, 21, 19, 17, 15, 13, 4, 3, 2]

Input:  [25, 15, 3, 6, 24, 30, 23, 7, 1, 10, 16, 29, 12, 13, 22, 8, 17, 14, 20, 11, 9, 18, 28, 21, 26, 27, 4, 2, 19, 5]
Output: [25, 24, 23, 22, 17, 14, 11, 9, 4, 2]
array-manipulation subsequence fastest-algorithm Marco
źródło
Związane z. (Nie mogę teraz sprawdzić, czy oba algorytmy są w rzeczywistości równoważne, ale myślę, że mogą być.)
Martin Ender
Komentarze nie są przeznaczone do rozszerzonej dyskusji; ta rozmowa została przeniesiona do czatu .
Martin Ender

Odpowiedzi:

3

Perl

Powinno to być O (n ^ 2) w czasie i O (n) w przestrzeni

Podaj liczby oddzielone spacją w jednym wierszu do STDIN

#!/usr/bin/perl -a
use strict;
use warnings;

# use Data::Dumper;
use constant {
    INFINITY => 9**9**9,
    DEBUG    => 0,
};

# Recover sequence from the 'how' linked list
sub how {
    my @z;
    for (my $h = shift->{how}; $h; $h = $h->[1]) {
        push @z, $h->[0];
    }
    pop @z;
    return join " ", reverse @z;
}

use constant MINIMUM => {
    how  => [-INFINITY, [INFINITY]],
    sum  => -INFINITY,
    next => undef,
};

# Candidates is a linked list of subsequences under consideration
# A given final element will only appear once in the list of candidates
# in combination with the best sum that can be achieved with that final element
# The list of candidates is reverse sorted by final element
my $candidates = {
    # 'how' will represent the sequence that adds up to the given sum as a
    # reversed lisp style list.
    # so e.g. "1, 5, 8" will be represented as [8, [5, [1, INFINITY]]]
    # So the final element will be at the front of 'how'
    how  => [INFINITY],
    # The highest sum that can be reached with any subsequence with the same
    # final element
    sum  => 0,
    # 'next' points to the next candidate
    next => MINIMUM,   # Dummy terminator to simplify program logic
};

for my $num (@F) {
    # Among the candidates on which an extension with $num is valid
    # find the highest sum
    my $max_sum = MINIMUM;
    my $c = \$candidates;
    while ($num < $$c->{how}[0]) {
        if ($$c->{sum} > $max_sum->{sum}) {
            $max_sum = $$c;
            $c = \$$c->{next};
        } else {
            # Remove pointless candidate
            $$c = $$c->{next};
        }
    }

    my $new_sum = $max_sum->{sum} + $num;
    if ($$c->{how}[0] != $num) {
        # Insert a new candidate with a never before seen end element
        # Due to the unique element rule this branch will always be taken
        $$c = { next => $$c };
    } elsif ($new_sum <= $$c->{sum}) {
        # An already known end element but the sum is no improvement
        next;
    }
    $$c->{sum} = $new_sum;
    $$c->{how} = [$num, $max_sum->{how}];
    # print(Dumper($candidates));
    if (DEBUG) {
        print "Adding $num\n";
        for (my $c = $candidates; $c; $c = $c->{next}) {
            printf "sum(%s) = %s\n", how($c), $c->{sum};
        }
        print "------\n";
    }
}

# Find the sequence with the highest sum among the candidates
my $max_sum = MINIMUM;
for (my $c = $candidates; $c; $c = $c->{next}) {
    $max_sum = $c if $c->{sum} > $max_sum->{sum};
}

# And finally print the result
print how($max_sum), "\n";
Ton Hospel
źródło
3

O(nlog⁡n)O(n)

{-# LANGUAGE MultiParamTypeClasses #-}

import qualified Data.FingerTree as F

data S = S
  { sSum :: Int
  , sArr :: [Int]
  } deriving (Show)

instance Monoid S where
  mempty = S 0 []
  mappend _ s = s

instance F.Measured S S where
  measure = id

bestSubarrays :: [Int] -> F.FingerTree S S
bestSubarrays [] = F.empty
bestSubarrays (x:xs) = left F.>< sNew F.<| right'
  where
    (left, right) = F.split (\s -> sArr s > [x]) (bestSubarrays xs)
    sLeft = F.measure left
    sNew = S (x + sSum sLeft) (x : sArr sLeft)
    right' = F.dropUntil (\s -> sSum s > sSum sNew) right

bestSubarray :: [Int] -> [Int]
bestSubarray = sArr . F.measure . bestSubarrays

Jak to działa

bestSubarrays xsjest sekwencją podnośników, xsktóre znajdują się na efektywnej granicy {największej sumy, najmniejszego pierwszego elementu}, uporządkowanej od lewej do prawej przez zwiększenie sumy i zwiększenie pierwszego elementu.

Aby przejść od bestSubarrays xscelu bestSubarrays (x:xs), my

  1. podziel sekwencję na lewą stronę z pierwszymi elementami mniejszymi niż xi prawą stronę z pierwszymi elementami większymi niż x,
  2. znajdź nową podtablicę, przechodząc xdo skrajnej prawej podtablicy po lewej stronie,
  3. upuść prefiks podrzędnych z prawej strony z mniejszą sumą niż nowa podtablica,
  4. połącz lewą stronę, nową podtablicę i pozostałą część prawej strony.

O(log⁡n)

Anders Kaseorg
źródło
1

Ta odpowiedź rozszerza się na Ton Hospel.

Problem można rozwiązać za pomocą programowania dynamicznego za pomocą recurence

T(i)=ai+max[{0}∪{T(j)|0≤j<i∧ai≤aj}]

gdzie jest sekwencją wejściową, a maksymalnie osiągalną sumą dowolnej malejącej podsekwencji kończącej się indeksem . Rzeczywiste rozwiązanie można następnie odtworzyć za pomocą , jak w poniższym kodzie rdzy.T ( i ) i T(ai)T(i)iT

fn solve(arr: &[usize]) -> Vec<usize> {
    let mut tbl = Vec::new();
    // Compute table with maximum sums of any valid sequence ending
    // with a given index i.
    for i in 0..arr.len() {
        let max = (0..i)
            .filter(|&j| arr[j] >= arr[i])
            .map(|j| tbl[j])
            .max()
            .unwrap_or(0);
        tbl.push(max + arr[i]);
    }
    // Reconstruct an optimal sequence.
    let mut sum = tbl.iter().max().unwrap_or(&0).clone();
    let mut limit = 0;
    let mut result = Vec::new();

    for i in (0..arr.len()).rev() {
        if tbl[i] == sum && arr[i] >= limit {
            limit = arr[i];
            sum -= arr[i];
            result.push(arr[i]);
        }
    }
    assert_eq!(sum, 0);
    result.reverse();
    result
}

fn read_input() -> Vec<usize> {
    use std::io::{Read, stdin};
    let mut s = String::new();
    stdin().read_to_string(&mut s).unwrap();
    s.split(|c: char| !c.is_numeric())
        .filter(|&s| !s.is_empty())
        .map(|s| s.parse().unwrap())
        .collect()
}

fn main() {
    println!("{:?}", solve(&read_input()));
}

Wypróbuj online!

politza
źródło