Przekierowywanie danych wyjściowych z pliku wsadowego

Tworzę plik wsadowy z kilkoma prostymi poleceniami do zbierania informacji z systemu. Plik wsadowy zawiera polecenia, aby uzyskać czas, informacje o adresie IP, użytkowników itp.

Zebrałem wszystkie polecenia w pliku wsadowym i działa, ale chciałbym, aby plik wsadowy po uruchomieniu wyprowadzał wyniki do pliku tekstowego (dziennika). Czy jest polecenie, które mogę dodać do partii, które to zrobi?

Należy pamiętać, że nie chcę uruchamiać partii z cmd, a następnie przekierowywać dane wyjściowe; Chcę przekierować dane wyjściowe z wnętrza wsadu, jeśli to możliwe.

Prosty, naiwny sposób, który jest powolny, ponieważ wielokrotnie otwiera i ustawia wskaźnik pliku na koniec pliku.

@echo off
command1 >output.txt
command2 >>output.txt
...
commandN >>output.txt

Lepszy sposób - łatwiejszy do napisania i szybszy, ponieważ plik jest otwierany i pozycjonowany tylko raz.

@echo off
>output.txt (
  command1
  command2
  ...
  commandN
)

Kolejny dobry i szybki sposób, który otwiera i pozycjonuje plik tylko raz

@echo off
call :sub >output.txt
exit /b

:sub
command1
command2
...
commandN

Edytuj 2020-04-17

Od czasu do czasu możesz chcieć wielokrotnie pisać do dwóch lub więcej plików. Możesz także chcieć wyświetlać różne komunikaty na ekranie. Nadal można to zrobić efektywnie, przekierowując do niezdefiniowanych uchwytów poza blokiem lub podprogramem umieszczonym w nawiasach, a następnie używać &notacji do odwoływania się do już otwartych plików.

call :sub 9>File1.txt 8>File2.txt
exit /b

:sub
echo Screen message 1
>&9 File 1 message 1
>&8 File 2 message 1
echo Screen message 2
>&9 File 1 message 2
>&8 File 2 message 2
exit /b

Zdecydowałem się użyć uchwytów 9 i 8 w odwrotnej kolejności, ponieważ w ten sposób bardziej prawdopodobne jest uniknięcie potencjalnego trwałego przekierowania z powodu błędu projektowego implementacji przekierowania firmy Microsoft podczas wykonywania wielu przekierowań dla tego samego polecenia. Jest to mało prawdopodobne, ale nawet takie podejście może ujawnić błąd, jeśli spróbujesz wystarczająco mocno. Jeśli przygotujesz przekierowanie, na pewno unikniesz problemu.

3>File1.txt ( 4>File2.txt call :sub)
exit /b

:sub
etc.

jeśli chcesz przekierować strumienie out i err

dir >> a.txt 2>&1

Wiem, że to starszy post, ale ktoś natknie się na niego w wyszukiwarce Google i wygląda na to, że niektóre pytania, które OP zadał w komentarzach, nie zostały szczegółowo omówione. Ponadto, proszę, bądź dla mnie łagodny, ponieważ jest to moja pierwsza odpowiedź opublikowana w SO. :)

Aby przekierować dane wyjściowe do pliku przy użyciu dynamicznie generowanej nazwy pliku, moje podejście do (czytaj: szybkie i brudne) jest drugim rozwiązaniem oferowanym przez @dbenham. Na przykład to:

@echo off
> filename_prefix-%DATE:~-4%-%DATE:~4,2%-%DATE:~7,2%_%time:~0,2%%time:~3,2%%time:~6,2%.log (
echo Your Name Here
echo Beginning Date/Time: %DATE:~-4%-%DATE:~4,2%-%DATE:~7,2%_%time:~0,2%%time:~3,2%%time:~6,2%.log
REM do some stuff here
echo Your Name Here
echo Ending Date/Time: %DATE:~-4%-%DATE:~4,2%-%DATE:~7,2%_%time:~0,2%%time:~3,2%%time:~6,2%.log
)

Utworzy plik podobny do tego, który widzisz na tym zrzucie ekranu pliku w katalogu docelowym

To będzie zawierać następujące dane wyjściowe:

Your Name Here
Beginning Date/Time: 2016-09-16_141048.log
Your Name Here
Ending Date/Time: 2016-09-16_141048.log

Pamiętaj również, że to rozwiązanie jest zależne od lokalizacji, więc uważaj, jak i kiedy go używasz.

echo some output >"your logfile"

lub

(
 echo some output
 echo more output
)>"Your logfile"

powinien wypełnić rachunek.

Jeśli chcesz uzyskać APPENDdane wyjściowe, użyj >>zamiast >. >uruchomi nowy plik dziennika.

@echo off
>output.txt (
echo Checking your system infor, Please wating...

systeminfo | findstr /c:"Host Name" 
systeminfo | findstr /c:"Domain"

ipconfig /all | find "Physical Address" 

ipconfig | find "IPv4" 
ipconfig | find "Default Gateway"

)

@pause

Jest fajny mały program, którego możesz użyć do przekierowania wyjścia do pliku i konsoli

some_command  ^|  TEE.BAT  [ -a ]  filename 

@ECHO OFF
:: Check Windows version
IF NOT "%OS%"=="Windows_NT" GOTO Syntax

:: Keep variables local
SETLOCAL

:: Check command line arguments
SET Append=0
IF /I [%1]==[-a] (
	SET Append=1
	SHIFT
)
IF     [%1]==[] GOTO Syntax
IF NOT [%2]==[] GOTO Syntax

:: Test for invalid wildcards
SET Counter=0
FOR /F %%A IN ('DIR /A /B %1 2^>NUL') DO CALL :Count "%%~fA"
IF %Counter% GTR 1 (
	SET Counter=
	GOTO Syntax
)

:: A valid filename seems to have been specified
SET File=%1

:: Check if a directory with the specified name exists
DIR /AD %File% >NUL 2>NUL
IF NOT ERRORLEVEL 1 (
	SET File=
	GOTO Syntax
)

:: Specify /Y switch for Windows 2000 / XP COPY command
SET Y=
VER | FIND "Windows NT" > NUL
IF ERRORLEVEL 1 SET Y=/Y

:: Flush existing file or create new one if -a wasn't specified
IF %Append%==0 (COPY %Y% NUL %File% > NUL 2>&1)

:: Actual TEE
FOR /F "tokens=1* delims=]" %%A IN ('FIND /N /V ""') DO (
	>  CON    ECHO.%%B
	>> %File% ECHO.%%B
)

:: Done
ENDLOCAL
GOTO:EOF

:Count
SET /A Counter += 1
SET File=%1
GOTO:EOF

:Syntax
ECHO.
ECHO Tee.bat,  Version 2.11a for Windows NT 4 / 2000 / XP
ECHO Display text on screen and redirect it to a file simultaneously
ECHO.
IF NOT "%OS%"=="Windows_NT" ECHO Usage:  some_command  ³  TEE.BAT  [ -a ]  filename
IF NOT "%OS%"=="Windows_NT" GOTO Skip
ECHO Usage:  some_command  ^|  TEE.BAT  [ -a ]  filename
:Skip
ECHO.
ECHO Where:  "some_command" is the command whose output should be redirected
ECHO         "filename"     is the file the output should be redirected to
ECHO         -a             appends the output of the command to the file,
ECHO                        rather than overwriting the file
ECHO.
ECHO Written by Rob van der Woude
ECHO http://www.robvanderwoude.com
ECHO Modified by Kees Couprie
ECHO http://kees.couprie.org
ECHO and Andrew Cameron

Dodaj te dwie linie w górnej części pliku wsadowego, wszystkie stdout i stderr po zostaną przekierowane do log.txt:

if not "%1"=="STDOUT_TO_FILE"  %0 STDOUT_TO_FILE %*  >log.txt 2>&1
shift /1

@echo OFF
[your command] >> [Your log file name].txt

Użyłem powyższego polecenia w moim pliku wsadowym i działa. W pliku dziennika pokazuje wyniki mojego polecenia.

Może to się nie powieść w przypadku „toksycznych” znaków na wejściu. Rozważenie takich danych wejściowych, jak this IsAnIn ^^^^, jest dobrym sposobem, aby zrozumieć, co się dzieje. Jasne, że istnieje zasada, że ​​ciąg wejściowy MUSI znajdować się w podwójnych cudzysłowach, ale mam wrażenie, że ta reguła jest prawidłowa tylko wtedy, gdy znaczenie wejścia jest lokalizacją na partycji NTFS (może jest to reguła dla adresów URL I nie jestem pewien). Ale oczywiście nie jest to regułą dla dowolnego ciągu wejściowego (jest to „dobra praktyka”, ale nie można na to liczyć).

Dodanie następujących wierszy u dołu pliku wsadowego spowoduje pobranie wszystkiego tak, jak jest wyświetlane w oknie CMD i wyeksportowanie do pliku tekstowego:

powershell -c "$wshell = New-Object -ComObject wscript.shell; $wshell.SendKeys('^a')
powershell -c "$wshell = New-Object -ComObject wscript.shell; $wshell.SendKeys('^c')
powershell Get-Clipboard > MyLog.txt

Zasadniczo wykonuje zaznaczenie wszystkiego -> skopiuj do schowka -> wklej do pliku tekstowego .