Używam następującej funkcji

=DAYS360(A2, A35)

obliczyć różnicę między dwiema datami w mojej kolumnie. Jednak kolumna stale się rozszerza i obecnie muszę ręcznie zmienić „A35” podczas aktualizowania arkusza kalkulacyjnego.

Czy istnieje sposób (w Arkuszach Google), aby znaleźć ostatnią niepustą komórkę w tej kolumnie, a następnie dynamicznie ustawić ten parametr w powyższej funkcji?

Może być bardziej wymowny sposób, ale oto, co wymyśliłem:

Funkcja znajdująca ostatnią wypełnioną komórkę w kolumnie to:

=INDEX( FILTER( A:A ; NOT( ISBLANK( A:A ) ) ) ; ROWS( FILTER( A:A ; NOT( ISBLANK( A:A ) ) ) ) )

Więc jeśli połączysz to z obecną funkcją, wyglądałoby to tak:

=DAYS360(A2,INDEX( FILTER( A:A ; NOT( ISBLANK( A:A ) ) ) ; ROWS( FILTER( A:A ; NOT( ISBLANK( A:A ) ) ) ) ))

Aby znaleźć ostatnią niepustą komórkę, możesz użyć INDEXi MATCHfunkcji takich jak:

=DAYS360(A2; INDEX(A:A; MATCH(99^99;A:A; 1)))

Myślę, że jest to trochę szybsze i łatwiejsze.

Jeśli A2: A zawiera daty ciągłe, to INDEKS (A2: A, LICZBA (A2: A)) zwróci ostatnią datę. Ostateczna formuła to

=DAYS360(A2,INDEX(A2:A,COUNT(A2:A)))

Moim ulubionym jest:

=INDEX(A2:A,COUNTA(A2:A),1)

Tak więc na potrzeby PO:

=DAYS360(A2,INDEX(A2:A,COUNTA(A2:A),1))

Jeśli kolumna rozszerzyła się tylko o kolejne dodane daty, tak jak w moim przypadku - użyłem tylko funkcji MAX, aby uzyskać ostatnią datę.

Ostateczna formuła będzie wyglądać następująco:

=DAYS360(A2; MAX(A2:A)) 

Chociaż odpowiedź na to pytanie jest już udzielona, ​​istnieje wymowny sposób, aby to zrobić.

Use just the column name to denote last non-empty row of that column.

Na przykład:

Jeśli Twoje dane są dostępne A1:A100i chcesz mieć możliwość dodania większej ilości danych do kolumny A, powiedzmy, że może być A1:A105lub nawet A1:A1234później, możesz użyć tego zakresu:

A1:A

Aby otrzymać ostatnią niepustą wartość w zakresie, użyjemy 2 funkcji:

• COUNTA
• INDEKS

Odpowiedź jest =INDEX(B3:B,COUNTA(B3:B)).

Oto wyjaśnienie:

COUNTA(range) zwraca liczbę wartości w zakresie, możemy to wykorzystać, aby uzyskać liczbę wierszy.

INDEX(range, row, col)zwraca wartość z zakresu na pozycji rowi col( col=1jeśli nie została określona)

Przykłady:

INDEX(A1:C5,1,1) = A1
INDEX(A1:C5,1) = A1 # implicitly states that col = 1
INDEX(A1:C5,1,2) = A2
INDEX(A1:C5,2,1) = B1
INDEX(A1:C5,2,2) = B2
INDEX(A1:C5,3,1) = C1
INDEX(A1:C5,3,2) = C2

Na powyższym zdjęciu nasz zakres będzie B3:B. Więc będziemy liczyć ile istnieją wartości w przedziale B3:Bod COUNTA(B3:B)pierwszego. Po lewej stronie będzie produkować, 8ponieważ istnieje 8 wartości, a 9po prawej stronie. Wiemy również, że ostatnia wartość znajduje się w pierwszej kolumnie zakresu, B3:Bwięc colparametr INDEXmusi wynosić 1, a rowparametr powinien być COUNTA(B3:B).

PS : proszę, zagłosuj na odpowiedź @ bloodymurderlive, ponieważ napisał ją pierwszy, tylko wyjaśniam to tutaj.

Oto kolejny:

=indirect("A"&max(arrayformula(if(A:A<>"",row(A:A),""))))

Ostateczne równanie jest następujące:

=DAYS360(A2,indirect("A"&max(arrayformula(if(A:A<>"",row(A:A),"")))))

Inne równania tutaj działają, ale podoba mi się to, ponieważ ułatwia uzyskanie numeru wiersza, co wydaje mi się, że muszę robić częściej. Tylko numer wiersza wyglądałby tak:

=max(arrayformula(if(A:A<>"",row(A:A),"")))

Początkowo próbowałem znaleźć to, aby rozwiązać problem z arkuszem kalkulacyjnym, ale nie mogłem znaleźć niczego przydatnego, co po prostu podało numer wiersza ostatniego wpisu, więc mam nadzieję, że jest to pomocne dla kogoś.

Ma to również tę dodatkową zaletę, że działa dla dowolnego typu danych w dowolnej kolejności, a między wierszami z zawartością mogą znajdować się puste wiersze, a nie zlicza komórek z formułami, których wynikiem jest „”. Może również obsługiwać powtarzające się wartości. Podsumowując, jest bardzo podobne do równania, które używa tutaj max ((G: G <> "") * row (G: G)), ale sprawia, że ​​wyciągnięcie numeru wiersza jest trochę łatwiejsze, jeśli tego szukasz .

Alternatywnie, jeśli chcesz umieścić skrypt na swoim arkuszu, możesz sobie to ułatwić, jeśli planujesz dużo to robić. Oto ten fragment:

function lastRow(sheet,column) {
  var ss = SpreadsheetApp.getActiveSpreadsheet();
  if (column == null) {
    if (sheet != null) {
       var sheet = ss.getSheetByName(sheet);
    } else {
      var sheet = ss.getActiveSheet();
    }
    return sheet.getLastRow();
  } else {
    var sheet = ss.getSheetByName(sheet);
    var lastRow = sheet.getLastRow();
    var array = sheet.getRange(column + 1 + ':' + column + lastRow).getValues();
    for (i=0;i<array.length;i++) {
      if (array[i] != '') {       
        var final = i + 1;
      }
    }
    if (final != null) {
      return final;
    } else {
      return 0;
    }
  }
}

Tutaj możesz po prostu wpisać następujące polecenie, jeśli chcesz, aby ostatni wiersz znajdował się w tym samym arkuszu, który obecnie edytujesz:

=LASTROW()

lub jeśli chcesz mieć ostatni wiersz określonej kolumny z tego arkusza lub określonej kolumny z innego arkusza, możesz wykonać następujące czynności:

=LASTROW("Sheet1","A")

I ogólnie dla ostatniego wiersza konkretnego arkusza:

=LASTROW("Sheet1")

Następnie, aby uzyskać rzeczywiste dane, możesz użyć pośredniego:

=INDIRECT("A"&LASTROW())

lub możesz zmodyfikować powyższy skrypt w ostatnich dwóch wierszach powrotu (ostatnie dwa, ponieważ musiałbyś umieścić zarówno arkusz, jak i kolumnę, aby uzyskać rzeczywistą wartość z rzeczywistej kolumny) i zastąpić zmienną następującą:

return sheet.getRange(column + final).getValue();

i

return sheet.getRange(column + lastRow).getValue();

Jedną z zalet tego skryptu jest to, że możesz wybrać, czy chcesz uwzględnić równania, których wynikiem jest „”. Jeśli nie zostaną dodane żadne argumenty, równania obliczane na „” zostaną policzone, ale jeśli określisz arkusz i kolumnę, zostaną zliczone. Ponadto istnieje duża elastyczność, jeśli chcesz używać odmian skryptu.

Prawdopodobnie przesada, ale wszystko możliwe.

A co z tą formułą na uzyskanie ostatniej wartości:

=index(G:G;max((G:G<>"")*row(G:G)))

A to byłaby ostateczna formuła twojego pierwotnego zadania:

=DAYS360(G10;index(G:G;max((G:G<>"")*row(G:G))))

Załóżmy, że data początkowa to G10.

Poszedłem inną drogą. Ponieważ wiem, że będę dodawał coś do wiersza / kolumny jeden po drugim, znajduję ostatni wiersz, licząc najpierw pola, które zawierają dane. Pokażę to za pomocą kolumny:

=COUNT(A5:A34)

Więc powiedzmy, że zwrócone 21. A5 jest o 4 wiersze w dół, więc muszę uzyskać 21. pozycję od czwartego wiersza w dół. Mogę to zrobić używając inderect, na przykład:

=INDIRECT("A"&COUNT(A5:A34)+4)

Znajduje liczbę wierszy z danymi i zwraca liczbę, której używam jako modyfikator indeksu.

dla rzędu:

=ARRAYFORMULA(INDIRECT("A"&MAX(IF(A:A<>"", ROW(A:A), ))))

dla kolumny:

=ARRAYFORMULA(INDIRECT(ADDRESS(1, MAX(IF(1:1<>"", COLUMN(1:1), )), 4)))

Wydaje się, że jest to najprostsze rozwiązanie, jakie znalazłem, aby pobrać ostatnią wartość w stale rozwijającej się kolumnie:

=INDEX(A:A,COUNTA(A:A),1)

To działa dla mnie. Pobierz ostatnią wartość kolumny A w arkuszu Google:

=index(A:A,max(row(A:A)*(A:A<>"")))

(Pomija również puste wiersze między, jeśli istnieją)

Oblicz różnicę między ostatnią datą w kolumnie A a datą w komórce A2.

=MAX(A2:A)-A2

To da zawartość ostatniej komórki:

=indirect("A"&max(ARRAYFORMULA(row(a:a)*--(a:a<>""))))

To da adres ostatniej komórki:

="A"&max(ARRAYFORMULA(row(a:a)*--(a:a<>"")))

To da wiersz ostatniej komórki:

=max(ARRAYFORMULA(row(a:a)*--(a:a<>"")))

Może wolisz scenariusz. Ten skrypt jest znacznie krótszy niż ogromny, który opublikował powyżej ktoś inny:

Przejdź do edytora skryptów i zapisz ten skrypt:

function getLastRow(range){
  while(range.length>0 && range[range.length-1][0]=='') range.pop();
  return range.length;
}

Po wykonaniu tej czynności wystarczy wpisać to w komórce:

=getLastRow(A:A)

Sposób, w jaki robi to amator, to „= CONCATENATE („ A ”, COUNTUNIQUE (A1: A9999))”, gdzie A1 to pierwsza komórka w kolumnie, a A9999 znajduje się niżej w tej kolumnie, niż kiedykolwiek spodziewałem się, że będą miały jakiekolwiek wpisy. Ten wynikowy znak A # może być używany w razie potrzeby z funkcją POŚREDNI.

Aby znaleźć ostatni niepusty numer wiersza (dopuszczając spacje między nimi) użyłem poniżej do wyszukiwania kolumny A.

=ArrayFormula(IFNA(match(2,1/(A:A<>""))))