Czy można zainstalować obraz woluminu EXT4 w systemie Windows 7?

Wykonane z ddrescue.

Zgaduję, że nie.

Możliwym rozwiązaniem byłoby użycie VMWare do stworzenia maszyny wirtualnej na W7. Zainstaluj swój ulubiony system Linux, a następnie zamontuj obraz, aby uzyskać do niego dostęp, lub zaimportuj go jako plik, a następnie zamontuj.

Następnie można skonfigurować udział Samba / CIFS i uzyskać dostęp z W7.

Ext2read pozwala na oglądanie tylko do odczytu, ale nie do faktycznego montażu, ani pisania. (przez # 37512 )

O ile mi wiadomo, nie ma sterownika ani aplikacji zdolnej do zapisu do ext4 dla Windows.

Jeśli musisz tylko z niego przeczytać, możesz użyć EXT $ Unpacker, który jest darmowy i open source.

http://sourceforge.net/projects/androidicsjbext/

Dlaczego nie? To tylko obraz.

Możesz użyć FTK IMAGER , Ściągnij tutaj

• Nowa funkcja pozwala użytkownikom zamontować obraz jako dysk lub urządzenie fizyczne   urządzenie.
• FTK Imager 3.0 zapewnia teraz wsparcie dla Plik VXFS, exFAT i Ext4   systemy .
• Bezpiecznie zamontuj obraz kryminalistyczny (AFF / DD / RAW / 001 / E01 / S01) jako fizyczny   urządzenie lub logicznie jako litera dysku.

Możesz zainstalować ext2fsd który zainstaluje sterowniki, których komputer z systemem Windows będzie musiał rozpoznać zew. Następnie zamontuj obraz za pomocą narzędzia do montażu, takiego jak Mount Image Pro lub FTK Imager.

OSFMount http://www.osforensics.com/tools/mount-disk-images.html

OSFMount pozwala montować pliki obrazów dysków lokalnych w systemie Windows za pomocą   litera dysku.

Świetnie nadaje się do zamontowania obrazu Ext4 w oknach, a pobieranie wynosi zaledwie 2 MB.

O innych:

• Mount Image Pro v6 [ https://dailyuploads.net/ewmo7ypfr1m5] (^ - mógł go uruchomić tylko ta wersja z poprawką Anti Dongle)
  ALE Mount Image Pro nie może montować plików Ext4 (jest to po prostu dobre dla * .iso, * .dmg, * .vhd i kilku innych obrazów sądowych)

• FTK Imager 3.4.3 http://ad-exe.s3.amazonaws.com/AccessData_FTK_Imager_3.4.3_x64.exe Cóż, mam taką samą historię - wszystkie rodzaje wsparcia dla obrazów CD, ale nie dla Ext4

OSFMount nie ma obsługi drop'n'drag - także użycia OSFMount.com nie jest łatwo łączyć go z plikami * .ext4 lub * .img, aby je zainstalować. (wymagane parametry dodawania) Oto skrypt cmd OSFMount.cmd

    @prompt -$G

    @echo OSFMount Script 1.0
    @echo ===================
    @echo.

    @set OSFMount_Exe=OSFMount.com
    @set OSFMount_Path="%programFiles%\OSFMount\%OSFMount_Exe%"

    @set MaxDrivesCount=4
    @set MountPoint=#:

    @set options=ro

    @set g_MuteOutput= ^>nul 2^>^&1


    @Call :CheckNSet_PathToExe

    @Call :MayBe_UnMountAll


    ::if "%2" NEQ "" set MountPoint=%2
    @set File=%1
    @set cmd=%OSFMount% -a -t file -m %MountPoint% -f "%File%" -o %options%

    @%cmd%
    @if Errorlevel 1 @(
        @echo Errorlevel: %Errorlevel%
        @call :UnMountAll
        %cmd%
    )


::  %g_MuteOutput% 

::  @pause

@goto :eof

:CheckNSet_PathToExe
    @call :SetIfExist OSFMount %OSFMount_Path%
    @if not defined OSFMount @(

        @call :SetIfExist OSFMount "%~dp0%OSFMount_Exe%"
        @if not defined OSFMount @(

            @echo ERROR: %OSFMount% not found!
            @echo.
            @echo Please copy %~nx0 into same dir where %OSFMount_Exe% is!
            @exit
        )

    )
@goto :eof

:SetIfExist
    @if exist "%~2" set %1="%~2"
@goto :eof




:MayBe_UnMountAll
    :: GetNumberOf (EXT4) Drives
    :: Well OSFMount can also mount other types but this is some kind of compromise or now  
    @set g_CountLines= ^^^| find /c  "="
    @set g_Drives=wmic logicaldisk where FileSystem^^^="EXT4" get Name /value

    @for /f %%x in ('%g_Drives% %g_CountLines%') do @set Lines=%%x

    @echo   Currently mounted drives %Lines% \ %MaxDrivesCount%

    @if %lines% GEQ %MaxDrivesCount% @call :UnMountAll


@goto :eof


:UnMountAll
    @for /f "tokens=2 delims==" %%d in (
        '%g_Drives%' 
        ) do @(
    @call :UnMount %%d
    )

    @prompt -$G

@goto :eof

:UnMount

    @%OSFMount% -D -m %1 %g_MuteOutput% 
    @if not errorlevel 1 @echo %1 UnMounted!


    @goto :eof

Instalacja:

1. Skopiuj / wklej i amp; zapisz go jako OSFMount.cmd (w Notatniku lub innym ładniejszym edytorze)
2. i umieść go w tym samym katalogu co OSFMount.com. (Cóż, jeśli OSFMount jest zainstalowany na „C: pliki programów OSFMount”, możesz także umieścić go gdzieś indziej)
3. Utwórz link do pulpitu lub paska szybkiego uruchamiania

Stosowanie:

• Aby zamontować obraz, przeciągnij go na OSFMount.cmd (lub jego link).
• Powiązanie plików jest równie proste - wystarczy wybrać OSFMount.cmd w oknie „Otwórz za pomocą”.

Przykład użycia wiersza poleceń: OSFMount.cmd d:\android-5.1-rc1\system.img

Cóż, kolejna wolna litera dysku jest wybierana automatycznie. Jeśli zamontowałeś więcej niż 4 obrazy, skrypt zresetuje i odmontuje pozostałe. (Zmień wiersz z MaxDrivesCount = 4 w skrypcie, jeśli potrzebujesz więcej lub mniej.)

Do tej pory skrypt jest tworzony i testowany tylko z obrazami ext4. Aby pracować z innymi typami obrazów, takimi jak iso, vhd, prawdopodobnie zmodyfikujesz skrypt.