vimdiff: Przejdź do następnej różnicy w linii?

vimdiffjest bardzo przydatny do porównywania plików. Jednak często używam go w plikach z długimi liniami i stosunkowo niewielkimi różnicami wewnątrz linii.

vimdiff poprawnie podświetli różnice wewnątrz linii (cała linia różowa, różne znaki czerwone). W takich przypadkach miło byłoby móc przeskoczyć do następnej różnicy w linii .

Możesz przejść do „następnej różnicy” ( ]c), ale spowoduje to przejście do następnej linii z różnicą.

Czy istnieje sposób przejścia do następnego innego znaku w bieżącej linii?

Widzę dwa rozwiązania:

1. musisz przetestować bieżące podświetlanie składni, aby przejść do czerwonej części linii.
2. musisz wyodrębnić bieżącą linię z obu buforów i znaleźć pierwszy znak, który różni się od prawidłowego ustawienia kursora

Oba rozwiązania muszą zostać wykonane po] ci wymagają skryptu vim.

EDYCJA: Oto pierwszy szkic, który wydaje się działać:

nnoremap <expr> <silent> <F3>   (&diff ? "]c:call \<sid>NextDiff()\<cr>" : ":cn\<cr>")

function! s:GotoWinline(w_l)
  normal! H
  while winline() < a:w_l
    normal! j
  endwhile
  " todo: beware of cases where the window is too little
endfunction

" Better ]c, [c jump
function! s:NextDiff()
  if ! &diffopt =~ 'filler' | return | endif

  let ignore_blanks = &diffopt =~ 'iwhite'

  " Assert: called just after a ]c or a [c
  " Forces the cursos to be synchronized in all synced windows
  " let diff_l = line()
  try 
    let foldenable = &foldenable
    set nofoldenable

    let w_l = winline() " problematic with enabled lines (from diff...)
    " echomsg w_l.'|'.line('.').'|'.getline('.')

    let lines = {}
    windo if &diff | call <sid>GotoWinline(w_l) | let lines[winnr()]={'text':getline('.'), 'number':line('.')} | endif
  finally
    let &foldenable = foldenable
  endtry

  " echomsg string(lines)
  if len(lines) < 2 | return | endif

  let indices = repeat([0], len(lines))
  let tLines = values(lines)
  let found = 0
  " infinite loop on two empty texts...
  while ! found
    let c = ''
    let next_idx = []
    let i = 0
    while i != len(indices)
      let crt_line = tLines[i].text
      let n = indices[i]
      if len(crt_line) == n
    let found = 1
    break
      endif

      let c2 = (len(crt_line) == n) ? 'EOL' : crt_line[n]
      if empty(c) 
    let c = c2
      endif

      " checks match
      let n += 1
      if c =~ '\s'
    if (c2 != c) && (ignore_blanks && c2 !~ '\s')
      let found = 1
      break
    else " advance
      while ignore_blanks && (n == len(crt_line) || crt_line[n] =~ '\s')
        let n += 1
      endwhile
    endif
      else
    if c2 != c
      let found = 1
      break
    endif
      endif
      let next_idx += [n]

      let i += 1
    endwhile
    if found | break | endif

    let indices = next_idx
  endwhile

  " now goto the right column
  let windows = keys(lines)
  " Assert len(windows) == len(indices)
  let w = 0
  while w != len(windows)
    " echomsg 'W#'.windows[w].' -> :'(tLines[w].number).'normal! '.(indices[w]+1).'|'
    exe windows[w].'wincmd w'
    silent! exe (tLines[w].number).'normal! 0'.(indices[w]).'l'
    let w += 1
  endwhile
  " echomsg string(indices)
endfunction

To łatwe obejście:

Możesz użyć set wrap.

Spowoduje to problemy, jeśli różnica spowoduje zawijanie tekstu w nierównej liczbie wierszy.

Nie mogę wymyślić, jak to zrobić vimdiff, ale możesz to sprawdzić wdiff. Pokazuje różnice między dwoma plikami po jednym słowie.

Musiałem go skompilować ze źródła:

curl http://ftp.gnu.org/gnu/wdiff/wdiff-1.2.1.tar.gz > wdiff-1.2.1.tar.gz
tar -xzvf wdiff-1.2.1.tar.gz
cd wdiff-1.2.1
./configure
make
make install

Sądząc po dokumentacji, nie da się tego zrobić.