Jak zmienić części niestandardowego motywu?

Używam jednego z predefiniowanych niestandardowych motywów dołączonych do Spacemacs (zenburn).

Jak mogę zmodyfikować określone części motywu, na przykład po prostu zmienić kolor czcionki użyty w komentarzach?

Wolę używać custom-theme-set-facesdo redefiniowania sposobu wyświetlania konkretnej twarzy, np.

(custom-theme-set-faces
 'zenburn
 '(font-lock-comment-face ((t (:foreground "#DFAF8F"))))
 '(font-lock-comment-delimiter-face ((t (:foreground "#DFAF8F")))))

W konkretnym przypadku zenburnsam motyw definiuje różne kolory i makro, w których są one powiązane z nazwami zmiennych, dzięki czemu możesz zapisać powyższe jako:

(zenburn-with-color-variables
  (custom-theme-set-faces
   'zenburn
   `(font-lock-comment-face ((t (:foreground ,zenburn-orange))))
   `(font-lock-comment-delimiter-face ((t (:foreground ,zenburn-orange))))))

W spacemacs zainstaluj warstwę theming, patrz https://github.com/syl20bnr/spacemacs/tree/master/layers/%2Bthemes/theming

Na przykład mam wycięte w dotspacemacs/user-initmoim, .spacemacsaby dostosować tło i kolor bielizny gruvbox i motyw światła słonecznego:

  (setq theming-modifications '(
    ;; requires the theming layer
    (gruvbox
       (default :background "#1D2021" :foreground "#fdf4c1")
       (linum :background "#000000" :foreground "#878787")
       (fringe  :background "#000000")
       (linum-relative-current-face :inherit (shadow default) :background "#3C3836" :foreground "#ff0000")
       (font-lock-comment-face :slant italic)
    )
    (solarized-light
     (linum :background "#DBCDA7" :foreground "#40371F")
       (fringe :background "#DBCDA7")
       (font-lock-comment-face :slant italic)
       )
))

Dodałem radę do funkcji motywu ładowania, aby zastąpić niektóre twarze - w ten sposób możesz nadal używać motywu ładowania jak zwykle, aby wybrać motyw, a to automatycznie zastosuje przesłonięcia.

(defadvice load-theme (after theme-set-overrides activate)
  "Set override faces for different custom themes."
  (dolist (theme-settings theme-overrides)
    (let ((theme (car theme-settings))
          (faces (cadr theme-settings)))
      (if (member theme custom-enabled-themes)
          (dolist (face faces)
            (custom-theme-set-faces theme face))))))

(defcustom theme-overrides nil
  "Association list of override faces to set for different custom themes.")

(defun alist-set (alist-symbol key value)
  "Set VALUE of a KEY in ALIST-SYMBOL."
  (set alist-symbol
        (cons (list key value) (assq-delete-all key (eval alist-symbol)))))

; override some settings of the ample-flat theme
(alist-set 'theme-overrides 'ample-flat '(
                                          (default ((t (:background "gray12" :foreground "#bdbdb3"))))
                                          (mode-line ((t (:background "cornsilk4" :foreground "#222" :inherit 'variable-pitch))))
                                          (outline-2 ((t (:inherit font-lock-keyword-face)))) ; blueish
                                          (outline-3 ((t (:inherit font-lock-comment-face)))) ; brownish
                                          (outline-4 ((t (:inherit font-lock-string-face)))) ; orangeish
                                          (org-table ((t (:inherit fixed-pitch :height 0.7 :foreground "#887"))))
                                          (org-formula ((t (:inherit org-table :foreground nil))))
                                          ))

Działa i byłoby miło mieć go jako część interfejsu, ale prawdopodobnie najłatwiej jest po prostu stworzyć funkcję dla każdego używanego motywu i wywołać niestandardowe zestawy motywów po załadowaniu -

(defun ample-flat ()
  (interactive)
  (mapc #'disable-theme custom-enabled-themes) ; clear any existing themes
  (load-theme 'ample-flat t)
  (custom-theme-set-faces 'ample-flat 
                          '(default ((t (:background "gray12" :foreground "#bdbdb3"))))
                          '(mode-line ((t (:background "cornsilk4" :foreground "#222" :inherit 'variable-pitch))))
                          '(outline-2 ((t (:inherit font-lock-keyword-face)))) ; blueish
                          '(outline-3 ((t (:inherit font-lock-comment-face)))) ; brownish
                          '(outline-4 ((t (:inherit font-lock-string-face)))) ; orangeish
                          '(org-table ((t (:inherit fixed-pitch :height 0.7 :foreground "#887"))))
                          '(org-formula ((t (:inherit org-table :foreground nil))))
                          ))

(ample-flat)

Przykład tego, co zrobiłem, aby edytować spacemacs-dark, usuwając kilka pogrubień, których nie lubię:

  ;; on dotspacemacs/user-config:

  ;; configure spacemacs-dark theme, specifically removing bolds
  (let
      ((func "#d75fd7")
       (keyword "#4f97d7")
       (type "#ce537a"))

    (custom-theme-set-faces
     'spacemacs-dark
     `(font-lock-function-name-face ((t (:foreground ,func :inherit normal))))
     `(font-lock-keyword-face ((t (:foreground ,keyword :inherit normal))))
     `(font-lock-type-face ((t (:foreground ,type :inherit normal))))
     )
    )

Łatwiej będzie ci po prostu użyć SPC SPC custom-theme-visit-theme, znaleźć gruvbox, wprowadzić tam zmiany, a następnie po prostu umieścić (load-file "~/.emacs.d/gruvbox-theme.el")w swojej dotspacemacs/user-configfunkcji.