make `delete-duplicate-lines` ignoruje puste linie i niektóre słowa

9

Edytuję tekst w trybie org, kilka linii jest powtarzanych, ponieważ są one częścią różnych plików z tego samego tematu.

Chcę użyć delete-duplicate-linesdo usunięcia powtarzających się wierszy, jednak polecenie usuwa również puste wiersze, czego nie chcę (w przeciwnym razie nie miałbym akapitów!). Chcę zignorować niektóre słowa, które istnieją same w wierszach, na przykład „Wznów” , powtarzają się wiele razy w tekście, ale chcę je zachować, ponieważ jest to wymagane.

text-editing shackra
źródło

Odpowiedzi:

5

Ignorowanie pustych linii

Możesz delete-duplicate-lineszignorować puste linie, wywołując je za pośrednictwem

C-u C-u C-u M-x delete-duplicate-lines RET

Jeśli nie chcesz naciskać C-utak wiele razy podczas połączenia delete-duplicate-lines, możesz zawinąć je w niestandardowe polecenie i powiązać to polecenie z wybraną sekwencją klawiszy:

(defun delete-duplicate-lines-keep-blanks ()
  (interactive)
  (delete-duplicate-lines (region-beginning) (region-end) nil nil t))

(global-set-key (kbd "C-c d") 'delete-duplicate-lines-keep-blanks)

Ignorowanie wierszy pasujących do wyrażenia regularnego

Co do drugiej części twojego pytania, nie sądzę, że możesz osiągnąć to, co chcesz, korzystając z wbudowanej wersji delete-duplicate-lines. Możesz jednak użyć zmodyfikowanej wersji polecenia (która domyślnie zachowuje również puste wiersze):

(defun delete-duplicate-lines
    (beg end keep &optional reverse adjacent keep-blanks interactive)
  (interactive
   (progn
     (barf-if-buffer-read-only)
     (list (region-beginning) (region-end)
           (read-string "Keep lines matching regexp: ") ; Prompt for regexp to keep
           (equal current-prefix-arg '(4))
           (equal current-prefix-arg '(16))
           t                                            ; Keep blanks by default
           t)))
  (let ((lines (unless adjacent (make-hash-table :test 'equal)))
        line prev-line
        (count 0)
        (beg (copy-marker beg))
        (end (copy-marker end)))
    (save-excursion
      (goto-char (if reverse end beg))
      (if (and reverse (bolp)) (forward-char -1))
      (while (if reverse
             (and (> (point) beg) (not (bobp)))
               (and (< (point) end) (not (eobp))))
        (setq line (buffer-substring-no-properties
                (line-beginning-position) (line-end-position)))
        (if (or (and keep-blanks (string= "" line))
                (string-match keep line))               ; Ignore line if it
                                                        ; matches regexp to keep
            (forward-line 1)
          (if (if adjacent (equal line prev-line) (gethash line lines))
              (progn
                (delete-region (progn (forward-line 0) (point))
                               (progn (forward-line 1) (point)))
                (if reverse (forward-line -1))
                (setq count (1+ count)))
            (if adjacent (setq prev-line line) (puthash line t lines))
            (forward-line (if reverse -1 1))))))
    (set-marker beg nil)
    (set-marker end nil)
    (when interactive
      (message "Deleted %d %sduplicate line%s%s"
               count
               (if adjacent "adjacent " "")
               (if (= count 1) "" "s")
               (if reverse " backward" "")))
    count))

Ta wersja delete-duplicate-linespoprosi cię o wyrażenie regularne i zachowa wszystkie wiersze, które pasują do wyrażenia regularnego. Na przykład, aby zachować wszystkie wiersze składające się ze słowa Resume:

M-x delete-duplicate-lines RET ^Resume$ RET

itsjeyd
źródło