AutoHotKey, jak przekazywać / oceniać parametry do funkcji

Mam problem ze zrozumieniem sposobu dostępu do parametrów w funkcjach AutoHotKey.

Na przykład ustawiłem zmienną myVar za pomocą InputBox, a następnie przekazuję ją do funkcji. Jak ocenić arg w funkcji TestFunction?

#t::
    inputbox myVar, What is your variable?
    myNewVar := TestFunction(%myVar%)
    MsgBox %myNewVar% 
    return

TestFunction(arg)
{
    MsgBox arg
    msgBox %arg%
    return %arg%
}    

Co chcę zrobić, to ustawić skrót klawiszowy, który poprosi o słowo kluczowe dla aplikacji, a następnie ocenić, co zostało wprowadzone w funkcji i uruchomić dowolną aplikację odpowiadającą temu słowu kluczowemu.

Dzięki!

Chris

Poprawiłem twój skrypt (tak jak zasugerowałem Bavi_H) i dodałem przykład uruchomienia aplikacji odpowiadającej słowu kluczowemu.

#t::
inputbox myVar, What is your variable?
myNewVar := TestFunction(myVar)
MsgBox %myNewVar% 
return

TestFunction(arg)
{
    msgBox %arg%
    if (arg = "calc")
    {
        run, calc.exe
    }
    else if (arg = "word")
    {
        run, winword.exe
    }
    return arg . "bob"
}

Zasadniczo polecenia, takie jak run, %something%, różnią się od funkcji, takich jak myFunction(something). Oto kolejny przykład oparty na odpowiedzi qwertzguy

#t::
    ; get variable from message box
    inputbox myVar, What is your variable?

    ; myVar DOES NOT have percents when passed to function
    myNewVar := TestFunction(myVar)

    ; myNewVar DOES have percents when passed to command
    MsgBox %myNewVar% 

return


TestFunction(arg)
{
    ; command DOES have percents 
    MsgBox Launching: %arg%

    if (arg = "calc")
    {
        ; commands use traditional variable method
        ; traditional method example: Var = The color is %FoundColor%
        ; variables are evaluated inside quotes

        run, "%A_WinDir%\system32\calc.exe"
    }
    else if (arg = "word")
    {

        ; functions need to use expression version since percents are not evaluated
        ; expression method example: Var := "The color is " . FoundColor
        ; variables are not evaluated inside quotes

        EnvGet, ProgramFilesVar, ProgramFiles(x86)
        OfficeVersionVar := "15"

        RunFunction(ProgramFilesVar . "\Microsoft Office\Office" . OfficeVersionVar . "\WINWORD.EXE")

    }

    return "You typed: " . arg

}



RunFunction(arg)
{
    run, %arg%
}