Jak automatycznie zainstalować pakiety Emacsa, określając listę nazw pakietów?

Używam packagedo zarządzania rozszerzeniami Emacsa. Aby zsynchronizować moje ustawienia Emacsa na różnych komputerach, chciałbym określić listę nazw pakietów w .emacspliku, a następnie packagemóc automatycznie wyszukiwać i instalować pakiety, aby nie musieć instalować ich ręcznie, dzwoniąc M-x package-list-packages. Jak to zrobić?

; list the packages you want
(setq package-list '(package1 package2))

; list the repositories containing them
(setq package-archives '(("elpa" . "http://tromey.com/elpa/")
                         ("gnu" . "http://elpa.gnu.org/packages/")
                         ("marmalade" . "http://marmalade-repo.org/packages/")))

; activate all the packages (in particular autoloads)
(package-initialize)

; fetch the list of packages available 
(unless package-archive-contents
  (package-refresh-contents))

; install the missing packages
(dolist (package package-list)
  (unless (package-installed-p package)
    (package-install package)))

Na podstawie komentarzy Profpatscha i odpowiedzi poniżej:

(defun ensure-package-installed (&rest packages)
  "Assure every package is installed, ask for installation if it’s not.

Return a list of installed packages or nil for every skipped package."
  (mapcar
   (lambda (package)
     ;; (package-installed-p 'evil)
     (if (package-installed-p package)
         nil
       (if (y-or-n-p (format "Package %s is missing. Install it? " package))
           (package-install package)
         package)))
   packages))

;; make sure to have downloaded archive description.
;; Or use package-archive-contents as suggested by Nicolas Dudebout
(or (file-exists-p package-user-dir)
    (package-refresh-contents))

(ensure-package-installed 'iedit 'magit) ;  --> (nil nil) if iedit and magit are already installed

;; activate installed packages
(package-initialize)

Emacs 25.1+ automatycznie śledzi pakiety zainstalowane przez użytkownika w dostosowywalnej package-selected-packageszmiennej. package-installzaktualizuje zmienną dostosowywania i będzie można zainstalować wszystkie wybrane pakiety za pomocą tej package-install-selected-packagesfunkcji.

Inną wygodną zaletą tego podejścia jest to, że można go użyć package-autoremovedo automatycznego usuwania pakietów, które nie są uwzględnione package-selected-packages(choć zachowa zależności).

(package-initialize)
(unless package-archive-contents
  (package-refresh-contents))
(package-install-selected-packages)

Źródło: http://endlessparentheses.com/new-in-package-el-in-emacs-25-1-user-selected-packages.html

Oto kod, którego używam do Emacs Prelude :

(require 'package)
(require 'melpa)
(add-to-list 'package-archives
             '("melpa" . "http://melpa.milkbox.net/packages/") t)
(package-initialize)

(setq url-http-attempt-keepalives nil)

(defvar prelude-packages
  '(ack-and-a-half auctex clojure-mode coffee-mode deft expand-region
                   gist haml-mode haskell-mode helm helm-projectile inf-ruby
                   magit magithub markdown-mode paredit projectile
                   python sass-mode rainbow-mode scss-mode solarized-theme
                   volatile-highlights yaml-mode yari yasnippet zenburn-theme)
  "A list of packages to ensure are installed at launch.")

(defun prelude-packages-installed-p ()
  (loop for p in prelude-packages
        when (not (package-installed-p p)) do (return nil)
        finally (return t)))

(unless (prelude-packages-installed-p)
  ;; check for new packages (package versions)
  (message "%s" "Emacs Prelude is now refreshing its package database...")
  (package-refresh-contents)
  (message "%s" " done.")
  ;; install the missing packages
  (dolist (p prelude-packages)
    (when (not (package-installed-p p))
      (package-install p))))

(provide 'prelude-packages)

Jeśli nie używasz MELPY, nie musisz tego wymagać (a jeśli tak, to melpa.elmusi być na twoim load-path(lub zainstalowanym przez MELPA). Pakiet db nie jest odświeżany za każdym razem (ponieważ to znacznie spowolniłoby uruchamianie ) - tylko w przypadku obecności odinstalowanych pakietów.

Nikt jeszcze nie wspomniał o Cask , ale nadaje się do tego zadania.

Zasadniczo tworzysz ~/.emacs.d/Casklistę pakietów, które chcesz zainstalować. Na przykład:

(source melpa)
(depends-on "expand-region")
(depends-on "goto-last-change")
; ... etc

Uruchomienie caskz wiersza poleceń spowoduje zainstalowanie tych pakietów i wszelkich potrzebnych im zależności.

Możesz także automatycznie aktualizować zainstalowane pakiety za pomocą cask update.

Zadzwoń package-installpodając nazwę pakietu jako symbol. Możesz znaleźć nazwy pakietów dla swoich pakietów, wywołując package-installinteraktywnie i uzupełniając nazwę. Funkcja package-installed-ppoinformuje Cię, czy została już zainstalowana.

Na przykład:

(mapc
 (lambda (package)
   (or (package-installed-p package)
       (package-install package)))
 '(package1 package2 package3))

(require 'cl)
(require 'package)

(setq cfg-var:packages '(
       emmet-mode
       ergoemacs-mode
       flycheck
       flycheck-pyflakes
       monokai-theme
       py-autopep8
       py-isort
       rainbow-mode
       yafolding
       yasnippet))

(defun cfg:install-packages ()
    (let ((pkgs (remove-if #'package-installed-p cfg-var:packages)))
        (when pkgs
            (message "%s" "Emacs refresh packages database...")
            (package-refresh-contents)
            (message "%s" " done.")
            (dolist (p cfg-var:packages)
                (package-install p)))))

(add-to-list 'package-archives '("gnu" . "http://elpa.gnu.org/packages/") t)
(add-to-list 'package-archives '("melpa" . "http://melpa.org/packages/") t)
(add-to-list 'package-archives '("melpa-stable" . "http://stable.melpa.org/packages/") t)
(add-to-list 'package-archives '("org" . "http://orgmode.org/elpa/") t)
(package-initialize)

(cfg:install-packages)

Lubię sprawdzać, czy użytkownik chce najpierw zainstalować pakiety, jak to zrobiono w tej odpowiedzi . Odświeżam również zawartość pakietu przed zainstalowaniem czegokolwiek. Nie jestem pewien, czy to najlepszy sposób, ale nie sądzę, że najlepsze odpowiedzi robiły to za mnie.

(setq required-pkgs '(jedi flycheck cider clojure-mode paredit markdown-mode jsx-mode company))

(require 'cl)

(setq pkgs-to-install
      (let ((uninstalled-pkgs (remove-if 'package-installed-p required-pkgs)))
        (remove-if-not '(lambda (pkg) (y-or-n-p (format "Package %s is missing. Install it? " pkg))) uninstalled-pkgs)))

(when (> (length pkgs-to-install) 0)
  (package-refresh-contents)
  (dolist (pkg pkgs-to-install)
    (package-install pkg)))

Pobiegłem na problem, że nic się nie stało, po dodaniu (package-install 'org)do .emacs. Chciałem zainstalować aktualną wersję programu, org-modea wbudowany org-modejest dość stary.

package-installWygrzebałem kod źródłowy z Emacsa 25.3.1. Funkcja self już sprawdza, czy pakiet jest zainstalowany, czy nie, i odmawia instalacji, jeśli pakiet jest już zainstalowany. Tak więc czek (unless (package-installed-p package) ...)z odpowiedzi 10093312 jest w rzeczywistości niewskazany .

(defun package-install (pkg &optional dont-select)
  "Install the package PKG.
PKG can be a package-desc or a symbol naming one of the available packages
in an archive in `package-archives'.  Interactively, prompt for its name.

If called interactively or if DONT-SELECT nil, add PKG to
`package-selected-packages'.

If PKG is a package-desc and it is already installed, don't try
to install it but still mark it as selected."
  (interactive
   (progn
     ;; Initialize the package system to get the list of package
     ;; symbols for completion.
     (unless package--initialized
       (package-initialize t))
     (unless package-archive-contents
       (package-refresh-contents))
     (list (intern (completing-read
                    "Install package: "
                    (delq nil
                          (mapcar (lambda (elt)
                                    (unless (package-installed-p (car elt))
                                      (symbol-name (car elt))))
                                  package-archive-contents))
                    nil t))
           nil)))
  (add-hook 'post-command-hook #'package-menu--post-refresh)
  (let ((name (if (package-desc-p pkg)
                  (package-desc-name pkg)
                pkg)))
    (unless (or dont-select (package--user-selected-p name))
      (package--save-selected-packages
       (cons name package-selected-packages)))
    (if-let ((transaction
              (if (package-desc-p pkg)
                  (unless (package-installed-p pkg)
                    (package-compute-transaction (list pkg)
                                                 (package-desc-reqs pkg)))
                (package-compute-transaction () (list (list pkg))))))
        (package-download-transaction transaction)
      (message "`%s' is already installed" name))))

Wbudowany org-moderównież liczy się jako zainstalowany i package-installodmawia zainstalowania nowszej wersji firmy ELPA. Po spędzeniu trochę czasu na czytaniu package.el wpadłem na następujące rozwiązanie.

(dolist (package (package-compute-transaction
                  () (list (list 'python '(0 25 1))
                           (list 'org '(20171211)))))
  ;; package-download-transaction may be more suitable here and
  ;; I don't have time to check it
  (package-install package))

Powodem, dla którego to działa, jest to, że package-*funkcje rodzinne różnie obsługują argumenty w zależności od tego, czy jest to symbol, czy package-descobiekt. Informacje o wersji można określić tylko za package-installpośrednictwem package-descobiektu.

Oto moje, jest krótsze :)

(mapc
 (lambda (package)
   (unless (package-installed-p package)
     (progn (message "installing %s" package)
            (package-refresh-contents)
            (package-install package))))
 '(browse-kill-ring flycheck less-css-mode tabbar org auto-complete undo-tree clojure-mode markdown-mode yasnippet paredit paredit-menu php-mode haml-mode rainbow-mode fontawesome))

Oto inny sposób.

;; assure every package is installed
(defun ensure-package-installed (&rest packages)
  (let ((user-required-packages
         (seq-remove
          (lambda (package) (package-installed-p package))
          packages)))
    (when user-required-packages
      (package-refresh-contents)
      (dolist (package user-required-packages)
        (package-install package)))))

;; list of packages to install
(ensure-package-installed
 'try
 'which-key)