Czy vim może monitorować zmiany w pliku w czasie rzeczywistym

Moje pytanie jest podobne do tego, jak monitorować plik tekstowy w czasie rzeczywistym, ale chcę to zrobić w vimie. Wiem, że mogę odczytać otwarty plik użycia tail -f sample.xmlpliku, a gdy nowa zawartość zostanie zapisana w pliku, zapisze również nową zawartość na moim ekranie. Czy mogę pozwolić, aby vim automatycznie wypełnił nowe dane, gdy plik jest aktualizowany?

Możesz :set autoreadtak, aby vim czytał plik, gdy się zmieni. Jednak (w zależności od platformy) musisz skupić się na tym.

Z pomocy:

Kiedy wykryto, że plik został zmieniony poza Vimem i nie został zmieniony wewnątrz Vima, automatycznie przeczytaj go ponownie. Po usunięciu pliku nie jest to wykonywane.

Nie wiem automatycznie, ale możesz wpisać:

:e!

aby ponownie załadować plik

Umieść w swoim .vimrc:

"sprawdź raz po 4 s bezczynności w trybie normalnym
ustaw autoread                                                                                                                                                                                    
au CursorHold * checktime                                                                                                                                                                       

jak @flukus powiedział w komentarzu do poprzedniej odpowiedzi , możesz call feedkeys["lh"](przesuwa kursor w prawo iz powrotem w lewo, co normalnie nie szkodzi podczas przeglądania pliku dziennika)

Tak więc, jeśli połączysz resztę odpowiedzi , masz oneliner, który możesz w razie potrzeby uruchomić z ex (whithin vim):

:set autoread | au CursorHold * checktime | call feedkeys("lh")

(jeśli chcesz przeskoczyć (prawie) na koniec pliku, po prostu użyj „G” zamiast „lh” z kluczami kanałów)

Objaśnienie:
- autoread : czyta plik po zmianie z zewnątrz (ale nie działa samodzielnie, nie ma wewnętrznego timera lub czegoś podobnego. Czyta plik tylko wtedy, gdy vim wykona akcję, jak polecenie w ex :!
- CursorHold * checktime : gdy kursor nie jest przesuwany przez użytkownika przez czas określony w 'updatetime' (który domyślnie wynosi 4000 milisekund) wykonywany jest checktime, który sprawdza zmiany spoza pliku
- wywołaj feedkeys ("lh") : kursor jest przesuwany raz, w prawo iz powrotem w lewo. i wtedy nic się nie dzieje (... co oznacza, że ​​wyzwalany jest CursorHold, co oznacza, że ​​mamy pętlę )

Dodatkowo możesz :set syntax=logtalkpokolorować dziennik

Aby zatrzymać przewijanie podczas używania call feedkeys("G"), wykonaj :set noautoread- teraz vim powie, że plik został zmieniony i zapyta, czy chcesz odczytać zmiany, czy nie)

(Czy ma to jakieś skutki uboczne?)

Edycja: Widzę jeden efekt uboczny: jeśli użyje się "G" es klucz kanału, przewinie się w dół każdy aktualnie otwarty bufor ?! Tak więc nie można pracować w lewym buforze podzielonego okna, podczas gdy prawy bufor automatycznie przewija plik dziennika

Umieść to w swoim .vimrc i powinno działać jak szef. (Zaczerpnięte z: http://vim.wikia.com/wiki/Have_Vim_check_automatically_if_the_file_has_changed_externally )

" Function to Watch for changes if buffer changed on disk
function! WatchForChanges(bufname, ...)
  " Figure out which options are in effect
  if a:bufname == '*'
    let id = 'WatchForChanges'.'AnyBuffer'
    " If you try to do checktime *, you'll get E93: More than one match for * is given
    let bufspec = ''
  else
    if bufnr(a:bufname) == -1
      echoerr "Buffer " . a:bufname . " doesn't exist"
      return
    end
    let id = 'WatchForChanges'.bufnr(a:bufname)
    let bufspec = a:bufname
  end
  if len(a:000) == 0
    let options = {}
  else
    if type(a:1) == type({})
      let options = a:1
    else
      echoerr "Argument must be a Dict"
    end
  end
  let autoread    = has_key(options, 'autoread')    ? options['autoread']    : 0
  let toggle      = has_key(options, 'toggle')      ? options['toggle']      : 0
  let disable     = has_key(options, 'disable')     ? options['disable']     : 0
  let more_events = has_key(options, 'more_events') ? options['more_events'] : 1
  let while_in_this_buffer_only = has_key(options, 'while_in_this_buffer_only') ? options['while_in_this_buffer_only'] : 0
  if while_in_this_buffer_only
    let event_bufspec = a:bufname
  else
    let event_bufspec = '*'
  end
  let reg_saved = @"
  "let autoread_saved = &autoread
  let msg = "\n"
  " Check to see if the autocommand already exists
  redir @"
    silent! exec 'au '.id
  redir END
  let l:defined = (@" !~ 'E216: No such group or event:')
  " If not yet defined...
  if !l:defined
    if l:autoread
      let msg = msg . 'Autoread enabled - '
      if a:bufname == '*'
        set autoread
      else
        setlocal autoread
      end
    end
    silent! exec 'augroup '.id
      if a:bufname != '*'
        "exec "au BufDelete    ".a:bufname . " :silent! au! ".id . " | silent! augroup! ".id
        "exec "au BufDelete    ".a:bufname . " :echomsg 'Removing autocommands for ".id."' | au! ".id . " | augroup! ".id
        exec "au BufDelete    ".a:bufname . " execute 'au! ".id."' | execute 'augroup! ".id."'"
      end
        exec "au BufEnter     ".event_bufspec . " :checktime ".bufspec
        exec "au CursorHold   ".event_bufspec . " :checktime ".bufspec
        exec "au CursorHoldI  ".event_bufspec . " :checktime ".bufspec
      " The following events might slow things down so we provide a way to disable them...
      " vim docs warn:
      "   Careful: Don't do anything that the user does
      "   not expect or that is slow.
      if more_events
        exec "au CursorMoved  ".event_bufspec . " :checktime ".bufspec
        exec "au CursorMovedI ".event_bufspec . " :checktime ".bufspec
      end
    augroup END
    let msg = msg . 'Now watching ' . bufspec . ' for external updates...'
  end
  " If they want to disable it, or it is defined and they want to toggle it,
  if l:disable || (l:toggle && l:defined)
    if l:autoread
      let msg = msg . 'Autoread disabled - '
      if a:bufname == '*'
        set noautoread
      else
        setlocal noautoread
      end
    end
    " Using an autogroup allows us to remove it easily with the following
    " command. If we do not use an autogroup, we cannot remove this
    " single :checktime command
    " augroup! checkforupdates
    silent! exec 'au! '.id
    silent! exec 'augroup! '.id
    let msg = msg . 'No longer watching ' . bufspec . ' for external updates.'
  elseif l:defined
    let msg = msg . 'Already watching ' . bufspec . ' for external updates'
  end
  echo msg
  let @"=reg_saved
endfunction

let autoreadargs={'autoread':1}
execute WatchForChanges("*",autoreadargs)

Tail Bundle powinien robić, co chcesz. Uwaga, sam z tego nie korzystałem.

Jeśli unix + neovim

:term tail -f <filename>

Oczywiście to nie zadziała dla wszystkich, ale tak to robię.

Jest też wtyczka:

https://github.com/djoshea/vim-autoread

To był jedyny sposób, w jaki mogłem to działać na OSX.

VIM ostrzeże Cię, gdy plik zostanie zaktualizowany, abyś nie nadpisał zmian, które zostały wprowadzone od czasu jego otwarcia. W tym momencie wyświetli się monit o ponowne załadowanie pliku.