Ukryj listę mniejszych trybów w linii trybu

Korzystam z kilku mniejszych trybów i zwykle wiem, który z mniejszych trybów jest włączony w każdym większym trybie. Jeśli naprawdę chcę zobaczyć pełną listę, mogę uruchomić C-h v minor-mode-list.

Jednocześnie moja linia trybu jest naprawdę zatkana, więc kiedy pionowo dzielę ramkę, czasami nie mogę odczytać końca linii trybu.

Rzeczywiste pytanie: jak wyłączyć wyświetlanie listy mniejszych trybów w linii trybu? Na przykład teraz może to wyglądać tak:

-:--- main.c        All (7,12)     (C/l FlyC SScr Abbrev Fill) [main] 16:19 0.45

Chcę, żeby wyglądało to bardziej zwięźle:

-:--- main.c        All (7,12)     (C/l) [main] 16:19

Zrobi to tryb zmniejszania (dostępny w Melpie).

(diminish 'projectile-mode)

Jak skomentował mbork, możesz użyć delight.el, aby selektywnie modyfikować lub wyłączać mniejszy (i rzeczywiście większy) tekst w trybie linii.

Jedną z zalet jest to, że dba o to eval-after-load(co musisz napisać ręcznie przy pomocy diminish.el w większości przypadków użycia), co czyni konfigurację czystszą. Nadal potrzebujesz tych samych informacji - nazwy trybu i biblioteki, która go implementuje (co Emacs powie ci, jeśli zapytasz go o tryb) - ale możesz to wszystko zawrzeć w jednym formularzu:

 (require 'delight)
 (delight '((some-mode nil "some-library")
            (some-other-mode nil "some-other-library")))

(Lub skorzystaj z powyższego linku, aby uzyskać przykłady prawdziwych zastosowań).

Poleciłbym takie podejście, ponieważ nawet jeśli nie chcesz, aby większość lżejszych tekstów w trybie mniejszym, istnieje duża szansa, że ​​niektóre z nich okażą się przydatne (i nadal możesz zmodyfikować te, aby były krótsze).

Jeśli naprawdę chcesz wyeliminować cały jaśniejszy tekst w trybie pomocniczym (i ponownie, nie polecam go), możesz zmodyfikować mode-line-modeszmienną. Zmienne linii trybu zmieniły się jakiś czas temu, więc możesz chcieć użyć, M-x find-variable RET mode-line-modes RETa następnie ręcznie dostosować swoją domyślną definicję, edytując sekcję dotyczącą minor-modes-alist.

Oczywiście wtedy musisz go zachować, co nie jest tak flashowe, więc wolisz zastąpić minor-mode-alistsymbol w ramach istniejącej wartości. Poniższe informacje są nieco specyficzne dla implementacji, ale na pewno ładniejsze niż ustawienie mode-line-modesw całości i można je włączać i wyłączać.

(define-minor-mode minor-mode-blackout-mode
  "Hides minor modes from the mode line."
  t)

(catch 'done
  (mapc (lambda (x)
          (when (and (consp x)
                     (equal (cadr x) '("" minor-mode-alist)))
            (let ((original (copy-sequence x)))
              (setcar x 'minor-mode-blackout-mode)
              (setcdr x (list "" original)))
            (throw 'done t)))
        mode-line-modes))

(global-set-key (kbd "C-c m") 'minor-mode-blackout-mode)

Używaj bogatej mniejszości z konfiguracją:

(require 'rich-minority)
(rich-minority-mode 1)
(setf rm-blacklist "")

Mam też taką myśl jak ty, ale skracam linię trybu bardziej paranoiczną :

• Usuń wszystkie niechciane spacje
• Usuń wszystkie spacje i „minimalną szerokość” pola informacji o pozycji bufora.

;; Remove all unwanted spaces
(setq-default mode-line-format
          '("%e" mode-line-front-space mode-line-mule-info mode-line-client mode-line-modified mode-line-remote mode-line-buffer-identification mode-line-position
        (vc-mode vc-mode) " "
        mode-line-modes mode-line-misc-info mode-line-end-spaces))
;; Remove all spaces and "min-width" of position info on mode-line
(setq mode-line-position
      `((1 ,(propertize
         " %p"
         'local-map mode-line-column-line-number-mode-map
         'mouse-face 'mode-line-highlight
         ;; XXX needs better description
         'help-echo "Size indication mode\n\
mouse-1: Display Line and Column Mode Menu"))
    (size-indication-mode
     (2 ,(propertize
          "/%I"
          'local-map mode-line-column-line-number-mode-map
          'mouse-face 'mode-line-highlight
          ;; XXX needs better description
          'help-echo "Size indication mode\n\
mouse-1: Display Line and Column Mode Menu")))
    (line-number-mode
     ((column-number-mode
       (1 ,(propertize
        "(%l,%c)"
        'local-map mode-line-column-line-number-mode-map
        'mouse-face 'mode-line-highlight
        'help-echo "Line number and Column number\n\
mouse-1: Display Line and Column Mode Menu"))
       (1 ,(propertize
        "L%l"
        'local-map mode-line-column-line-number-mode-map
        'mouse-face 'mode-line-highlight
        'help-echo "Line Number\n\
mouse-1: Display Line and Column Mode Menu"))))
     ((column-number-mode
       (1 ,(propertize
        "C%c"
        'local-map mode-line-column-line-number-mode-map
        'mouse-face 'mode-line-highlight
        'help-echo "Column number\n\
mouse-1: Display Line and Column Mode Menu"))))))
      )

Teraz zawsze widzę powiadomienie w trybie Twitter i licznik trybu organizacji: D

Oto, co zadziałało dla mnie:

(defvar hidden-minor-modes ; example, write your own list of hidden
  '(abbrev-mode            ; minor modes
    auto-fill-function
    flycheck-mode
    flyspell-mode
    inf-haskell-mode
    haskell-indent-mode
    haskell-doc-mode
    smooth-scroll-mode))

(defun purge-minor-modes ()
  (interactive)
  (dolist (x hidden-minor-modes nil)
    (let ((trg (cdr (assoc x minor-mode-alist))))
      (when trg
        (setcar trg "")))))

(add-hook 'after-change-major-mode-hook 'purge-minor-modes)

Dzięki komentarzowi Drew poprawiłem realizację tego rozwiązania. Teraz wykorzystuje zalety list asocjacyjnych i powinien być nieco bardziej wydajny ;-)

Wrzucę też moje rozwiązanie tego na ring:

(defun modeline-set-lighter (minor-mode lighter)
  (when (assq minor-mode minor-mode-alist)
    (setcar (cdr (assq minor-mode minor-mode-alist)) lighter)))

(defun modeline-remove-lighter (minor-mode)
  (modeline-set-lighter minor-mode ""))

modeline-set-lighterpozwala ustawić zapalniczkę trybu podrzędnego na dowolny ciąg, który ci się podoba. modeline-remove-lighterpozwala całkowicie usunąć zapalniczkę z mniejszego trybu.

Następnie na końcu mojego pliku init wywołuję te funkcje dla mniejszych trybów, których zapalniczki chcę zmodyfikować:

(modeline-remove-lighter 'auto-complete-mode)
(modeline-remove-lighter 'git-gutter+-mode)
(modeline-remove-lighter 'guide-key-mode)
(modeline-remove-lighter 'whitespace-mode)
(modeline-set-lighter 'abbrev-mode " Abbr")
(modeline-set-lighter 'auto-fill-function (string 32 #x23ce))

Możesz również tępo usunąć wszystkie pomniejsze tryby w następujący sposób:

(setq mode-line-modes
      (mapcar (lambda (elem)
                (pcase elem
                  (`(:propertize (,_ minor-mode-alist . ,_) . ,_)
                   "")
                  (t elem)))
              mode-line-modes))

Będzie to również działać w przypadku mniejszych trybów zdefiniowanych w przyszłości, ponieważ po prostu całkowicie usuwa użycie minor-mode-alistz mode-line-format.

Warto zauważyć, że use-package wspiera zmniejszanie i zachwyt . Jeśli używasz go do zarządzania pakietami, możesz ukryć pomniejsze tryby w wierszu trybu, dodając słowa kluczowe: zmniejsz lub: zachwyt.

(use-package abbrev
  :diminish abbrev-mode
  :config
  (if (file-exists-p abbrev-file-name)
     (quietly-read-abbrev-file)))

Nie widzę sensu instalowania fantazyjnych nazwanych rozszerzeń dla czegoś tak prostego jak:

(setcar (alist-get minor-mode minor-mode-alist) "")

Na przykład:

(dolist (mode '(projectile-mode
                whitespace-mode
                hs-minor-mode
                outline-minor-mode
                auto-fill-function))
  (setcar (alist-get mode minor-mode-alist) ""))

W ten sposób możesz robić różne rzeczy. Zamiana tekstu jest oczywista z powyższego. Na przykład, aby umieścić tryb Flymake na początku listy:

(let ((mode (assq #'flymake-mode minor-mode-alist)))
  (setq minor-mode-alist (cons mode (remq mode minor-mode-alist))))