Wyrażanie sekwencji podwójnego sumowania w Raku

X(Międzynarodowe operatora) i [+](metaoperator redukcji [ ]z operatorem dodatków +) czynią to zaskakująco proste:

Aby przedstawić ¹ podwójne sumowanie x³ _{x = 1} ∑⁵ _{y = 1} 2x + y , możesz wykonać następujące czynności:

  [+] do for 1..3 X 1..5 -> ($x, $y) { 2 * $x + $y }
#        for 1..3 X 1..5                             # loop cross values
#                        -> ($x, $y)                 # plug into x/y
#                                    { 2 * $x + $y } # calculate each iteration
#     do                                             # collect loop return vals 
# [+]                                                # sum them all

Jeśli chcesz utworzyć subdo tego celu, możesz napisać go w następujący sposób ²

sub ΣΣ (
    Int $aₒ, Int $aₙ,     # to / from for the outer
    Int $bₒ, Int $bₙ,     # to / from for the inner
    &f where .arity = 2   # 'where' clause guarantees only two params
) {
  [+] do for $aₒ..$aₙ X $bₒ..$bₙ -> ($a, $b) { &f(a,b) }
}

say ΣΣ 1,3, 1,5, { 2 * $^x + $^y }

Lub nawet uprościć rzeczy bardziej

sub ΣΣ (
    Iterable \a,            # outer values
    Iterable \b,            # inner values
    &f where .arity = 2) {  # ensure only two parameters
  [+] do f(|$_) for a X b
}

# All of the following are equivalent
say ΣΣ 1..3, 1..5, -> $x, $y { 2 * $x  + $y  }; # Anonymous block
say ΣΣ 1..3, 1..5,           { 2 * $^x + $^y }; # Alphabetic args
say ΣΣ 1..3, 1..5,             2 *  *  +  *   ; # Overkill, but Whatever ;-)

Zauważ, że wpisując go, możemy upewnić się, że zakresy są przekazywane, ale wpisując go Iterablezamiast Range, możemy pozwolić na bardziej interesujące sekwencje sumowania, na przykład, ΣΣ (1..∞).grep(*.is-prime)[^99], 1..10, { … }co pozwoliłoby nam użyć sekwencji pierwszych 100 liczb pierwszych.

W rzeczywistości, jeśli naprawdę chcielibyśmy, moglibyśmy przesadzić i pozwolić na dowolny operator sumowania głębokości, który jest najłatwiejszy, przesuwając funkcję w lewo:

sub ΣΣ (
    &function, 
    **@ranges where                # slurp in the ranges
        .all   ~~ Iterable &&      # make sure they're Iterables 
        .elems == &function.arity  # one per argument in the function
) {
  [+] do function(|$_) for [X] @ranges;
};

Podobnie jak [+]sumuje wszystkie wartości naszej f()funkcji, [X]oblicza krzyżowo iteracyjnie, np. [X] 0..1, 3..4, 5..6Najpierw robi 0..1 X 3..4lub (0,3),(0,4),(1,3),(1,4), a następnie robi (0,3),(0,4),(1,3),(1,4) X 5..6lub (0,3,5),(0,4,5),(1,3,5),(1,4,5),(0,3,6),(0,4,6),(1,3,6),(1,4,6).

^{1. Niestety, SO nie pozwala mi na LaTeX, ale powinieneś o tym pomyśleć. 2. Tak, wiem, że to litera indeksu dolnego O nie zero, numery indeksu dolnego normalnie nie są poprawnymi identyfikatorami, ale możesz użyć Slang :: Subscripts, aby je włączyć.}

użytkownik 0721090601
źródło

Wyrażanie sekwencji podwójnego sumowania w Raku

Odpowiedzi: