Jak prawidłowo osiągnąć dynamiczne działanie równoległe za pomocą deklaratywnego potoku?

Obecnie potrzebuję implementacji, która musi znaleźć wszystkie pliki w katalogu i uruchomić równoległe zadanie dla każdego znalezionego pliku.

Czy można to osiągnąć za pomocą deklaratywnych potoków?

pipeline {
    agent any
    stages {
        stage("test") {
            steps {
                dir ("file_path") {
                    // find all files with complete path
                    parallel (
                        // execute parallel tasks for each file found.
                        // this must be dynamic
                        }
                    }
                }
            }
        }
    }
}

Udało się go rozwiązać za pomocą następującego kodu:

pipeline {
    agent { label "master"}
    stages {
        stage('1') {
            steps {
                script {
                    def tests = [:]
                    for (f in findFiles(glob: '**/html/*.html')) {
                        tests["${f}"] = {
                            node {
                                stage("${f}") {
                                    echo '${f}'
                                }
                            }
                        }
                    }
                    parallel tests
                }
            }
        }       
    }
}

Działa to również, jeśli chcesz pozostać w Declarative Pipelineprzestrzeni

// declare our vars outside the pipeline
def tests = [:]
def files

pipeline {
    agent any
    stages {
        stage('1') {
            steps {
                script {
                    // we've declared the variable, now we give it the values
                    files = findFiles(glob: '**/html/*.html')
                    // Loop through them
                    files.each { f ->
                        // add each object from the 'files' loop to the 'tests' array
                        tests[f] = {
                            // we're already in the script{} block, so do our advanced stuff here
                            echo f.toString()
                        }
                    }
                    // Still within the 'Script' block, run the parallel array object
                    parallel tests
                }
            }
        }       
    }
}

Jest to o wiele łatwiejsze do użycia skryptuowych potoków, ponieważ możesz użyć dowolnego Groovy, ale nadal powinieneś być w stanie to zrobić z deklaratywnymi potokami za pomocą tego findFileskroku.

Należy pamiętać, że kroki kompilacji dynamicznej mogą powodować pewne problemy na niektórych etapach kompilacji, np. Podczas wywoływania innego zadania:

pipeline {
    stages {
        stage('Test') {
            steps {
                script {
                    def tests = [:]
                    for (f in findFiles(glob: '**/html/*.html')) {
                        // Create temp variable, otherwise the name will be the last value of the for loop
                        def name = f
                        tests["${name}"] = {
                            build job: "${name}"
                        }
                    }
                    parallel tests
                }
            }
        }       
    }
}