Sprawdź, czy istnieje tabela tymczasowa i usuń, jeśli istnieje, przed utworzeniem tabeli tymczasowej

Korzystam z następującego kodu, aby sprawdzić, czy istnieje tabela tymczasowa i upuścić tabelę, jeśli istnieje, przed ponownym utworzeniem. Działa dobrze, dopóki nie zmieniam kolumn. Jeśli dodam kolumnę później, wyświetli się komunikat „nieprawidłowa kolumna”. Daj mi znać, co robię źle.

IF OBJECT_ID('tempdb..#Results') IS NOT NULL
    DROP TABLE #Results

CREATE TABLE #Results
(
    Company                CHAR(3),
    StepId                TINYINT,
    FieldId                TINYINT,
)

select company, stepid, fieldid from #Results

--Works fine to this point

IF OBJECT_ID('tempdb..#Results') IS NOT NULL
    DROP TABLE #Results

CREATE TABLE #Results
(
    Company                CHAR(3),
    StepId                TINYINT,
    FieldId                TINYINT,
    NewColumn            NVARCHAR(50)
)

select company, stepid, fieldid, NewColumn from #Results

--Does not work

Nie mogę odtworzyć błędu.

Być może nie rozumiem problemu.

Poniższe działa dla mnie dobrze w SQL Server 2005, z dodatkową kolumną „foo” pojawiającą się w drugim wyniku wyboru:

IF OBJECT_ID('tempdb..#Results') IS NOT NULL DROP TABLE #Results
GO
CREATE TABLE #Results ( Company CHAR(3), StepId TINYINT, FieldId TINYINT )
GO
select company, stepid, fieldid from #Results
GO
ALTER TABLE #Results ADD foo VARCHAR(50) NULL
GO
select company, stepid, fieldid, foo from #Results
GO
IF OBJECT_ID('tempdb..#Results') IS NOT NULL DROP TABLE #Results
GO

Oświadczenie powinno być uporządkowane

1. Instrukcja Alter dla tabeli
2. UDAĆ SIĘ
3. Wybierz wyciąg.

Bez „GO” pomiędzy nimi, całość będzie traktowana jako pojedynczy skrypt, a kiedy instrukcja select szuka kolumny, nie zostanie znaleziona.

W przypadku „GO” rozważy część skryptu aż do „GO” jako pojedynczą partię i wykona się, zanim przejdzie do zapytania po „GO”.

Zamiast droppingtworzyć tabelę tymczasową truncatei ponownie ją tworzyć, możesz jej ponownie użyć

IF OBJECT_ID('tempdb..#Results') IS NOT NULL
    Truncate TABLE #Results
else
    CREATE TABLE #Results
    (
        Company             CHAR(3),
        StepId              TINYINT,
        FieldId             TINYINT,
    )

Jeśli używasz Sql Server 2016lub Azure Sql Databaseużyj poniższej składni, aby upuścić tabelę tymczasową i ponownie ją utworzyć. Więcej informacji tutaj MSDN

Składnia

DROP TABLE [JEŚLI ISTNIEJE] [nazwa_bazy_danych. [nazwa_schematu]. | nazwa_schematu. ] nazwa_tabeli [, ... n]

Pytanie:

DROP TABLE IF EXISTS tempdb.dbo.#Results
CREATE TABLE #Results
  (
   Company             CHAR(3),
   StepId              TINYINT,
   FieldId             TINYINT,
  )

Myślę, że problem polega na tym, że musisz dodać instrukcję GO pomiędzy, aby rozdzielić wykonanie na partie. Jako drugi skrypt zrzutu, tj. IF OBJECT_ID('tempdb..#Results') IS NOT NULL DROP TABLE #ResultsNie upuścił tabeli temp będącej częścią pojedynczej partii. Czy możesz wypróbować poniższy skrypt?

IF OBJECT_ID('tempdb..#Results') IS NOT NULL
    DROP TABLE #Results

CREATE TABLE #Results
(
    Company                CHAR(3),
    StepId                TINYINT,
    FieldId                TINYINT,
)

GO

select company, stepid, fieldid from #Results

IF OBJECT_ID('tempdb..#Results') IS NOT NULL
DROP TABLE #Results

CREATE TABLE #Results
(
    Company                CHAR(3),
    StepId                TINYINT,
    FieldId                TINYINT,
    NewColumn            NVARCHAR(50)
)

GO

select company, stepid, fieldid, NewColumn from #Results

Można to osiągnąć za pomocą jednego wiersza kodu:

IF OBJECT_ID('tempdb..#tempTableName') IS NOT NULL DROP TABLE #tempTableName;   

To zadziałało dla mnie: social.msdn.microsoft.com/Forums/en/transactsql/thread/02c6da90-954d-487d-a823-e24b891ec1b0?prof=required

if exists (
    select  * from tempdb.dbo.sysobjects o
    where o.xtype in ('U') 

   and o.id = object_id(N'tempdb..#tempTable')
)
DROP TABLE #tempTable;

Tylko mały komentarz z mojej strony, ponieważ OBJECT_IDto nie działa dla mnie. Zawsze to zwraca

`#tempTable nie istnieje

..even choć nie istnieje. Właśnie znalazłem, że jest przechowywany pod inną nazwą (po _podkreśleniu):

#tempTable________

Działa to dla mnie dobrze:

IF EXISTS(SELECT [name] FROM tempdb.sys.tables WHERE [name] like '#tempTable%') BEGIN
   DROP TABLE #tempTable;
END;

Teraz możesz użyć poniższej składni, jeśli korzystasz z jednej z nowych wersji programu SQL Server (2016+).

DROP TABLE IF EXISTS schema.yourtable(even temporary tables #...)

pmac72 używa GO, aby podzielić zapytanie na partie i używa ALTER.

Wygląda na to, że uruchamiasz tę samą partię, ale uruchamiasz ją dwukrotnie po zmianie: DROP ... CREATE ... edit ... DROP ... CREATE ..

Być może opublikuj swój dokładny kod, abyśmy mogli zobaczyć, co się dzieje.

Zazwyczaj trafiam ten błąd, gdy już utworzyłem tabelę tymczasową; kod, który sprawdza, czy w instrukcji SQL nie ma błędów, widzi „starą” tabelę tymczasową na miejscu i zwraca błędne obliczenie liczby kolumn w późniejszych instrukcjach, tak jakby tabela tymczasowa nigdy nie została usunięta.

Po zmianie liczby kolumn w tabeli tymczasowej po utworzeniu wersji z mniejszą liczbą kolumn, upuść tabelę i NASTĘPNIE uruchom zapytanie.

Niedawno widziałem, jak DBA robi coś podobnego do tego:

begin try
    drop table #temp
end try

begin catch 
    print 'table does not exist'
end catch 

create table #temp(a int, b int)

Mój kod używa Sourcetabeli, która się zmienia, i Destinationtabeli, która musi pasować do tych zmian.

-- 
-- Sample SQL to update only rows in a "Destination" Table
--  based on only rows that have changed in a "Source" table
--


--
-- Drop and Create a Temp Table to use as the "Source" Table
--
IF OBJECT_ID('tempdb..#tSource') IS NOT NULL drop table #tSource
create table #tSource (Col1 int, Col2 int, Col3 int, Col4 int)

--
-- Insert some values into the source
--
Insert #tSource (Col1, Col2, Col3, Col4) Values(1,1,1,1)
Insert #tSource (Col1, Col2, Col3, Col4) Values(2,1,1,2)
Insert #tSource (Col1, Col2, Col3, Col4) Values(3,1,1,3)
Insert #tSource (Col1, Col2, Col3, Col4) Values(4,1,1,4)
Insert #tSource (Col1, Col2, Col3, Col4) Values(5,1,1,5)
Insert #tSource (Col1, Col2, Col3, Col4) Values(6,1,1,6)

--
-- Drop and Create a Temp Table to use as the "Destination" Table
--
IF OBJECT_ID('tempdb..#tDest') IS NOT NULL drop Table #tDest
create table #tDest (Col1 int, Col2 int, Col3 int, Col4 int)

--
-- Add all Rows from the Source to the Destination
--
Insert #tDest
Select Col1, Col2, Col3, Col4 from #tSource


--
-- Look at both tables to see that they are the same
--
select *
from #tSource
Select *
from #tDest

--
-- Make some changes to the Source
--
update #tSource
    Set Col3=19
    Where Col1=1
update #tSource
    Set Col3=29
    Where Col1=2
update #tSource
    Set Col2=38
    Where Col1=3
update #tSource
    Set Col2=48
    Where Col1=4

--
-- Look at the Differences
-- Note: Only 4 rows are different. 2 Rows have remained the same.
--
Select Col1, Col2, Col3, Col4
from #tSource
except
Select Col1, Col2, Col3, Col4
from #tDest

--
-- Update only the rows that have changed
-- Note: I am using Col1 like an ID column
--
Update #tDest
    Set Col2=S.Col2,
        Col3=S.Col3,
        Col4=S.Col4
From    (   Select Col1, Col2, Col3, Col4
            from #tSource
            except
            Select Col1, Col2, Col3, Col4
            from #tDest
        ) S
Where #tDest.Col1=S.Col1 

--
-- Look at the tables again to see that
--  the destination table has changed to match
--  the source table.

select *
from #tSource
Select *
from #tDest

--
-- Clean Up
--
drop table #tSource
drop table #tDest

Tak, „nieprawidłowa kolumna” ten błąd podniesiony z wiersza „wybierz firmę, stepid, fieldid, NewColumn z #Results”.

Istnieją dwie fazy uruchamiania t-sql,

po pierwsze, parsowanie, w tej fazie serwer sql sprawdza poprawność przesłanego ciągu sql, w tym kolumny tabeli, i optymalizuje zapytanie, aby uzyskać najszybsze przywracanie.

po drugie, uruchamianie, przywracanie danych.

Jeśli tabela #Results istnieje, wówczas proces analizowania sprawdzi, czy określone kolumny są poprawne, czy nie, w przeciwnym razie (tabela nie istnieje) analizowanie zostanie przekazane zgodnie z podanymi kolumnami sprawdzającymi.

Po zmianie kolumny w tabeli tymczasowej należy usunąć tabelę przed ponownym uruchomieniem zapytania. (Tak, to denerwujące. Właśnie to musisz zrobić.)

Zawsze zakładałem, że dzieje się tak, ponieważ sprawdzanie „niepoprawnej kolumny” jest wykonywane przez analizator składni przed uruchomieniem zapytania, więc jest ono oparte na kolumnach w tabeli przed usunięciem ..... i to również powiedział pnbs.