w tym parametry w OPENQUERY

Jak mogę użyć parametru wewnątrz sql openquery, takiego jak:

SELECT * FROM OPENQUERY([NameOfLinkedSERVER], 'SELECT * FROM TABLENAME
where field1=@someParameter') T1 INNER JOIN MYSQLSERVER.DATABASE.DBO.TABLENAME
T2 ON T1.PK = T2.PK

Z dokumentacji OPENQUERY wynika, że:

OPENQUERY nie akceptuje zmiennych jako argumentów.

Zobacz ten artykuł, aby obejść ten problem .

AKTUALIZACJA:

Zgodnie z sugestią załączam zalecenia z poniższego artykułu.

Przekaż podstawowe wartości

Gdy znana jest podstawowa instrukcja Transact-SQL, ale musisz przekazać jedną lub więcej określonych wartości, użyj kodu podobnego do następującego przykładu:

DECLARE @TSQL varchar(8000), @VAR char(2)
SELECT  @VAR = 'CA'
SELECT  @TSQL = 'SELECT * FROM OPENQUERY(MyLinkedServer,''SELECT * FROM pubs.dbo.authors WHERE state = ''''' + @VAR + ''''''')'
EXEC (@TSQL)

Przekaż całe zapytanie

Kiedy musisz przekazać całe zapytanie Transact-SQL lub nazwę połączonego serwera (lub oba), użyj kodu podobnego do następującego przykładu:

DECLARE @OPENQUERY nvarchar(4000), @TSQL nvarchar(4000), @LinkedServer nvarchar(4000)
SET @LinkedServer = 'MyLinkedServer'
SET @OPENQUERY = 'SELECT * FROM OPENQUERY('+ @LinkedServer + ','''
SET @TSQL = 'SELECT au_lname, au_id FROM pubs..authors'')' 
EXEC (@OPENQUERY+@TSQL) 

Użyj procedury przechowywanej Sp_executesql

Aby uniknąć wielowarstwowych cudzysłowów, użyj kodu podobnego do poniższego przykładu:

DECLARE @VAR char(2)
SELECT  @VAR = 'CA'
EXEC MyLinkedServer.master.dbo.sp_executesql
N'SELECT * FROM pubs.dbo.authors WHERE state = @state',
N'@state char(2)',
@VAR

Możesz wykonać ciąg za pomocą OPENQUERY, gdy go zbudujesz. Jeśli pójdziesz tą drogą, pomyśl o bezpieczeństwie i uważaj, aby nie łączyć tekstu wprowadzonego przez użytkownika w swoim SQL!

DECLARE @Sql VARCHAR(8000)
SET @Sql = 'SELECT * FROM Tbl WHERE Field1 < ''someVal'' AND Field2 IN '+ @valueList 
SET @Sql = 'SELECT * FROM OPENQUERY(SVRNAME, ''' + REPLACE(@Sql, '''', '''''') + ''')'
EXEC(@Sql)

Ze strony MSDN :

OPENQUERY nie akceptuje zmiennych jako argumentów

Zasadniczo oznacza to, że nie możesz wysłać dynamicznego zapytania. Aby osiągnąć to, co stara się Twoja próbka, spróbuj tego:

SELECT * FROM 
   OPENQUERY([NameOfLinkedSERVER], 'SELECT * FROM TABLENAME') T1 
   INNER JOIN 
   MYSQLSERVER.DATABASE.DBO.TABLENAME T2 ON T1.PK = T2.PK 
where
   T1.field1 = @someParameter

Oczywiście, jeśli tabela TABLENAME zawiera dużą ilość danych, to również przejdzie przez sieć i wydajność może być niska. Z drugiej strony, w przypadku niewielkiej ilości danych, działa to dobrze i pozwala uniknąć narzutów związanych z dynamiczną budową sql (wstrzykiwanie sql, cudzysłowy), których execmoże wymagać to podejście.

Właściwie znaleźliśmy sposób, aby to zrobić:

DECLARE @username varchar(50)
SET @username = 'username'
DECLARE @Output as numeric(18,4)
DECLARE @OpenSelect As nvarchar(500)
SET @OpenSelect = '(SELECT @Output = CAST((CAST(pwdLastSet As bigint) / 864000000000) As numeric(18,4)) FROM OpenQuery (ADSI,''SELECT pwdLastSet
                                FROM  ''''LDAP://domain.net.intra/DC=domain,DC=net,DC=intra''''
                                WHERE objectClass =  ''''User'''' AND sAMAccountName = ''''' + @username + '''''
                          '') AS tblADSI)'
EXEC sp_executesql @OpenSelect, N'@Output numeric(18,4) out', @Output out
SELECT @Output As Outputs

Spowoduje to przypisanie wyniku wykonania OpenQuery w zmiennej @Output.

Przetestowaliśmy pod kątem procedury Store w MSSQL 2012, ale powinno działać z MSSQL 2008+.

Microsoft twierdzi, że sp_executesql (Transact-SQL): dotyczy: SQL Server (od SQL Server 2008 do bieżącej wersji), Windows Azure SQL Database (od wersji początkowej do bieżącej). ( http://msdn.microsoft.com/en-us/library/ms188001.aspx )

DECLARE @guid varchar(36);  select @guid= convert(varchar(36), NEWID() );
/*
    The one caveat to this technique is that ##ContextSpecificGlobal__Temp should ALWAYS have the exact same columns.  
    So make up your global temp table name in the sproc you're using it in and only there!
    In this example I wanted to pass in the name of a global temporary table dynamically.  I have 1 procedure dropping 
    off temporary data in whatever @TableSrc is and another procedure picking it up but we are dynamically passing 
    in the name of our pickup table as a parameter for OPENQUERY.
*/
IF ( OBJECT_ID('tempdb..##ContextSpecificGlobal__Temp' , 'U') IS NULL )
    EXEC ('SELECT * INTO ##ContextSpecificGlobal__Temp FROM OPENQUERY(loopback, ''Select *,''''' +  @guid +''''' as tempid FROM ' + @TableSrc + ''')')
ELSE 
    EXEC ('INSERT ##ContextSpecificGlobal__Temp SELECT * FROM OPENQUERY(loopback, ''Select *,''''' +  @guid +''''' as tempid FROM ' + @TableSrc + ''')')

--If this proc is run frequently we could run into race conditions, that's why we are adding a guid and only deleting
--the data we added to ##ContextSpecificGlobal__Temp
SELECT * INTO #TableSrc FROM ##ContextSpecificGlobal__Temp WHERE tempid = @guid

BEGIN TRAN t1
    IF ( OBJECT_ID('tempdb..##ContextSpecificGlobal__Temp' , 'U') IS NOT NULL ) 
    BEGIN
        -- Here we wipe out our left overs if there if everyones done eating the data
        IF (SELECT COUNT(*) FROM ##ContextSpecificGlobal__Temp) = 0
            DROP TABLE ##ContextSpecificGlobal__Temp
    END
COMMIT TRAN t1

-- YEAH! Now I can use the data from my openquery without wrapping the whole !$#@$@ thing in a string.

SELECT field1 FROM OPENQUERY 
                   ([NameOfLinkedSERVER], 
                   'SELECT field1 FROM TABLENAME') 
                           WHERE field1=@someParameter T1 
                                 INNER JOIN MYSQLSERVER.DATABASE.DBO.TABLENAME           
                                 T2 ON T1.PK = T2.PK

Połącz dynamiczny SQL z OpenQuery. (To trafia do serwera Teradata)

DECLARE 
    @dayOfWk    TINYINT = DATEPART(DW, GETDATE()),
    @qSQL       NVARCHAR(MAX) = '';

SET @qSQL = '
SELECT
    *
FROM
    OPENQUERY(TERASERVER,''
        SELECT DISTINCT
            CASE
                WHEN ' + CAST(@dayOfWk AS NCHAR(1)) + ' = 2
                THEN ''''Monday''''
                ELSE ''''Not Monday''''
            END
        '');';

EXEC sp_executesql @qSQL;

W poniższym przykładzie przekazuję parametr działu do procedury składowanej (spIncreaseTotalsRpt) i w tym samym czasie tworzę tabelę tymczasową z OPENQUERY. Tabela Temp musi być globalną tabelą Temp (##), aby można było się do niej odwoływać poza jej intencją. Używając exec sp_executesql, możesz przekazać parametr działu.

Uwaga: zachowaj ostrożność podczas używania sp_executeSQL. Również Twój administrator może nie mieć dostępnej dla Ciebie tej opcji.

Mam nadzieję, że to komuś pomoże.

 IF OBJECT_ID('tempdb..##Temp') IS NOT NULL
/*Then it exists*/
    begin
       DROP TABLE ##Temp
    end 
 Declare @Dept as nvarchar(20) ='''47'''

 declare @OPENQUERY  as nvarchar(max)
set @OPENQUERY = 'Select ' + @Dept + ' AS Dept,  * into ##Temp from openquery(SQL_AWSPROD01,''' 

declare @sql nvarchar(max)= @openquery +  'SET FMTONLY OFF EXECUTE SalaryCompensation.dbo.spIncreaseTotalsRpts ' + '''' + @Dept + ''''  + ''')'
declare @parmdef nvarchar(25) 
DECLARE @param nvarchar(20) 

SET @parmdef = N'@Dept varchar(20)'
-- select @sql
-- Print @sql + @parmdef  + @dept
exec sp_executesql @sql,@parmdef, @Dept  
Select * from ##Temp

Wyniki

Wzrost depozytu Cnt 0 1 2 3 4 5 6 0,0000 1,0000 0,0000 0,0000 0,0000 0,0000 0,0000 0,0000

Znalazłem sposób, który działa dla mnie. Wymaga to jednak użycia tabeli zdrapek, do której serwer połączony ma dostęp.

Utworzyłem tabelę i wypełniłem ją potrzebnymi wartościami, a następnie odwołuję się do tej tabeli za pośrednictwem połączonego serwera.

SELECT * 
FROM OPENQUERY(KHSSQLODSPRD,'SELECT *
  FROM ABC.dbo.CLAIM A WITH (NOLOCK)
  WHERE A.DOS >= (SELECT MAX(DATE) FROM KHSDASQL01.DA_MAIN.[dbo].[ALLFILENAMES]) ')

declare @p_Id varchar(10)
SET @p_Id = '40381'

EXECUTE ('BEGIN update TableName
                set     ColumnName1 = null,
                        ColumnName2 = null,
                        ColumnName3 = null,
                        ColumnName4 = null
                 where   PERSONID = '+ @p_Id +'; END;') AT [linked_Server_Name]

executeZamiast tego możemy użyć metody openquery. Jego kod jest znacznie bardziej przejrzysty. Musiałem uzyskać linked serverwynik zapytania w zmiennej. Użyłem następującego kodu.

CREATE TABLE #selected_store
(
   code VARCHAR(250),
   id INT
)
declare @storeId as integer = 25
insert into #selected_store (id, code) execute('SELECT store_id, code from quickstartproductionnew.store where store_id = ?', @storeId) at [MYSQL]  

declare @code as varchar(100)
select @code = code from #selected_store
select @code
drop table #selected_store

Uwaga:

jeśli twoje zapytanie nie działa, upewnij się, że remote proc transaction promotionjest ustawione tak jak falsedla twojego linked serverpołączenia.

EXEC master.dbo.sp_serveroption
       @server = N'{linked server name}',
       @optname = N'remote proc transaction promotion',
       @optvalue = N'false';

Prosty przykład oparty na przykładzie @Tuan Zaidi, który wydawał się najłatwiejszy. Nie wiedziałem, że możesz zrobić filtr na zewnątrz OPENQUERY ... o wiele łatwiej!

Jednak w moim przypadku musiałem umieścić go w zmiennej, więc utworzyłem dodatkowy Sub Query Level, aby zwrócić pojedynczą wartość.

SET @SFID = (SELECT T.Id FROM (SELECT Id,  Contact_ID_SQL__c  FROM OPENQUERY([TR-SF-PROD], 'SELECT Id,  Contact_ID_SQL__c FROM Contact') WHERE Contact_ID_SQL__c = @ContactID) T)