Czy istnieje yasnippet wytwarzający wstępnie wypełniony komentarz doxygen?

10

Dla następującej funkcji C ++:

bool importantStuff(double a, double b);

Powinien wygenerować następujący fragment kodu, być może bez tagów:

/**
 * <Insert description of importantStuff>
 *
 * @param a <Insert description of a>
 * @param b <Insert description of b>
 * @return <Insert description of the return value>
 */

Szukałem po internecie, ale najbliżej stałam na odpowiedź jest to stary, więc pytanie, jeżeli odpowiedź zależy już prowadzonego trybu doxymacs.

yasnippet c++ Rovanion
źródło
Myślę, że c-sharp-modema coś, co to robi.
erikstokes
Czy chcesz to zrobić dla nowych lub istniejących funkcji?
itsjeyd
Zadając pytanie, myślałem o komentarzu doksygen generowanym z podpisu funkcji.
Rovanion

Odpowiedzi:

4

Używam poniższego, który jest połączeniem standardowego opartego na doksymakach i semantycznego opartego na abo-abo wspomnianego już jako odpowiedź - to wymaga tylko semantycznego i yasnippet. To wstępnie wypełnia niektóre z symboli zastępczych yasnippet odpowiednimi informacjami, a także w porównaniu z wersją abo-abo.


# -*- mode: snippet -*-
# name: dox
# key: dox
# type: command
# --
(unless (and (fboundp 'semantic-current-tag)
             semantic-mode)
  (error "Semantic required to use dox snippet"))
(let ((tag (senator-next-tag)))
  (while (or (null tag)
             (not (semantic-tag-of-class-p tag 'function)))
    (setq tag (senator-next-tag)))
  (let* ((name (semantic-tag-name tag))
         (attrs (semantic-tag-attributes tag))
         (args (plist-get attrs :arguments))
         (return-name (plist-get attrs :type))
         (idx 1))
    (if (listp return-name)
      (setq return-name (car return-name)))
    (yas/expand-snippet
     (format
      "/**
* @brief ${1:%s}
*
%s
%s*/
"
      name
      (mapconcat
       (lambda (x)
         (format "* @param %s ${%d:Description of %s}"
                 (car x) (incf idx) (car x)))
       args
       "\n")
      (if (and return-name (not (string-equal "void" return-name)))
          (format " * @return ${%d:%s}\n" (incf idx) return-name)
        "")))))
alexmurray
źródło
To rozwiązanie absolutnie działa, ale czekanie, aż tryb semantyczny przeszuka cały wymagany kod, jest nieco kłopotliwe. Miałem też emacsa, który utknął w nieskończonych pętlach, jeśli zamiast tego napiszę dox <tab> przed zmienną. Ale nie można mieć wszystkiego na tym świecie: D
Rovanion
należy głosować wyżej niż wyżej, ponieważ jest bogatszy niż moo-doxygen
Alejandro Erickson
3

Właśnie dodałem tę funkcję do argumentów funkcji .

Oto kod, jeśli jesteś zainteresowany. Korzysta z CEDET:

(defun moo-doxygen ()
  "Generate a doxygen yasnippet and expand it with `aya-expand'.
The point should be on the top-level function name."
  (interactive)
  (move-beginning-of-line nil)
  (let ((tag (semantic-current-tag)))
    (unless (semantic-tag-of-class-p tag 'function)
      (error "Expected function, got %S" tag))
    (let* ((name (semantic-tag-name tag))
           (attrs (semantic-tag-attributes tag))
           (args (plist-get attrs :arguments))
           (ord 1))
      (setq aya-current
            (format
             "/**
* $1
*
%s
* @return $%d
*/
"
             (mapconcat
              (lambda (x)
                (format "* @param %s $%d"
                        (car x) (incf ord)))
              args
              "\n")
             (incf ord)))
      (aya-expand))))

Potrzebujesz także auto-yasnippet . Oba pakiety są dostępne w MELPA.

abo-abo
źródło