Szukam narzędzia, które pozwoli na odwrotne wyszukiwanie przyrostowe z obsługą prostego wyrażenia regularnego (lub tylko wielu dopasowań). Na przykład, jeśli chcę znaleźć polecenie „foo bar baz”, mógłbym zrobić coś takiego, aby szybko znaleźć polecenie:

CRTL-R (rozpoczyna wyszukiwanie) wpisz „foo” (dopasowuje najnowszą komendę za pomocą foo) kontynuuj wpisywanie „foo | baz” (pasuje do najnowszej komendy zawierającej „foo” ORAZ „baz”.

Czy coś takiego istnieje? Jeśli nie, jak mógłbym sam to wdrożyć?

Niestandardowy widget history-incremental-multi-searchdlazsh

Ustawiać

Utwórz katalog i dołącz go do swojego. $fpathNa przykład utworzyłem katalog ~/.zsh/functionsi wiersz fpath=($HOME/.zsh/functions $fpath)w moim .zshrc.

Umieść następujące w pliku o nazwie history-incremental-multi-searchw tym katalogu.

emulate -L zsh
setopt extended_glob

local oldbuffer=$BUFFER
local -i oldcursor=$CURSOR

local dir                # search direction
local chars              # input buffer
local -a words           # search terms
local -a found           # all history items that match first term
local -i hindex=$HISTNO  # current 
local -i lmatch          # last matched history item (for prev/next)

if [[ $WIDGET == *forward* ]]; then
    dir=fwd
else
    dir=bck
fi

function find-next {
    # split the input buffer on spaces to get search terms
    words=(${(s: :)chars})

    # if we have at least one search term
    if (( $#words )); then
        # get all keys of history items that match the first
        found=(${(k)history[(R)*$words[1]*]})
        if (( $#found )); then
            # search in widget direction by default
            # but accept exception in $1 for "prev match"
            search-${1:-$dir}
        else
            # no matches
            lmatch=$HISTNO
        fi
    else
        # no search terms
        lmatch=$HISTNO
        BUFFER=$oldbuffer
        CURSOR=$oldcursor
    fi
}

function search-fwd {
    # search forward through matches
    local -i i
    for (( i = $#found; i > 0; i-- )); do
        # but not before hindex as we're searching forward
        if [[ $found[$i] -gt $hindex ]]; then
            set-match $found[$i]
        fi
    done
}

function search-bck {
    # search backward through matches
    local -i i
    for (( i = 1; i <= $#found; i++ )); do
        # but not beyond hindex as we're searching backward
        if [[ $found[$i] -lt $hindex ]]; then
            set-match $found[$i]
        fi
    done
}

function set-match {
    # match history item against all terms and select it if successful
    local match=1
    local -i i
    for (( i = 2; i <= $#words; i++ )); do
        if [[ $history[$1] != *$words[$i]* ]]; then
            match=0
            break
        fi
    done
    if [[ $match -ne 0 ]]; then
        lmatch=$1
        BUFFER=$history[$1]
        CURSOR=$#BUFFER
        break
    fi
}

# display sub prompt
zle -R "${dir}-i-search-multi:"

# handle input keys
while read -k; do
    case $REPLY in
        # next
        $'\C-n' )
            hindex=$lmatch
            find-next
            ;;
        # prev
        $'\C-p' )
            hindex=$lmatch
            if [[ $dir == fwd ]]; then
                find-next bck
            else
                find-next fwd
            fi
            ;;
        # break
        $'\e' | $'\C-g' )
            BUFFER=$oldbuffer
            CURSOR=$oldcursor
            break
            ;;
        # accept
        $'\C-m' | $'\C-j' )
            if [[ $lmatch -eq $HISTNO ]]; then
                BUFFER=$oldbuffer
                CURSOR=$oldcursor
            else
                HISTNO=$lmatch
            fi
            break
            ;;
        # erase char
        $'\C-h' | $'\C-?' )
            chars=$chars[1,-2]
            hindex=$HISTNO
            find-next
            ;;
        # erase word
        $'\C-w' )
            if [[ $chars =~ \  ]]; then
                chars=${chars% *}
            else
                chars=
            fi
            hindex=$HISTNO
            find-next
            ;;
        # kill line
        $'\C-u' )
            chars=
            hindex=$HISTNO
            find-next
            ;;
        # add unhandled chars to buffer
        * )
            chars=${chars}${REPLY}
            hindex=$HISTNO
            find-next
            ;;
    esac

    zle -R "${dir}-i-search-multi: $words"
done

Włóż to lub zrób z .zshrc:

autoload -U history-incremental-multi-search

# make new widgets from function
zle -N history-incremental-multi-search-backward history-incremental-multi-search
zle -N history-incremental-multi-search-forward history-incremental-multi-search

# bind the widgets to keys
bindkey '^Xr' history-incremental-multi-search-backward
bindkey '^Xs' history-incremental-multi-search-forward

Posługiwać się

Teraz powinno być w stanie zainicjować wyszukiwanie przyrostowe z tyłu Ctrl+X, r, z przodu Ctrl+X, s.

Wpisz wyszukiwane hasła oddzielone spacją. Dostępne są następujące klucze do sterowania:

• ← Backspace: usuń znak

• Ctrl+W: usuń słowo

• Ctrl+U: linia zabicia

• Ctrl+N: Następny mecz

• Ctrl+P: poprzedni mecz

• Ctrl+G/ Esc: anuluj wyszukiwanie

• Enter: zaakceptować

To rozwiązanie można prawdopodobnie nieco uprościć. Jest to bardziej funkcjonalny dowód koncepcji, z dużą ilością miejsca na ulepszenia.

Możesz przeglądać swoją historię:

history | egrep '(foo|baz)'

Mam nadzieję że to pomogło.

Opierając się na odpowiedzi @ peth:

Zsh ma teraz history-incremental-pattern-search-backward, nie musisz tego definiować sam. Wystarczy dodać powiązanie klucza. Wolę zastąpić ^R, dodając następujący wiersz do .zshrc:

bindkey '^R' history-incremental-pattern-search-backward

Teraz możesz używać operatorów glob (sic! Not rexex) w wyszukiwaniu.