Jak zresetować sekwencję w Oracle?

W PostgreSQL mogę zrobić coś takiego:

ALTER SEQUENCE serial RESTART WITH 0;

Czy istnieje odpowiednik Oracle?

Oto dobra procedura resetowania dowolnej sekwencji do 0 od guru Oracle, Toma Kyte . Świetna dyskusja na temat zalet i wad również w poniższych linkach.

tkyte@TKYTE901.US.ORACLE.COM> 
create or replace
procedure reset_seq( p_seq_name in varchar2 )
is
    l_val number;
begin
    execute immediate
    'select ' || p_seq_name || '.nextval from dual' INTO l_val;

    execute immediate
    'alter sequence ' || p_seq_name || ' increment by -' || l_val || 
                                                          ' minvalue 0';

    execute immediate
    'select ' || p_seq_name || '.nextval from dual' INTO l_val;

    execute immediate
    'alter sequence ' || p_seq_name || ' increment by 1 minvalue 0';
end;
/

Z tej strony: Dynamiczny SQL do resetowania wartości sekwencji
Kolejna dobra dyskusja jest tutaj: Jak zresetować sekwencje?

Prawdziwy restart nie jest możliwy AFAIK . (Proszę popraw mnie jeżeli się mylę!).

Jeśli jednak chcesz ustawić go na 0, możesz go po prostu usunąć i ponownie utworzyć.

Jeśli chcesz ustawić go na określoną wartość, możesz ustawić INCREMENT na wartość ujemną i uzyskać następną wartość.

Oznacza to, że jeśli twoja sekwencja ma wartość 500, możesz ustawić ją na 100 za pośrednictwem

ALTER SEQUENCE serial INCREMENT BY -400;
SELECT serial.NEXTVAL FROM dual;
ALTER SEQUENCE serial INCREMENT BY 1;

To jest moje podejście:

1. upuść sekwencję
2. odtworzyć to

Przykład:

--Drop sequence

DROP SEQUENCE MY_SEQ;

-- Create sequence 

create sequence MY_SEQ
minvalue 1
maxvalue 999999999999999999999
start with 1
increment by 1
cache 20;

alter sequence serial restart start with 1;

Ta funkcja została oficjalnie dodana w 18c, ale jest nieoficjalnie dostępna w wersji 12.1.

Korzystanie z tej nieudokumentowanej funkcji w wersji 12.1 jest prawdopodobnie bezpieczne. Mimo że składnia nie jest uwzględniona w oficjalnej dokumentacji , jest generowana przez pakiet Oracle DBMS_METADATA_DIFF . Używałem go kilka razy w systemach produkcyjnych. Jednak utworzyłem żądanie usługi Oracle Service i potwierdzili, że nie jest to błąd dokumentacji, funkcja jest naprawdę nieobsługiwana.

W wersji 18c funkcja nie pojawia się w składni języka SQL, ale została uwzględniona w Podręczniku administratora bazy danych .

Moje podejście jest młodzieńczym rozszerzeniem przykładu Dougmana .

Rozszerzenia są ...

Przekaż wartość początkową jako parametr. Czemu? Lubię nazywać tę rzecz resetującą sekwencję z powrotem do maksymalnego ID używanego w jakiejś tabeli . W końcu wywołuję ten proces z innego skryptu, który wykonuje wiele wywołań dla całej grupy sekwencji, resetując wartość nextval z powrotem do pewnego poziomu, który jest wystarczająco wysoki, aby nie powodować naruszeń klucza podstawowego, w którym używam wartości sekwencji dla unikalnego identyfikatora.

Uwzględnia również poprzednią minvalue . W rzeczywistości może przesunąć następną wartość jeszcze wyżej, jeśli pożądana wartość p_value lub istniejąca wartość minimalna są wyższe niż bieżąca lub obliczona następna wartość.

Co najlepsze, można go wywołać w celu zresetowania do określonej wartości i po prostu poczekaj, aż na końcu pojawi się procedura „napraw wszystkie moje sekwencje”.

create or replace
procedure Reset_Sequence( p_seq_name in varchar2, p_val in number default 0)
is
  l_current number := 0;
  l_difference number := 0;
  l_minvalue user_sequences.min_value%type := 0;

begin

  select min_value
  into l_minvalue
  from user_sequences
  where sequence_name = p_seq_name;

  execute immediate
  'select ' || p_seq_name || '.nextval from dual' INTO l_current;

  if p_Val < l_minvalue then
    l_difference := l_minvalue - l_current;
  else
    l_difference := p_Val - l_current;
  end if;

  if l_difference = 0 then
    return;
  end if;

  execute immediate
    'alter sequence ' || p_seq_name || ' increment by ' || l_difference || 
       ' minvalue ' || l_minvalue;

  execute immediate
    'select ' || p_seq_name || '.nextval from dual' INTO l_difference;

  execute immediate
    'alter sequence ' || p_seq_name || ' increment by 1 minvalue ' || l_minvalue;
end Reset_Sequence;

Ta procedura jest użyteczna sama w sobie, ale teraz dodajmy kolejną, która ją wywołuje i określa wszystko programowo z konwencją nazewnictwa sekwencji i szuka maksymalnej wartości używanej w istniejącej tabeli / polu ...

create or replace
procedure Reset_Sequence_to_Data(
  p_TableName varchar2,
  p_FieldName varchar2
)
is
  l_MaxUsed NUMBER;
BEGIN

  execute immediate
    'select coalesce(max(' || p_FieldName || '),0) from '|| p_TableName into l_MaxUsed;

  Reset_Sequence( p_TableName || '_' || p_Fieldname || '_SEQ', l_MaxUsed );

END Reset_Sequence_to_Data;

Teraz gotujemy na gazie!

Powyższa procedura sprawdzi maksymalną wartość pola w tabeli, zbuduje nazwę sekwencji z pary tabela / pole i wywoła "Reset_Sequence" z tą odczytaną wartością maksymalną.

Ostatni element tej układanki i wisienka na torcie jest następny ...

create or replace
procedure Reset_All_Sequences
is
BEGIN

  Reset_Sequence_to_Data( 'ACTIVITYLOG', 'LOGID' );
  Reset_Sequence_to_Data( 'JOBSTATE', 'JOBID' );
  Reset_Sequence_to_Data( 'BATCH', 'BATCHID' );

END Reset_All_Sequences;

W mojej aktualnej bazie danych istnieje około stu innych sekwencji resetowanych za pomocą tego mechanizmu, więc w powyższej procedurze jest jeszcze 97 wywołań Reset_Sequence_to_Data .

Kocham to? Nienawidzisz tego? Obojętny?

Poniższy skrypt ustawia sekwencję na żądaną wartość:

Biorąc pod uwagę świeżo utworzoną sekwencję o nazwie PCS_PROJ_KEY_SEQ i tabelę PCS_PROJ:

BEGIN
   DECLARE
      PROJ_KEY_MAX       NUMBER := 0;
      PROJ_KEY_CURRVAL   NUMBER := 0;
   BEGIN

    SELECT MAX (PROJ_KEY) INTO PROJ_KEY_MAX FROM PCS_PROJ;
    EXECUTE IMMEDIATE 'ALTER SEQUENCE PCS_PROJ_KEY_SEQ INCREMENT BY ' || PROJ_KEY_MAX;
    SELECT PCS_PROJ_KEY_SEQ.NEXTVAL INTO PROJ_KEY_CURRVAL FROM DUAL;
    EXECUTE IMMEDIATE 'ALTER SEQUENCE PCS_PROJ_KEY_SEQ INCREMENT BY 1';

END;
END;
/

Ta procedura składowana uruchamia ponownie moją sekwencję:

Create or Replace Procedure Reset_Sequence  
  is
  SeqNbr Number;
begin
   /*  Reset Sequence 'seqXRef_RowID' to 0    */
   Execute Immediate 'Select seqXRef.nextval from dual ' Into SeqNbr;
   Execute Immediate 'Alter sequence  seqXRef increment by - ' || TO_CHAR(SeqNbr) ;
   Execute Immediate 'Select seqXRef.nextval from dual ' Into SeqNbr;
   Execute Immediate 'Alter sequence  seqXRef increment by 1';
END;

/

Istnieje inny sposób resetowania sekwencji w Oracle: ustaw właściwości maxvaluei cycle. Kiedy nextvalsekwencja osiągnie wartość maxvalue, jeśli cyclewłaściwość jest ustawiona, rozpocznie się ponownie odminvalue sekwencji.

Zaleta tej metody w porównaniu z ustawieniem negatywu increment by jest to, że sekwencja może być nadal używana podczas trwania procesu resetowania, co zmniejsza prawdopodobieństwo wystąpienia jakiejś formy wyłączenia w celu wykonania resetu.

Wartość for maxvaluemusi być większa niż bieżąca nextval, więc poniższa procedura zawiera opcjonalny parametr zezwalający na buforowanie w przypadku ponownego uzyskania dostępu do sekwencji między wybraniem nextvalw procedurze a ustawieniem cyclewłaściwości.

create sequence s start with 1 increment by 1;

select s.nextval from dual
connect by level <= 20;

   NEXTVAL
----------
         1 
...
        20

create or replace procedure reset_sequence ( i_buffer in pls_integer default 0)
as
  maxval pls_integer;
begin

  maxval := s.nextval + greatest(i_buffer, 0); --ensure we don't go backwards!
  execute immediate 'alter sequence s cycle minvalue 0 maxvalue ' || maxval;
  maxval := s.nextval;
  execute immediate 'alter sequence s nocycle maxvalue 99999999999999';

end;
/
show errors

exec reset_sequence;

select s.nextval from dual;

   NEXTVAL
----------
         1 

Procedura w obecnym stanie pozwala na możliwość, że inna sesja pobierze wartość 0, co może, ale nie musi, stanowić problem dla Ciebie. Jeśli tak, zawsze możesz:

• Ustaw minvalue 1w pierwszym ołtarzu
• Wyklucz drugie nextvalpobranie
• Przenieś instrukcję, aby ustawić nocyclewłaściwość do innej procedury, która ma zostać uruchomiona w późniejszym terminie (zakładając, że chcesz to zrobić).

Jezus, całe to programowanie dla samego restartu indeksu ... Może jestem idiotą, ale dla wersji pre-oracle 12 (która ma funkcję restartu), co jest nie tak z prostym:

drop sequence blah;
create sequence blah 

?

1) Załóżmy, że tworzysz SEKWENCJĘ, jak pokazano poniżej:

CREATE SEQUENCE TESTSEQ
INCREMENT BY 1
MINVALUE 1
MAXVALUE 500
NOCACHE
NOCYCLE
NOORDER

2) Teraz pobierasz wartości z SEQUENCE. Powiedzmy, że pobrałem cztery razy, jak pokazano poniżej.

SELECT TESTSEQ.NEXTVAL FROM dual
SELECT TESTSEQ.NEXTVAL FROM dual
SELECT TESTSEQ.NEXTVAL FROM dual
SELECT TESTSEQ.NEXTVAL FROM dual

3) Po wykonaniu powyższych czterech poleceń wartość SEKWENCJI wyniesie 4. Teraz przypuśćmy, że ponownie zresetowałem wartość SEKWENCJI do 1. Wykonaj następujące kroki. Wykonaj wszystkie kroki w tej samej kolejności, jak pokazano poniżej:

1. ALTER SEQUENCE TESTSEQ INCREMENT BY -3;
2. SELECT TESTSEQ.NEXTVAL FROM dual
3. ALTER SEQUENCE TESTSEQ INCREMENT BY 1;
4. SELECT TESTSEQ.NEXTVAL FROM dual

Zmiana wartości INCREMENT sekwencji, zwiększenie jej, a następnie zmiana z powrotem jest dość bezbolesna, a ponadto masz dodatkową korzyść polegającą na tym, że nie musisz ponownie ustalać wszystkich grantów, tak jak w przypadku upuszczenia / odtworzenia sekwencji.

Tworzę blok, aby zresetować wszystkie moje sekwencje:

DECLARE
    I_val number;
BEGIN
    FOR US IN
        (SELECT US.SEQUENCE_NAME FROM USER_SEQUENCES US)
    LOOP
        execute immediate 'select ' || US.SEQUENCE_NAME || '.nextval from dual' INTO l_val;
        execute immediate 'alter sequence ' || US.SEQUENCE_NAME || ' increment by -' || l_val || ' minvalue 0';
        execute immediate 'select ' || US.SEQUENCE_NAME || '.nextval from dual' INTO l_val;
        execute immediate 'alter sequence ' || US.SEQUENCE_NAME || ' increment by 1 minvalue 0';
    END LOOP;
END;

Oto bardziej niezawodna procedura zmiany następnej wartości zwracanej przez sekwencję, a także dużo więcej.

• Po pierwsze, chroni przed atakami typu SQL injection, ponieważ żaden z przekazanych ciągów nie jest używany do bezpośredniego tworzenia żadnych dynamicznych instrukcji SQL,
• Po drugie, zapobiega ustawieniu następnej wartości sekwencji poza granicami minimalnych lub maksymalnych wartości sekwencji. next_valueBędzie! = min_valueI pomiędzy min_valuei max_value.
• Po trzecie, increment_bypodczas czyszczenia bierze pod uwagę obecne (lub proponowane) ustawienie, a także wszystkie inne ustawienia sekwencji.
• Po czwarte, wszystkie parametry z wyjątkiem pierwszego są opcjonalne i jeśli nie określono inaczej, przyjmują bieżące ustawienia sekwencji jako wartości domyślne. Jeśli nie określono parametrów opcjonalnych, nie jest podejmowane żadne działanie.
• Wreszcie, jeśli spróbujesz zmienić sekwencję, która nie istnieje (lub nie należy do bieżącego użytkownika), spowoduje to zgłoszenie ORA-01403: no data foundbłędu.

Oto kod:

CREATE OR REPLACE PROCEDURE alter_sequence(
    seq_name      user_sequences.sequence_name%TYPE
  , next_value    user_sequences.last_number%TYPE := null
  , increment_by  user_sequences.increment_by%TYPE := null
  , min_value     user_sequences.min_value%TYPE := null
  , max_value     user_sequences.max_value%TYPE := null
  , cycle_flag    user_sequences.cycle_flag%TYPE := null
  , cache_size    user_sequences.cache_size%TYPE := null
  , order_flag    user_sequences.order_flag%TYPE := null)
  AUTHID CURRENT_USER
AS
  l_seq user_sequences%rowtype;
  l_old_cache user_sequences.cache_size%TYPE;
  l_next user_sequences.min_value%TYPE;
BEGIN
  -- Get current sequence settings as defaults
  SELECT * INTO l_seq FROM user_sequences WHERE sequence_name = seq_name;

  -- Update target settings
  l_old_cache := l_seq.cache_size;
  l_seq.increment_by := nvl(increment_by, l_seq.increment_by);
  l_seq.min_value    := nvl(min_value, l_seq.min_value);
  l_seq.max_value    := nvl(max_value, l_seq.max_value);
  l_seq.cycle_flag   := nvl(cycle_flag, l_seq.cycle_flag);
  l_seq.cache_size   := nvl(cache_size, l_seq.cache_size);
  l_seq.order_flag   := nvl(order_flag, l_seq.order_flag);

  IF next_value is NOT NULL THEN
    -- Determine next value without exceeding limits
    l_next := LEAST(GREATEST(next_value, l_seq.min_value+1),l_seq.max_value);

    -- Grab the actual latest seq number
    EXECUTE IMMEDIATE
        'ALTER SEQUENCE '||l_seq.sequence_name
            || ' INCREMENT BY 1'
            || ' MINVALUE '||least(l_seq.min_value,l_seq.last_number-l_old_cache)
            || ' MAXVALUE '||greatest(l_seq.max_value,l_seq.last_number)
            || ' NOCACHE'
            || ' ORDER';
    EXECUTE IMMEDIATE 
      'SELECT '||l_seq.sequence_name||'.NEXTVAL FROM DUAL'
    INTO l_seq.last_number;

    l_next := l_next-l_seq.last_number-1;

    -- Reset the sequence number
    IF l_next <> 0 THEN
      EXECUTE IMMEDIATE 
        'ALTER SEQUENCE '||l_seq.sequence_name
            || ' INCREMENT BY '||l_next
            || ' MINVALUE '||least(l_seq.min_value,l_seq.last_number)
            || ' MAXVALUE '||greatest(l_seq.max_value,l_seq.last_number)
            || ' NOCACHE'
            || ' ORDER';
      EXECUTE IMMEDIATE 
        'SELECT '||l_seq.sequence_name||'.NEXTVAL FROM DUAL'
      INTO l_next;
    END IF;
  END IF;

  -- Prepare Sequence for next use.
  IF COALESCE( cycle_flag
             , next_value
             , increment_by
             , min_value
             , max_value
             , cache_size
             , order_flag) IS NOT NULL
  THEN
    EXECUTE IMMEDIATE 
      'ALTER SEQUENCE '||l_seq.sequence_name
          || ' INCREMENT BY '||l_seq.increment_by
          || ' MINVALUE '||l_seq.min_value
          || ' MAXVALUE '||l_seq.max_value
          || CASE l_seq.cycle_flag
             WHEN 'Y' THEN ' CYCLE' ELSE ' NOCYCLE' END
          || CASE l_seq.cache_size
             WHEN 0 THEN ' NOCACHE'
             ELSE ' CACHE '||l_seq.cache_size END
          || CASE l_seq.order_flag
             WHEN 'Y' THEN ' ORDER' ELSE ' NOORDER' END;
  END IF;
END;

W moim projekcie kiedyś zdarzyło się, że ktoś ręcznie wprowadzał rekordy bez użycia sekwencji, stąd muszę ręcznie zresetować wartość sekwencji, dla której napisałem poniżej fragment kodu sql:

declare
max_db_value number(10,0);
cur_seq_value number(10,0);
counter number(10,0);
difference number(10,0);
dummy_number number(10);

begin

-- enter table name here
select max(id) into max_db_value from persons;
-- enter sequence name here
select last_number into cur_seq_value from user_sequences where  sequence_name = 'SEQ_PERSONS';

difference  := max_db_value - cur_seq_value;

 for counter in 1..difference
 loop
    -- change sequence name here as well
    select SEQ_PERSONS.nextval into dummy_number from dual;
 end loop;
end;

Pamiętaj, że powyższy kod będzie działał, jeśli sekwencja jest opóźniona.

Możesz skorzystać z opcji CYKL pokazanej poniżej:

CREATE SEQUENCE test_seq
MINVALUE 0
MAXVALUE 100
START WITH 0
INCREMENT BY 1
CYCLE;

W tym przypadku, gdy sekwencja osiągnie MAXVALUE (100), powróci do MINVALUE (0).

W przypadku dekrementowanej sekwencji sekwencja powróci do MAXVALUE.

Oto jak dopasować wszystkie sekwencje autoinkrementacji do rzeczywistych danych:

1. Utwórz procedurę wymuszającą następną wartość, jak już opisano w tym wątku:

   CREATE OR REPLACE PROCEDURE Reset_Sequence(
       P_Seq_Name IN VARCHAR2,
       P_Val      IN NUMBER DEFAULT 0)
   IS
     L_Current    NUMBER                      := 0;
     L_Difference NUMBER                      := 0;
     L_Minvalue User_Sequences.Min_Value%Type := 0;
   BEGIN
     SELECT Min_Value
     INTO L_Minvalue
     FROM User_Sequences
     WHERE Sequence_Name = P_Seq_Name;
     EXECUTE Immediate 'select ' || P_Seq_Name || '.nextval from dual' INTO L_Current;
     IF P_Val        < L_Minvalue THEN
       L_Difference := L_Minvalue - L_Current;
     ELSE
       L_Difference := P_Val - L_Current;
     END IF;
     IF L_Difference = 0 THEN
       RETURN;
     END IF;
     EXECUTE Immediate 'alter sequence ' || P_Seq_Name || ' increment by ' || L_Difference || ' minvalue ' || L_Minvalue;
     EXECUTE Immediate 'select ' || P_Seq_Name || '.nextval from dual' INTO L_Difference;
     EXECUTE Immediate 'alter sequence ' || P_Seq_Name || ' increment by 1 minvalue ' || L_Minvalue;
   END Reset_Sequence;

2. Utwórz inną procedurę, aby uzgodnić wszystkie sekwencje z rzeczywistą zawartością:

   CREATE OR REPLACE PROCEDURE RESET_USER_SEQUENCES_TO_DATA
   IS
     STMT CLOB;
   BEGIN
     SELECT 'select ''BEGIN'' || chr(10) || x || chr(10) || ''END;'' FROM (select listagg(x, chr(10)) within group (order by null) x FROM ('
       || X
       || '))'
     INTO STMT
     FROM
       (SELECT LISTAGG(X, ' union ') WITHIN GROUP (
       ORDER BY NULL) X
       FROM
         (SELECT CHR(10)
           || 'select ''Reset_Sequence('''''
           || SEQ_NAME
           || ''''','' || coalesce(max('
           || COL_NAME
           || '), 0) || '');'' x from '
           || TABLE_NAME X
         FROM
           (SELECT TABLE_NAME,
             REGEXP_SUBSTR(WTEXT, 'NEW\.(\S*) IS NULL',1,1,'i',1) COL_NAME,
             REGEXP_SUBSTR(BTEXT, '(\.|\s)([a-z_]*)\.nextval',1,1,'i',2) SEQ_NAME
           FROM USER_TRIGGERS
           LEFT JOIN
             (SELECT NAME BNAME,
               TEXT BTEXT
             FROM USER_SOURCE
             WHERE TYPE = 'TRIGGER'
             AND UPPER(TEXT) LIKE '%NEXTVAL%'
             )
           ON BNAME = TRIGGER_NAME
           LEFT JOIN
             (SELECT NAME WNAME,
               TEXT WTEXT
             FROM USER_SOURCE
             WHERE TYPE = 'TRIGGER'
             AND UPPER(TEXT) LIKE '%IS NULL%'
             )
           ON WNAME             = TRIGGER_NAME
           WHERE TRIGGER_TYPE   = 'BEFORE EACH ROW'
           AND TRIGGERING_EVENT = 'INSERT'
           )
         )
       ) ;
     EXECUTE IMMEDIATE STMT INTO STMT;
     --dbms_output.put_line(stmt);
     EXECUTE IMMEDIATE STMT;
   END RESET_USER_SEQUENCES_TO_DATA;

UWAGI:

1. Procedura wyodrębnia nazwy z kodu wyzwalacza i nie zależy od konwencji nazewnictwa
2. Aby sprawdzić wygenerowany kod przed wykonaniem, przełącz komentarze w ostatnich dwóch wierszach

Tworzę alternatywę, że użytkownik nie musi znać wartości, system pobiera i używa zmiennych do aktualizacji.

--Atualizando sequence da tabela SIGA_TRANSACAO, pois está desatualizada
DECLARE
 actual_sequence_number INTEGER;
 max_number_from_table INTEGER;
 difference INTEGER;
BEGIN
 SELECT [nome_da_sequence].nextval INTO actual_sequence_number FROM DUAL;
 SELECT MAX([nome_da_coluna]) INTO max_number_from_table FROM [nome_da_tabela];
 SELECT (max_number_from_table-actual_sequence_number) INTO difference FROM DUAL;
IF difference > 0 then
 EXECUTE IMMEDIATE CONCAT('alter sequence [nome_da_sequence] increment by ', difference);
 --aqui ele puxa o próximo valor usando o incremento necessário
 SELECT [nome_da_sequence].nextval INTO actual_sequence_number from dual;
--aqui volta o incremento para 1, para que futuras inserções funcionem normalmente
 EXECUTE IMMEDIATE 'ALTER SEQUENCE [nome_da_sequence] INCREMENT by 1';
 DBMS_OUTPUT.put_line ('A sequence [nome_da_sequence] foi atualizada.');
ELSE
 DBMS_OUTPUT.put_line ('A sequence [nome_da_sequence] NÃO foi atualizada, já estava OK!');
END IF;
END;

Procedura składowana, która zadziałała dla mnie

create or replace
procedure reset_sequence( p_seq_name in varchar2, tablename in varchar2 )
is
    l_val number;
    maxvalueid number;
begin
    execute immediate 'select ' || p_seq_name || '.nextval from dual' INTO l_val;
    execute immediate 'select max(id) from ' || tablename INTO maxvalueid;
    execute immediate 'alter sequence ' || p_seq_name || ' increment by -' || l_val || ' minvalue 0';
    execute immediate 'select ' || p_seq_name || '.nextval from dual' INTO l_val;
    execute immediate 'alter sequence ' || p_seq_name || ' increment by '|| maxvalueid ||' minvalue 0';  
    execute immediate 'select ' || p_seq_name || '.nextval from dual' INTO l_val;
    execute immediate 'alter sequence ' || p_seq_name || ' increment by 1 minvalue 0';
end;

Jak korzystać z procedury składowanej:

execute reset_sequence('company_sequence','company');