Jak zaimplementować instrukcję if-else w XSLT?

171

Próbuję zaimplementować instrukcję if -else w XSLT, ale mój kod po prostu nie analizuje. Czy ktoś ma jakieś pomysły?

  <xsl:variable name="CreatedDate" select="@createDate"/>
  <xsl:variable name="IDAppendedDate" select="2012-01-01" />
  <b>date: <xsl:value-of select="$CreatedDate"/></b> 

  <xsl:if test="$CreatedDate > $IDAppendedDate">
    <h2> mooooooooooooo </h2>
  </xsl:if>
  <xsl:else>
    <h2> dooooooooooooo </h2>
  </xsl:else>
xml xslt if-statement Odjechany
źródło
Możliwy duplikat XSL, jeśli inny warunek

Odpowiedzi:

316

Musisz go ponownie zaimplementować za pomocą <xsl:choose>tagu:

       <xsl:choose>
         <xsl:when test="$CreatedDate > $IDAppendedDate">
           <h2> mooooooooooooo </h2>
         </xsl:when>
         <xsl:otherwise>
          <h2> dooooooooooooo </h2>
         </xsl:otherwise>
       </xsl:choose>
px1mp
źródło
65

Jeśli instrukcja jest używana do szybkiego sprawdzenia tylko jednego warunku. Jeśli masz wiele opcji, użyj, <xsl:choose>jak pokazano poniżej:

   <xsl:choose>
     <xsl:when test="$CreatedDate > $IDAppendedDate">
       <h2>mooooooooooooo</h2>
     </xsl:when>
     <xsl:otherwise>
      <h2>dooooooooooooo</h2>
     </xsl:otherwise>
   </xsl:choose>

Możesz także używać wielu <xsl:when>tagów do wyrażania If .. Else Iflub Switchwzorców, jak pokazano poniżej:

   <xsl:choose>
     <xsl:when test="$CreatedDate > $IDAppendedDate">
       <h2>mooooooooooooo</h2>
     </xsl:when>
     <xsl:when test="$CreatedDate = $IDAppendedDate">
       <h2>booooooooooooo</h2>
     </xsl:when>
     <xsl:otherwise>
      <h2>dooooooooooooo</h2>
     </xsl:otherwise>
   </xsl:choose>

Poprzedni przykład byłby odpowiednikiem poniższego pseudokodu:

   if ($CreatedDate > $IDAppendedDate)
   {
       output: <h2>mooooooooooooo</h2>
   }
   else if ($CreatedDate = $IDAppendedDate)
   {
       output: <h2>booooooooooooo</h2>
   }
   else
   {
       output: <h2>dooooooooooooo</h2>
   }
InfantPro'Aravind '
źródło
1
Czy mógłbyś poprawić poniższe stwierdzenie, wszyscy wiemy, że jeśli (case> x) bez podążania za {} wykona tylko 1 następną linię, widziałem to na wielu początkujących, że piszą dokładnie to, co tu zamieściłeś, prawdopodobnie wielu z nich skopiowane 1: 1
Oliver
1
Nawiasem mówiąc, if elsewarunek był tylko przykładem lub raczej pseudokodem.
Rozważam
36

Jeśli mogę zaproponować jakieś sugestie (dwa lata później, ale mam nadzieję, że będą pomocne dla przyszłych czytelników) :

  • Pomiń wspólne h2 element.
  • Pomiń wspólne ooooooooooooo tekst.
  • Pamiętaj o nowej if/then/elsekonstrukcji XPath 2.0, jeśli używasz XSLT 2.0.

Rozwiązanie XSLT 1.0 (działa również z XSLT 2.0)

<h2>
  <xsl:choose>
    <xsl:when test="$CreatedDate > $IDAppendedDate">m</xsl:when>
    <xsl:otherwise>d</xsl:otherwise>
  </xsl:choose>
  ooooooooooooo
</h2>

Rozwiązanie XSLT 2.0

<h2>
   <xsl:value-of select="if ($CreatedDate > $IDAppendedDate) then 'm' else 'd'"/>
   ooooooooooooo
</h2>
kjhughes
źródło
1

Najprostszym podejściem jest wykonanie drugiego testu if, ale z odwróconym warunkiem. Ta technika jest krótsza, łatwiejsza dla oczu i łatwiejsza do wykonania niż zagnieżdżony blok typu „wybierz, kiedy”:

<xsl:variable name="CreatedDate" select="@createDate"/>
     <xsl:variable name="IDAppendedDate" select="2012-01-01" />
     <b>date: <xsl:value-of select="$CreatedDate"/></b> 
     <xsl:if test="$CreatedDate &gt; $IDAppendedDate">
        <h2> mooooooooooooo </h2>
     </xsl:if>
     <xsl:if test="$CreatedDate &lt;= $IDAppendedDate">
        <h2> dooooooooooooo </h2>
     </xsl:if>

Oto rzeczywisty przykład techniki używanej w arkuszu stylów witryny rządowej: http://w1.weather.gov/xml/current_obs/latest_ob.xsl

Raymond Hettinger
źródło
5
Konieczność zapamiętania i upewnienia się, że drugi iftest pasuje do uzupełnienia pierwszego, sprawia, że ​​każda kolejna modyfikacja jest bardziej podatna na błąd.
Philippe-André Lorin
2
Zgadzam się, Pal. Myślę też, że powyższy przykład jest trudniejszy do odczytania, podczas gdy użycie a <xsl:choose>byłoby o wiele prostsze, a jego znaczenie o wiele bardziej jasne.
Doug Barbieri
1

Pierwotnie z tego wpisu na blogu . Możemy to osiągnąć, używając poniższego kodu

<xsl:choose>
    <xsl:when test="something to test">

    </xsl:when>
    <xsl:otherwise>

    </xsl:otherwise>
</xsl:choose>

Więc oto co zrobiłem

<h3>System</h3>
    <xsl:choose>
        <xsl:when test="autoIncludeSystem/autoincludesystem_info/@mdate"> <!-- if attribute exists-->
            <p>
                <dd><table border="1">
                    <tbody>
                        <tr>
                            <th>File Name</th>
                            <th>File Size</th>
                            <th>Date</th>
                            <th>Time</th>
                            <th>AM/PM</th>
                        </tr>
                        <xsl:for-each select="autoIncludeSystem/autoincludesystem_info">
                            <tr>
                                <td valign="top" ><xsl:value-of select="@filename"/></td>
                                <td valign="top" ><xsl:value-of select="@filesize"/></td>
                                <td valign="top" ><xsl:value-of select="@mdate"/></td>
                                <td valign="top" ><xsl:value-of select="@mtime"/></td>
                                <td valign="top" ><xsl:value-of select="@ampm"/></td>
                            </tr>
                        </xsl:for-each>
                    </tbody>
                </table>
                </dd>
            </p>
        </xsl:when>
        <xsl:otherwise> <!-- if attribute does not exists -->
            <dd><pre>
                <xsl:value-of select="autoIncludeSystem"/><br/>
            </pre></dd> <br/>
        </xsl:otherwise>
    </xsl:choose>

Moje wyjście

wprowadź opis obrazu tutaj

AabinGunz
źródło