Muszę sprawdzić, czy zmienna jest ustawiona, czy nie. Wypróbowałem kilka technik, ale wydaje się, że zawodzą, gdy %1są otoczone cytatami, na przykład w przypadku, gdy %1jest "c:\some path with spaces".

IF NOT %1 GOTO MyLabel // This is invalid syntax
IF "%1" == "" GOTO MyLabel // Works unless %1 has double quotes which fatally kills bat execution
IF %1 == GOTO MyLabel // Gives an unexpected GOTO error.

Według tej witryny są to obsługiwane IFtypy składni. Więc nie widzę sposobu, aby to zrobić.

IF [NOT] ERRORLEVEL number command
IF [NOT] string1==string2 command
IF [NOT] EXIST filename command

Użyj nawiasów kwadratowych zamiast cudzysłowów:

IF [%1] == [] GOTO MyLabel

Nawiasy są niepewne : używaj tylko nawiasów kwadratowych.

Możesz użyć:

IF "%~1" == "" GOTO MyLabel

aby usunąć zewnętrzny zestaw cytatów. Ogólnie rzecz biorąc, jest to bardziej niezawodna metoda niż stosowanie nawiasów kwadratowych, ponieważ będzie działać, nawet jeśli zmienna zawiera spacje.

Jednym z najlepszych rozwiązań semi jest skopiowanie %1do zmiennej, a następnie użycie opóźnionego rozwinięcia, jako delayedExp. jest zawsze bezpieczny w przypadku jakichkolwiek treści.

set "param1=%~1"
setlocal EnableDelayedExpansion
if "!param1!"=="" ( echo it is empty )
rem ... or use the DEFINED keyword now
if defined param1 echo There is something

Zaletą tego jest to, że radzenie sobie z param1 jest całkowicie bezpieczne.

Ustawienie parametru param1 będzie działać w wielu przypadkach, na przykład

test.bat hello"this is"a"test
test.bat you^&me

Ale nadal zawodzi z dziwnymi treściami takimi jak

test.bat ^&"&

Aby uzyskać 100% poprawną odpowiedź na istnienie

Wykrywa, czy %1jest pusty, ale w przypadku niektórych treści nie może pobrać zawartości.
Może to być również przydatne do rozróżnienia pustego %1i jednego z "".
Wykorzystuje zdolność CALLpolecenia do niepowodzenia bez przerywania pliku wsadowego.

@echo off
setlocal EnableDelayedExpansion
set "arg1="
call set "arg1=%%1"

if defined arg1 goto :arg_exists

set "arg1=#"
call set "arg1=%%1"
if "!arg1!" EQU "#" (
    echo arg1 exists, but can't assigned to a variable
    REM Try to fetch it a second time without quotes
    (call set arg1=%%1)
    goto :arg_exists
)

echo arg1 is missing
exit /b

:arg_exists
echo arg1 exists, perhaps the content is '!arg1!'

Jeśli chcesz być w 100% odporny na pociski, aby pobrać zawartość, przeczytaj artykuł Jak otrzymać nawet najdziwniejsze parametry wiersza poleceń?

Z IF / ?:

Jeśli rozszerzenia poleceń są włączone, JEŻELI zmieni się w następujący sposób:

IF [/I] string1 compare-op string2 command
IF CMDEXTVERSION number command
IF DEFINED variable command

......

Warunek DEFINED działa podobnie jak EXISTS, z tym że przyjmuje nazwę zmiennej środowiskowej i zwraca true, jeśli zmienna środowiskowa jest zdefiniowana.

Niestety nie mam wystarczającej reputacji, aby komentować lub głosować nad aktualnymi odpowiedziami, na które musiałem napisać własną.

Pierwotnie pytanie OP brzmiało „zmienna”, a nie „parametr”, co stało się bardzo mylące, zwłaszcza, że ​​był to numer jeden w wyszukiwarce Google do wyszukiwania pustych zmiennych. Od czasu mojej pierwotnej odpowiedzi Stephan zredagował pierwotne pytanie, aby użyć poprawnej terminologii, ale zamiast usunąć moją odpowiedź, postanowiłem ją zostawić, aby pomóc w rozwiązaniu wszelkich nieporozumień, szczególnie w przypadku, gdy Google nadal wysyła tu ludzi po zmienne:

% 1 NIE JEST ZMIENNY! TO PARAMETR LINII POLECEŃ.

Bardzo ważne rozróżnienie. Pojedynczy znak procentu z liczbą po odnosi się do parametru wiersza polecenia, a nie zmiennej.

Zmienne są ustawiane za pomocą polecenia set i są przywoływane przy użyciu 2 znaków procentowych - jeden przed, a drugi po. Na przykład% myvar%

Aby przetestować pustą zmienną, użyj składni „jeśli nie zdefiniowano” (polecenia jawnie dla zmiennych nie wymagają żadnych znaków procentu), na przykład:

set myvar1=foo  
if not defined myvar1 echo You won't see this because %myvar1% is defined.  
if not defined myvar2 echo You will see this because %myvar2% isn't defined.

(Jeśli chcesz przetestować parametry wiersza poleceń, polecam odnieść się do odpowiedzi jamesdlin.)

Użyj „JEŚLI DEFINIOWANE polecenie zmiennej”, aby przetestować zmienną w pliku wsadowym.

Ale jeśli chcesz przetestować parametry partii, wypróbuj poniższe kody, aby uniknąć trudnych danych wejściowych (takich jak „1 2” lub ab ^> cd)

set tmp="%1"
if "%tmp:"=.%"==".." (
    echo empty
) else (
    echo not empty
)

Testuję z poniższym kodem i jest w porządku.

@echo off

set varEmpty=
if not "%varEmpty%"=="" (
    echo varEmpty is not empty
) else (
    echo varEmpty is empty
)
set varNotEmpty=hasValue
if not "%varNotEmpty%"=="" (
    echo varNotEmpty is not empty
) else (
    echo varNotEmpty is empty
)

Zwykle używam tego:

IF "%1."=="." GOTO MyLabel

Jeśli% 1 jest pusty, IF porówna „.” do "." które oceni prawdę.

Stworzyłem ten mały skrypt wsadowy na podstawie odpowiedzi tutaj, ponieważ istnieje wiele poprawnych. Dodawaj do tego, jeśli korzystasz z tego samego formatu:

REM Parameter-testing

Setlocal EnableDelayedExpansion EnableExtensions

IF NOT "%~1"=="" (echo Percent Tilde 1 failed with quotes) ELSE (echo SUCCESS)
IF NOT [%~1]==[] (echo Percent Tilde 1 failed with brackets) ELSE (echo SUCCESS)
IF NOT  "%1"=="" (echo Quotes one failed) ELSE (echo SUCCESS)
IF NOT [%1]==[] (echo Brackets one failed) ELSE (echo SUCCESS)
IF NOT "%1."=="." (echo Appended dot quotes one failed) ELSE (echo SUCCESS)
IF NOT [%1.]==[.] (echo Appended dot brackets one failed) ELSE (echo SUCCESS)

pause

Pusty ciąg to para double-quotes/ "", możemy po prostu przetestować długość:

set ARG=%1
if not defined ARG goto nomore

set CHAR=%ARG:~2,1%
if defined CHAR goto goon

następnie przetestuj 2 znaki na double-quotes:

if ^%ARG:~1,1% == ^" if ^%ARG:~0,1% == ^" goto blank
::else
goto goon

Oto skrypt wsadowy, z którym możesz grać. Myślę, że właściwie łapie pusty ciąg.

To tylko przykład, wystarczy dostosować 2 (lub 3?) Kroki powyżej zgodnie ze skryptem.

@echo off
if not "%OS%"=="Windows_NT" goto EOF
:: I guess we need enableExtensions, CMIIW
setLocal enableExtensions
set i=0
set script=%0

:LOOP
set /a i=%i%+1

set A1=%1
if not defined A1 goto nomore

:: Assumption:
:: Empty string is (exactly) a pair of double-quotes ("")

:: Step out if str length is more than 2
set C3=%A1:~2,1%
if defined C3 goto goon

:: Check the first and second char for double-quotes
:: Any characters will do fine since we test it *literally*
if ^%A1:~1,1% == ^" if ^%A1:~0,1% == ^" goto blank
goto goon

:goon
echo.args[%i%]: [%1]
shift
goto LOOP

:blank
echo.args[%i%]: [%1] is empty string
shift
goto LOOP

:nomore
echo.
echo.command line:
echo.%script% %*

:EOF

Wynik testu tortur:

.test.bat :: ""  ">"""bl" " "< "">"  (")(") "" :: ""-"  " "( )"">\>" ""
args[1]: [::]
args[2]: [""] is empty string
args[3]: [">"""bl" "]
args[4]: ["< "">"]
args[5]: [(")(")]
args[6]: [""] is empty string
args[7]: [::]
args[8]: [""-"  "]
args[9]: ["( )"">\>"]
args[10]: [""] is empty string

command line:
.test.bat :: ""  ">"""bl" " "< "">"  (")(") "" :: ""-"  " "( )"">\>" ""

Możesz użyć

if defined (variable) echo That's defined!
if not defined (variable) echo Nope. Undefined.

Skrypt 1:

Dane wejściowe („Usuń Quotes.cmd” „To jest test”)

@ECHO OFF

REM Set "string" variable to "first" command line parameter
SET STRING=%1

REM Remove Quotes [Only Remove Quotes if NOT Null]
IF DEFINED STRING SET STRING=%STRING:"=%

REM IF %1 [or String] is NULL GOTO MyLabel
IF NOT DEFINED STRING GOTO MyLabel


REM   OR   IF "." equals "." GOTO MyLabel
IF "%STRING%." == "." GOTO MyLabel

REM GOTO End of File
GOTO :EOF

:MyLabel
ECHO Welcome!

PAUSE

Dane wyjściowe (nie ma,% 1 NIE było puste, puste lub NULL):

Uruchom („Usuń Quotes.cmd”) bez żadnych parametrów z powyższym skryptem 1

Dane wyjściowe (% 1 jest pusty, pusty lub NULL):

Welcome!

Press any key to continue . . .

Uwaga: Jeśli ustawisz zmienną wewnątrz IF ( ) ELSE ( )instrukcji, nie będzie ona dostępna dla DEFINICJI, dopóki nie wyjdzie z instrukcji „JEŻELI” (chyba że włączona jest opcja „Opóźnione rozszerzanie zmiennej”; po włączeniu użyj wykrzyknika „!” Zamiast symbol procentu „%”}.

Na przykład:

Skrypt 2:

Dane wejściowe („Usuń Quotes.cmd” „To jest test”)

@ECHO OFF

SETLOCAL EnableDelayedExpansion

SET STRING=%0
IF 1==1 (
  SET STRING=%1
  ECHO String in IF Statement='%STRING%'
  ECHO String in IF Statement [delayed expansion]='!STRING!'
) 

ECHO String out of IF Statement='%STRING%'

REM Remove Quotes [Only Remove Quotes if NOT Null]
IF DEFINED STRING SET STRING=%STRING:"=%

ECHO String without Quotes=%STRING% 

REM IF %1 is NULL GOTO MyLabel
IF NOT DEFINED STRING GOTO MyLabel

REM GOTO End of File
GOTO :EOF

:MyLabel
ECHO Welcome!

ENDLOCAL
PAUSE

Wynik:

C:\Users\Test>"C:\Users\Test\Documents\Batch Files\Remove Quotes.cmd" "This is a Test"  
String in IF Statement='"C:\Users\Test\Documents\Batch Files\Remove Quotes.cmd"'  
String in IF Statement [delayed expansion]='"This is a Test"'  
String out of IF Statement='"This is a Test"'  
String without Quotes=This is a Test  

C:\Users\Test>  

Uwaga: usunie także cudzysłowy z ciągu.

Na przykład (przy użyciu skryptu 1 lub 2): C: \ Users \ Test \ Documents \ Batch Files> „Usuń Quotes.cmd” „To jest„ test ”

Dane wyjściowe (skrypt 2):

String in IF Statement='"C:\Users\Test\Documents\Batch Files\Remove Quotes.cmd"'  
String in IF Statement [delayed expansion]='"This is "a" Test"'  
String out of IF Statement='"This is "a" Test"'  
String without Quotes=This is a Test  

Wykonaj („Usuń Quotes.cmd”) bez żadnych parametrów w Skrypcie 2:

Wynik:

Welcome!

Press any key to continue . . .

Podsumowując:

set str=%~1
if not defined str ( echo Empty string )

Ten kod wyświetli „Pusty ciąg”, jeśli% 1 to „” lub „albo pusty”. Dodano go do zaakceptowanej odpowiedzi, która jest obecnie niepoprawna.

Miałem wiele problemów z wieloma odpowiedziami w sieci. Większość działa na większość rzeczy, ale zawsze jest narożna skrzynka, która psuje każdą z nich.
Może nie działa, jeśli ma cytaty, może się psuje, jeśli nie ma cudzysłowów, błąd składniowy, jeśli var ma spację, niektóre będą działać tylko na parametrach (w przeciwieństwie do zmiennych środowiskowych), inne techniki pozwalają na puste zestaw cytatów, które należy przekazać jako „zdefiniowane”, a niektóre trudniejsze nie pozwolą na elsepóźniejsze połączenie.

Oto rozwiązanie, z którego jestem zadowolony. Daj mi znać, jeśli znajdziesz skrzynkę narożną, która nie będzie działać.

:ifSet
if "%~1"=="" (Exit /B 1) else (Exit /B 0)

Posiadanie tego podprogramu w skrypcie lub w jego własnym .bat, powinno działać.
Więc jeśli chcesz napisać (pseudo):

if (var)
then something
else somethingElse

Możesz pisać:

(Call :ifSet %var% && (
    Echo something
)) || (
    Echo something else
)

Działa we wszystkich moich testach:

(Call :ifSet && ECHO y) || ECHO n
(Call :ifSet a && ECHO y) || ECHO n
(Call :ifSet "" && ECHO y) || ECHO n
(Call :ifSet "a" && ECHO y) || ECHO n
(Call :ifSet "a a" && ECHO y) || ECHO n

Echo'd n, y, n, y,y

Więcej przykładów:

• Chcesz tylko sprawdzić if?Call :ifSet %var% && Echo set
• Tylko jeśli nie (tylko inne)? Call :ifSet %var% || Echo set
• Sprawdzanie przekazanego argumentu; działa w porządku.Call :ifSet %1 && Echo set
• Nie chciałeś zatkać swoich skryptów / kodu dupe, więc umieściłeś go we własnym ifSet.bat? Nie ma problemu:((Call ifSet.bat %var%) && Echo set) || (Echo not set)

Za pomocą ! zamiast „do sprawdzania pustych ciągów

@echo off
SET a=
SET b=Hello
IF !%a%! == !! echo String a is empty
IF !%b%! == !! echo String b is empty

Dostałem się w niecały miesiąc (mimo że zapytano go 8 lat temu) ... Mam nadzieję, że do tej pory wyszedł poza pliki wsadowe. ;-) Robiłem to cały czas. Nie jestem jednak pewien, jaki jest ostateczny cel. Jeśli jest leniwy jak ja, mój plik go.bat działa na takie rzeczy. (Patrz poniżej) Ale 1, polecenie w OP może być nieprawidłowe, jeśli bezpośrednio używasz danych wejściowych jako polecenia. to znaczy,

"C:/Users/Me"

to niepoprawne polecenie (lub używane, gdy byłeś na innym dysku). Musisz go rozbić na dwie części.

C:
cd /Users/Me

I, 2, co oznacza „zdefiniowany” lub „niezdefiniowany”? GIGO. Używam domyślnego, aby wyłapać błędy. Jeśli dane wejściowe nie zostaną złapane, spada do pomocy (lub domyślnego polecenia). Zatem żadne dane wejściowe nie są błędem. Możesz spróbować cd do wejścia i wychwycić błąd, jeśli taki istnieje. (Ok, przy użyciu pobierania go (tylko jeden paren) jest przechwytywany przez DOS. (Surowe!))

cd "%1"
if %errorlevel% neq 0 goto :error

I, 3, cytaty są potrzebne tylko wokół ścieżki, a nie polecenia. to znaczy,

"cd C:\Users" 

było złe (lub dawniej przywykło), chyba że byłeś na innym dysku.

cd "\Users" 

jest funkcjonalny.

cd "\Users\Dr Whos infinite storage space"

działa, jeśli masz spacje na swojej ścieżce.

@REM go.bat
@REM The @ sigh prevents echo on the current command
@REM The echo on/off turns on/off the echo command. Turn on for debugging
@REM You can't see this.
@echo off
if "help" == "%1" goto :help

if "c" == "%1" C:
if "c" == "%1" goto :done

if "d" == "%1" D:
if "d" == "%1" goto :done

if "home"=="%1" %homedrive%
if "home"=="%1" cd %homepath%
if "home"=="%1" if %errorlevel% neq 0 goto :error
if "home"=="%1" goto :done

if "docs" == "%1" goto :docs

@REM goto :help
echo Default command
cd %1
if %errorlevel% neq 0 goto :error
goto :done

:help
echo "Type go and a code for a location/directory
echo For example
echo go D
echo will change disks (D:)
echo go home
echo will change directories to the users home directory (%homepath%)
echo go pictures
echo will change directories to %homepath%\pictures
echo Notes
echo @ sigh prevents echo on the current command
echo The echo on/off turns on/off the echo command. Turn on for debugging
echo Paths (only) with folder names with spaces need to be inclosed in         quotes (not the ommand)
goto :done

:docs
echo executing "%homedrive%%homepath%\Documents"
%homedrive%
cd "%homepath%\Documents"\test error\
if %errorlevel% neq 0 goto :error
goto :done

:error
echo Error: Input (%1 %2 %3 %4 %5 %6 %7 %8 %9) or command is invalid
echo go help for help
goto :done

:done