Jak zrobić coś dla każdego pliku w katalogu za pomocą skryptu wsadowego

Jak iterować każdy plik w katalogu z plikiem .bat lub .cmd?

Dla uproszczenia proszę podać odpowiedź, która po prostu odzwierciedla nazwę pliku lub ścieżkę pliku.

Wykorzystanie wiersza poleceń:

for /f %f in ('dir /b c:\') do echo %f

Wykorzystanie pliku wsadowego:

for /f %%f in ('dir /b c:\') do echo %%f

Aktualizacja : jeśli katalog zawiera pliki ze spacjami w nazwach, musisz zmienić separator, którego for /fużywa polecenie. na przykład możesz użyć znaku potoku.

for /f "delims=|" %%f in ('dir /b c:\') do echo %%f

Aktualizacja 2 : (szybko półtora roku po oryginalnej odpowiedzi :-)) Jeśli nazwa katalogu ma spację w nazwie, możesz użyć usebackqopcji na for:

for /f "usebackq delims=|" %%f in (`dir /b "c:\program files"`) do echo %%f

A jeśli chcesz użyć przekierowania wyjściowego lub potoku poleceń, użyj znaku esc ( ^):

for /f "usebackq delims=|" %%f in (`dir /b "c:\program files" ^| findstr /i microsoft`) do echo %%f

Alternatywnie użyj:

forfiles /s /m *.png /c "cmd /c echo @path"

Polecenie forfiles jest dostępne w systemie Windows Vista i nowszych.

Najłatwiejsza metoda:

Z wiersza poleceń użyj:

for %f in (*.*) do echo %f

Z pliku wsadowego (dwukrotnie znak% procent):

for %%f in (*.*) do echo %%f

Z pliku wsadowego z folderem określonym jako pierwszy parametr:

for %%f in (%1\*.*) do echo %%f

Posługiwać się

for /r path %%var in (*.*) do some_command %%var

z:

• ścieżka jest ścieżką początkową.
• %% var jest jakimś identyfikatorem.
• *. * jest maską pliku LUB zawartością zmiennej.
• some_command jest poleceniem do wykonania ze ścieżką i zmienną var połączoną jako parametry.

Inny sposób:

for %f in (*.mp4) do call ffmpeg -i "%~f" -vcodec copy -acodec copy "%~nf.avi"

Miałem złośliwe oprogramowanie, które oznaczało wszystkie pliki w katalogu jako ukryte / systemowe / tylko do odczytu. Jeśli ktokolwiek znajdzie się w takiej sytuacji, przejdź do katalogu i uruchom for /f "delims=|" %f in ('forfiles') do attrib -s -h -r %f.