Groovy wykonuje polecenia powłoki

Groovy dodaje executemetodę Stringdo, aby wykonywanie powłok było dość łatwe;

println "ls".execute().text

ale jeśli wystąpi błąd, nie ma wynikowego wyniku. Czy istnieje łatwy sposób na uzyskanie zarówno błędu standardowego, jak i standardowego? (inne niż tworzenie zestawu kodu; utworzyć dwa wątki w celu odczytania obu strumieni wejściowych, a następnie użyć strumienia nadrzędnego, aby poczekać na ich zakończenie, a następnie przekonwertować ciągi z powrotem na tekst?)

Byłoby miło mieć coś takiego;

 def x = shellDo("ls /tmp/NoFile")
 println "out: ${x.out} err:${x.err}"

Ok, rozwiązałem to sam;

def sout = new StringBuilder(), serr = new StringBuilder()
def proc = 'ls /badDir'.execute()
proc.consumeProcessOutput(sout, serr)
proc.waitForOrKill(1000)
println "out> $sout err> $serr"

wyświetlacze:

out> err> ls: cannot access /badDir: No such file or directory

"ls".execute()zwraca Processobiekt, dlatego "ls".execute().textdziała. Powinieneś być w stanie po prostu przeczytać strumień błędów, aby określić, czy wystąpiły jakieś błędy.

Jest to dodatkowy sposób na Processktóre pozwalają przejść StringBufferdo pobierania tekst: consumeProcessErrorStream(StringBuffer error).

Przykład:

def proc = "ls".execute()
def b = new StringBuffer()
proc.consumeProcessErrorStream(b)

println proc.text
println b.toString()

// a wrapper closure around executing a string                                  
// can take either a string or a list of strings (for arguments with spaces)    
// prints all output, complains and halts on error                              
def runCommand = { strList ->
  assert ( strList instanceof String ||
           ( strList instanceof List && strList.each{ it instanceof String } ) \
)
  def proc = strList.execute()
  proc.in.eachLine { line -> println line }
  proc.out.close()
  proc.waitFor()

  print "[INFO] ( "
  if(strList instanceof List) {
    strList.each { print "${it} " }
  } else {
    print strList
  }
  println " )"

  if (proc.exitValue()) {
    println "gave the following error: "
    println "[ERROR] ${proc.getErrorStream()}"
  }
  assert !proc.exitValue()
}

Uważam to za bardziej idiomatyczne:

def proc = "ls foo.txt doesnotexist.txt".execute()
assert proc.in.text == "foo.txt\n"
assert proc.err.text == "ls: doesnotexist.txt: No such file or directory\n"

Jak wspomina inny post, są to połączenia blokujące, ale ponieważ chcemy pracować z wyjściem, może to być konieczne.

Aby dodać jeszcze jedną ważną informację do powyższych odpowiedzi -

Na proces

def proc = command.execute();

zawsze staraj się użyć

def outputStream = new StringBuffer();
proc.waitForProcessOutput(outputStream, System.err)
//proc.waitForProcessOutput(System.out, System.err)

zamiast

def output = proc.in.text;

przechwytywanie wyjść po wykonaniu poleceń w groovy, ponieważ to drugie jest wywołaniem blokującym ( pytanie SO z powodu ).

def exec = { encoding, execPath, execStr, execCommands ->

def outputCatcher = new ByteArrayOutputStream()
def errorCatcher = new ByteArrayOutputStream()

def proc = execStr.execute(null, new File(execPath))
def inputCatcher = proc.outputStream

execCommands.each { cm ->
    inputCatcher.write(cm.getBytes(encoding))
    inputCatcher.flush()
}

proc.consumeProcessOutput(outputCatcher, errorCatcher)
proc.waitFor()

return [new String(outputCatcher.toByteArray(), encoding), new String(errorCatcher.toByteArray(), encoding)]

}

def out = exec("cp866", "C:\\Test", "cmd", ["cd..\n", "dir\n", "exit\n"])

println "OUT:\n" + out[0]
println "ERR:\n" + out[1]

command = "ls *"

def execute_state=sh(returnStdout: true, script: command)

ale jeśli polecenie nie powiedzie się, proces zostanie zakończony