Automatyczne wcięcie \ jeśli instrukcje z AUCTeX

Obecne AUCTeXzachowanie dla prymitywnego texkodu udziałem razie -jak sprawozdań jest wciąć instrukcji warunkowej na tym samym poziomie co otaczającej stanie. Tj. Kod taki jak

\if@sometoggle%
\dosomething%
\else%
\doanotherthing%
\fi%

pojawia się jako duży blok tekstu. Chciałbym wprowadzić AUCTeXwcięcie w następujący sposób:

\if@sometoggle%
  \dosomething%
\else%
  \doanotherthing%
\fi%

czy to możliwe?

To jest możliwe:

(setq LaTeX-begin-regexp "\\(?:begin\\|if@\\)\\b")
(setq LaTeX-end-regexp "\\(?:end\\|else\\|fi\\)\\b")
(defun LaTeX-indent-level-count ()
  "Count indentation change caused by all \\left, \\right, \\begin, and
\\end commands in the current line."
  (save-excursion
    (save-restriction
      (let ((count 0))
        (narrow-to-region (point)
                          (save-excursion
                            (re-search-forward
                             (concat "[^" TeX-esc "]"
                                     "\\(" LaTeX-indent-comment-start-regexp
                                     "\\)\\|\n\\|\\'"))
                            (backward-char)
                            (point)))
        (while (search-forward TeX-esc nil t)
          (cond
            ((looking-at "left\\b")
             (setq count (+ count LaTeX-left-right-indent-level)))
            ((looking-at "right\\b")
             (setq count (- count LaTeX-left-right-indent-level)))
            ((looking-at LaTeX-begin-regexp)
             (setq count (+ count LaTeX-indent-level)))
            ((looking-at "else\\b"))
            ((looking-at LaTeX-end-regexp)
             (setq count (- count LaTeX-indent-level)))
            ((looking-at (regexp-quote TeX-esc))
             (forward-char 1))))
        count))))

Pamiętaj, że musiałem ponownie zdefiniować LaTeX-indent-level-count. Różnica to po prostu jedna condgałąź:

((looking-at "else\\b"))