Zmienić kolor podświetlenia, gdy okno nie jest ostre?

Używam trybu hl jako mniejszego trybu dla zręczności. Jak zmienić kolor podświetlonej linii (np. Na szary), gdy okno deft nie jest bieżącym oknem, a następnie powrócić do domyślnego koloru podświetlenia, gdy okno deft ponownie staje się bieżącym oknem?

Zaimplementowałem to do hl-line-modeużywania buffer-list-update-hook. Oto kod:

(defface hl-line-inactive
  '((t nil))
  "Inactive variant of `hl-line'."
  :group 'hl-line)

(defun hl-line-update-face (window)
  "Update the `hl-line' face in WINDOW to indicate whether the window is selected."
  (with-current-buffer (window-buffer window)
    (when hl-line-mode
      (if (eq (current-buffer) (window-buffer (selected-window)))
          (face-remap-reset-base 'hl-line)
        (face-remap-set-base 'hl-line (face-all-attributes 'hl-line-inactive))))))

(add-hook 'buffer-list-update-hook (lambda () (walk-windows #'hl-line-update-face nil t)))

Co robi ten kod:

• Zdefiniuj nową twarz hl-line-inactivedo użycia w nieaktywnych oknach. Możesz użyć M-x customize-facedo zmodyfikowania atrybutów tej twarzy według własnego gustu.
• Zdefiniuj funkcję tymczasowego mapowania podświetlonej twarzy w nieaktywnych oknach. Okno jest uważane za nieaktywne, jeśli nie wyświetla tego samego bufora co aktualnie wybrane okno.
• Dodaj hak do buffer-list-update-hooktych połączeń hl-line-update-facedla wszystkich widocznych okien.

Stara odpowiedź

Powyższy kod (którego używam we własnym initpliku) jest znacznie prostszy niż ten, który pierwotnie opublikowałem. Dzięki @Drew za sugestię użycia walk-windows. Przeczytałem również więcej o remapowaniu twarzy (zobacz Remapowanie twarzy w Podręczniku Emacs Lisp) i zdałem sobie sprawę, że mogę usunąć dużo kodu.

Dla potomnych oto, co pierwotnie opublikowałem:

;; Define a face for the inactive highlight line.
(defface hl-line-inactive
  '((t nil))
  "Inactive variant of `hl-line'."
  :group 'local)

(defun toggle-active-window-highlighting ()
  "Update the `hl-line' face in any visible buffers to indicate which window is active."
  (let ((dups))
    (mapc
     (lambda (frame)
       (mapc
        (lambda (window)
          (with-current-buffer (window-buffer window)
            (when hl-line-mode
              (make-local-variable 'face-remapping-alist)
              (let ((inactive (rassoc '(hl-line-inactive) face-remapping-alist)))
                (if (eq window (selected-window))
                    (progn
                      (setq dups (get-buffer-window-list nil nil 'visible))
                      (setq face-remapping-alist (delq inactive face-remapping-alist)))
                  (unless (or inactive (memq window dups))
                    (add-to-list 'face-remapping-alist '(hl-line hl-line-inactive))))))))
        (window-list frame)))
     (visible-frame-list))))

(add-hook 'buffer-list-update-hook #'toggle-active-window-highlighting)