Uzyskaj listę przekazanych argumentów w skrypcie wsadowym systemu Windows (.bat)

Chciałbym znaleźć partię Bash dla Windows, $@która zawiera listę wszystkich argumentów przekazanych do skryptu.

A może muszę się przejmować shift?

dancavallaro ma rację, %*dla wszystkich parametrów wiersza poleceń (z wyjątkiem samej nazwy skryptu). Przydatne mogą być również:

%0- komenda używana do wywołania pliku wsadowego (może być foo, ..\foo, c:\bats\foo.bat, itd.)
%1To pierwszy parametr wiersza poleceń,
%2to drugi parametr linii poleceń,
i tak dalej aż do %9(iSHIFT mogą być wykorzystywane do tych po 9).

%~nx0- rzeczywista nazwa pliku wsadowego, niezależnie od metody wywołania (some-batch.bat)
%~dp0- dysk i ścieżka do skryptu (d: \ scripts)
%~dpnx0- to pełna nazwa ścieżki skryptu (d: \ scripts \ some -batch.bat)

Więcej informacji przykłady na https://www.ss64.com/nt/syntax-args.html i https://www.robvanderwoude.com/parameters.html

%* wydaje się, że zawiera wszystkie argumenty przekazane do skryptu.

%1... %ni %*przechowuje argumenty, ale dostęp do nich może być trudny, ponieważ treść zostanie zinterpretowana.
Dlatego niemożliwe jest radzenie sobie z czymś takim za pomocą zwykłych instrukcji

myBatch.bat "&"^&

Każda linia kończy się niepowodzeniem, ponieważ cmd.exe próbuje wykonać jeden z ampersandów (zawartość% 1 to "&"&)

set var=%1
set "var=%1"
set var=%~1
set "var=%~1"

Istnieje jednak obejście z plikiem tymczasowym

@echo off
SETLOCAL DisableDelayedExpansion

SETLOCAL
for %%a in (1) do (
    set "prompt=$_"
    echo on
    for %%b in (1) do rem * #%1#
    @echo off
) > param.txt
ENDLOCAL

for /F "delims=" %%L in (param.txt) do (
  set "param1=%%L"
)
SETLOCAL EnableDelayedExpansion
set "param1=!param1:*#=!"
set "param1=!param1:~0,-2!"
echo %%1 is '!param1!'

Sztuką jest włączenie echo oni rozwinięcie instrukcji %1after rem(działa również z% 2 ..% *).
Ale aby móc przekierować wyjście echo on, potrzebujesz dwóch FOR-LOOPS.

Dodatkowe znaki * #są używane, aby zabezpieczyć się przed takimi treściami jak /?(pokaże pomoc dla REM).
Lub karetka ^ na końcu linii może działać jako znak wielowierszowy.

FOR / F powinien działać z opóźnionym rozszerzaniem wyłączonym, w przeciwnym razie zawartość „!” zostanie zniszczony.
Po usunięciu dodatkowych znaków param1i masz go.

Aby używać param1w bezpieczny sposób, włącz opóźnioną ekspansję.

Edycja: Jedna uwaga do% 0

%0zawiera polecenie użyte do wywołania partii, zachowując także wielkość liter, jak w przypadku FoO.BaT
Ale po wywołaniu funkcji, %0a także %~0zawiera nazwę funkcji (lub lepiej ciąg, który został użyty do wywołania funkcji).
Ale %~f0nadal możesz przypomnieć sobie nazwę pliku.

@echo off
echo main %0, %~0, %~f0
call :myLabel+xyz
exit /b

:MYlabel
echo func %0, %~0, %~f0
exit /b

Wynik

main test.bat, test.bat, C:\temp\test.bat
func :myLabel+xyz, :myLabel+xyz, C:\temp\test.bat

Zauważyłem, że następnym razem, gdy będziesz musiał sprawdzić te informacje. Zamiast otwierać przeglądarkę i google, możesz po prostu wpisać call /?cmd, a otrzymasz:

...

%* in a batch script refers to all the arguments (e.g. %1 %2 %3
    %4 %5 ...)

Substitution of batch parameters (%n) has been enhanced.  You can
now use the following optional syntax:

    %~1         - expands %1 removing any surrounding quotes (")
    %~f1        - expands %1 to a fully qualified path name
    %~d1        - expands %1 to a drive letter only
    %~p1        - expands %1 to a path only
    %~n1        - expands %1 to a file name only
    %~x1        - expands %1 to a file extension only
    %~s1        - expanded path contains short names only
    %~a1        - expands %1 to file attributes
    %~t1        - expands %1 to date/time of file
    %~z1        - expands %1 to size of file
    %~$PATH:1   - searches the directories listed in the PATH
                   environment variable and expands %1 to the fully
                   qualified name of the first one found.  If the
                   environment variable name is not defined or the
                   file is not found by the search, then this
                   modifier expands to the empty string

The modifiers can be combined to get compound results:

    %~dp1       - expands %1 to a drive letter and path only
    %~nx1       - expands %1 to a file name and extension only
    %~dp$PATH:1 - searches the directories listed in the PATH
                   environment variable for %1 and expands to the
                   drive letter and path of the first one found.
    %~ftza1     - expands %1 to a DIR like output line

In the above examples %1 and PATH can be replaced by other
valid values.  The %~ syntax is terminated by a valid argument
number.  The %~ modifiers may not be used with %*

Sposób na odzyskanie wszystkich argumentów do skryptu jest tutaj:

@ECHO off
ECHO The %~nx0 script args are...
for %%I IN (%*) DO ECHO %%I
pause

Oto dość prosty sposób na uzyskanie argumentów i ustawienie ich jako zmiennych env. W tym przykładzie będę po prostu nazywał je Kluczami i Wartościami.

Zapisz następujący przykład kodu jako „args.bat”. Następnie wywołaj plik wsadowy zapisany z wiersza polecenia. przykład: arg.bat --x 90 --y 120

Podałem kilka poleceń echa, które przeprowadzą cię przez ten proces. Ale końcowy wynik jest taki, że --x będzie miało wartość 90, a --y będzie miało wartość 120 (to znaczy, jeśli uruchomisz przykład jak podano powyżej ;-)).

Następnie możesz użyć instrukcji warunkowej „jeśli zdefiniowano”, aby ustalić, czy uruchomić blok kodu. Powiedzmy, więc uruchom: „arg.bat --x hello-world” Mógłbym wtedy użyć wyrażenia „JEŚLI OSTATECZNIE - x echo% - x%”, a wynikiem byłoby „hello-world”. Bardziej sensowne powinno być uruchomienie partii.

@setlocal enableextensions enabledelayedexpansion
@ECHO off
ECHO.
ECHO :::::::::::::::::::::::::: arg.bat example :::::::::::::::::::::::::::::::
ECHO :: By:      User2631477, 2013-07-29                                   ::
ECHO :: Version: 1.0                                                         ::
ECHO :: Purpose: Checks the args passed to the batch.                        ::
ECHO ::                                                                      ::
ECHO :: Start by gathering all the args with the %%* in a for loop.          ::
ECHO ::                                                                      ::
ECHO :: Now we use a 'for' loop to search for our keys which are identified  ::
ECHO :: by the text '--'. The function then sets the --arg ^= to the next    ::
ECHO :: arg. "CALL:Function_GetValue" ^<search for --^> ^<each arg^>         ::
ECHO ::                                                                      ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

ECHO.

ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: From the command line you could pass... arg.bat --x 90 --y 220       ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
ECHO.Checking Args:"%*"

FOR %%a IN (%*) do (
    CALL:Function_GetValue "--","%%a" 
)

ECHO.
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: Now lets check which args were set to variables...                   ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: For this we are using the CALL:Function_Show_Defined "--x,--y,--z"   ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
CALL:Function_Show_Defined "--x,--y,--z"
endlocal
goto done

:Function_GetValue

REM First we use find string to locate and search for the text.
echo.%~2 | findstr /C:"%~1" 1>nul

REM Next we check the errorlevel return to see if it contains a key or a value
REM and set the appropriate action.

if not errorlevel 1 (
  SET KEY=%~2
) ELSE (
  SET VALUE=%~2
)
IF DEFINED VALUE (
    SET %KEY%=%~2
    ECHO.
    ECHO ::::::::::::::::::::::::: %~0 ::::::::::::::::::::::::::::::
    ECHO :: The KEY:'%KEY%' is now set to the VALUE:'%VALUE%'                     ::
    ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    ECHO.
    ECHO %KEY%=%~2
    ECHO.
    REM It's important to clear the definitions for the key and value in order to
    REM search for the next key value set.
    SET KEY=
    SET VALUE=
)
GOTO:EOF

:Function_Show_Defined 
ECHO.
ECHO ::::::::::::::::::: %~0 ::::::::::::::::::::::::::::::::
ECHO :: Checks which args were defined i.e. %~2
ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
SET ARGS=%~1
for %%s in (%ARGS%) DO (
    ECHO.
    ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    ECHO :: For the ARG: '%%s'                         
    IF DEFINED %%s (
        ECHO :: Defined as: '%%s=!%%s!'                                             
    ) else (
        ECHO :: Not Defined '%%s' and thus has no value.
    )
    ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    ECHO.
)
goto:EOF

:done

Aby użyć pętli, aby uzyskać wszystkie argumenty w czystej partii:

Obs: Do użytku bez:?*&<>

@echo off && setlocal EnableDelayedExpansion

for %%Z in (%*)do set "_arg_=%%Z" && set/a "_cnt+=1+0" && call set "_arg_[!_cnt!]=!_arg_!")

:: write/test these arguments/parameters ::
for /l %%l in (1 1 !_cnt!)do echo/ The argument n:%%l is: !_arg_[%%l]!

goto :eof 

Twój kod jest gotowy do zrobienia czegoś z numerem argumentu, w którym potrzebuje, na przykład ...

@echo off && setlocal EnableDelayedExpansion

for %%Z in (%*)do set "_arg_=%%Z" && set/a "_cnt+=1+0" && call set "_arg_[!_cnt!]=!_arg_!"

echo= !_arg_[1]! !_arg_[2]! !_arg_[2]!> log.txt

Poniższy kod symuluje tablicę (' params') - pobiera parametry otrzymane przez skrypt i zapisuje je w zmiennych params_1.. params_n, gdzie n= params_0= liczba elementów tablicy:

@echo off

rem Storing the program parameters into the array 'params':
rem Delayed expansion is left disabled in order not to interpret "!" in program parameters' values;
rem however, if a parameter is not quoted, special characters in it (like "^", "&", "|") get interpreted at program launch
set /a count=0
:repeat
    set /a count+=1
    set "params_%count%=%~1"
    shift
    if defined params_%count% (
        goto :repeat
    ) else (
        set /a count-=1
    )    
set /a params_0=count

rem Printing the program parameters stored in the array 'params':
rem After the variables params_1 .. params_n are set with the program parameters' values, delayed expansion can
rem be enabled and "!" are not interpreted in the variables params_1 .. params_n values
setlocal enabledelayedexpansion
    for /l %%i in (1,1,!params_0!) do (
        echo params_%%i: "!params_%%i!"
    )
endlocal

pause
goto :eof

Jeśli masz parametry w cudzysłowie zawierające spacje, %*nie będzie działać poprawnie. Najlepszym rozwiązaniem, jakie znalazłem, jest pętla łącząca wszystkie argumenty: https://serverfault.com/a/22541

set args=%1
shift
:start
if [%1] == [] goto done
set args=%args% %1
shift
goto start

:done
(use %args% here)

Możesz użyć ForCommad, aby uzyskać listę Arg.

Pomoc: For /? Pomoc:Setlocal /?

Oto moja droga =

@echo off
::For Run Use This = cmd /c ""Args.cmd" Hello USER Scientist etc"
setlocal EnableDelayedExpansion
set /a Count=0
for %%I IN (%*) DO (
 Echo Arg_!Count! = %%I
 set /a Count+=1 
)
Echo Count Of Args = !Count!
Endlocal

Nie potrzebujesz polecenia Shift.

@echo wyłączone
:początek

:: Wpisz swój kod tutaj
echo. %% 1 jest teraz:% ~ 1
:: Zakończ wstaw swój kod tutaj

jeśli „% ~ 2” NEQ ”(
    Zmiana
    goto: start
)

Wiele powyższych informacji doprowadziło mnie do dalszych badań i ostatecznie mojej odpowiedzi, więc chciałem przekazać to, co skończyłem, mając nadzieję, że pomoże to komuś innemu:

• Chciałem również przekazać zmienną liczbę zmiennych do pliku wsadowego, aby mogły być przetwarzane w tym pliku.

• Nie przeszkadzało mi przekazywanie ich do pliku wsadowego za pomocą cudzysłowów

• Chciałbym, aby były przetwarzane podobnie jak poniżej - ale używając pętli zamiast pisać ręcznie:

Więc chciałem to wykonać:

prog_ZipDeleteFiles.bat "_appPath=C:\Services\Logs\PCAP" "_appFile=PCAP*.?"

I za pomocą magii pętli for wykonaj to w pliku wsadowym:

set "_appPath=C:\Services\Logs\PCAP"
set "_appFile=PCAP*.?"

Problemem było to, że wszystkie moje próby użycia pętli for nie działały. Poniższy przykład:

for /f "tokens* delims= " in %%A (%*) DO (
   set %%A
)

po prostu zrobiłby:

set "_appPath=C:\Services\Logs\PCAP"

i nie:

set "_appPath=C:\Services\Logs\PCAP"
set "_appFile=PCAP*.?"

nawet po ustawieniu

SETLOCAL EnableDelayedExpansion

Powodem było to, że pętla for odczytała całą linię i przypisała mój drugi parametr do %% B podczas pierwszej iteracji pętli. Ponieważ% * reprezentuje wszystkie argumenty, do przetworzenia jest tylko jedna linia - ergo następuje tylko jedno przejście pętli for. Okazuje się, że jest to zgodne z projektem, a moja logika była błędna.

Przestałem więc próbować używać pętli for i uprościłem to, co próbowałem zrobić, używając instrukcji if, shift i goto. Zgodziłem się, że to trochę hack, ale bardziej odpowiada moim potrzebom. Mogę przeglądać wszystkie argumenty, a następnie użyć instrukcji if, aby wyjść z pętli po przetworzeniu ich wszystkich.

Zwycięskie oświadczenie za to, co próbowałem osiągnąć:

echo on
:processArguments
:: Process all arguments in the order received
if defined %1 then (
    set %1
    shift
    goto:processArguments
) ELSE (
    echo off 
)

AKTUALIZACJA - musiałem zmodyfikować poniżej, ujawniłem wszystkie zmienne środowiskowe, próbując odwołać się do% 1 i używając shift w ten sposób:

echo on
shift
:processArguments
:: Process all arguments in the order received
if defined %0 then (
    set %0
    shift
    goto:processArguments
) ELSE (
    echo off 
)

Czasami muszę wyodrębnić kilka parametrów wiersza poleceń, ale nie wszystkie i nie z pierwszego. Załóżmy następujące połączenie:

Test.bat uno dos tres cuatro cinco seis siete

Oczywiście rozszerzenie „.bat” nie jest potrzebne, przynajmniej masz test.exe w tym samym folderze. Chcemy uzyskać wynik „tres cuatro cinco” (bez względu na to, czy jedna linia, czy trzy). Chodzi o to, że tylko ja potrzebuję trzech parametrów i zaczynam od trzeciego. Aby mieć prosty przykład, akcja dla każdego z nich to po prostu „echo”, ale możesz pomyśleć o innej, bardziej złożonej akcji nad wybranymi parametrami.

Przedstawiłem kilka przykładów (opcji), abyś mógł zobaczyć, który z nich uważasz za lepszy. Niestety, nie ma przyjemnego (lub nie wiem o tym) sposobu opartego na pętli for w zakresie takim jak „for %% i in (% 3, 1,% 5)”.

@echo off 
setlocal EnableDelayedExpansion

echo Option 1: one by one (same line)
echo %3, %4, %5
echo.

echo Option 2: Loop For one by one
for %%a in (%3, %4, %5) do echo %%a
echo.

echo Option 3: Loop For with check of limits
set i=0
for %%a in (%*) do (
    set /A i=i+1
    If !i! GTR 2 if !i! LSS 6 echo %%a
)
echo.

echo Option 4: Loop For with auxiliary list
for /l %%i in (3,1,5) do  (
    set a=%%i
    set b=echo %%
    set b=!b!!a!
    call !b!
)
echo.

echo Option 5: Assigning to an array of elements previously
set e[0]=%0
set i=0 
for %%a in (%*) do (
    set /A i=i+1
    set e[!i!]=%%a
)
for  /l %%i in (3,1,5) do (
    echo !e[%%i]!
)
echo.

echo Option 6: using shift and goto loop. It doesn't work with for loop
set i=2
:loop6
    set /A i=i+1
    echo %3
    shift
    If %i% LSS 5 goto :loop6

Prawdopodobnie możesz znaleźć więcej opcji lub połączyć kilka. Ciesz się nimi.

Wersja Windows (wymaga jednak socat)

C:\Program Files (x86)\Git\bin>type gitproxy.cmd
socat STDIO PROXY:proxy.mycompany.de:%1:%2,proxyport=3128

konfigurowanie:

C:\Users\exhau\AppData\Roaming\npm>git config --global core.gitproxy gitproxy.cmd