TextWrangler: klawisze skrótu do przesuwania linii w górę / w dół

W Eclipse możesz nacisnąć ALT- (strzałki), aby przesunąć linię w górę lub w dół.

Czy ktoś odkrył te funkcje klawiszy skrótu w TextWrangler?

W systemie Mac OS X jest to ctrl+ ↑lub ctrl+ ↓.

Może być konieczna zmiana ustawień skrótu kontroli misji (w Preferencjach systemowych), ponieważ są tam ustawione dwa pociągnięcia klawisza.

W podręczniku nic nie wspomniano (tylko znaki i słowa wymiany ).

Jeśli TextWrangler obsługuje system tekstowy Cocoa (podejrzewam, że nie, ale nadal), możesz utworzyć plik ~/Library/Keybindings/DefaultKeyBinding.dicti wprowadzić następujące dane:

{
    "~\UF701" = (
        "moveToBeginningOfLine:",
        "deleteToEndOfLine:",
        "deleteForward:",
        "moveDown:",
        "yank:",
        "insertNewline:",
        "moveUp:"
    );
}

Spowoduje to dodanie skrótu Opt-DownArrowdo polecenia zamiany linii (wraz z linią poniżej) do każdej aplikacji obsługującej system tekstowy Cocoa.

Nie sądzę, że TextWrangler ma to wbudowane.

Możesz jednak uruchamiać skrypty jabłkowe w TextWrangler, więc możesz to zrobić. Znalazłem nawet kilka skryptów jabłkowych , które to umożliwią.

Będziesz musiał zastąpić BBEdit TextWrangler w skryptach jabłkowych. Umieść skrypty w „~ / Library / Application Support / TextWrangler / Scripts /”, a pojawią się one w menu skryptów w TextWrangler. Kliknij Okno -> Palety -> Skrypty, aby wyświetlić paletę skryptów, w której można ustawić niestandardowe skróty klawiaturowe.

Rozwiązanie nathangs działa całkiem dobrze. Ale podany link już nie działa. Oto skrypty w postaci zwykłego tekstu. Wystarczy wkleić je do „AppleScript Editor” i zapisać je w ~ / Library / Application Support / TextWrangler / Scripts /

Działa dobrze na Mountain Lion i TextWrangler 4.

MoveLineDown.scpt:

tell application "TextWrangler"
    set x to startLine of selection
    tell text 1 of window 1
        if x = (count of lines) then return
        set myline to contents of line x
        delete line x
        if length of line x = 0 then
            make line at line x with data "
"
            make line at line (x + 1) with data myline
        else
            make line at line x with data myline

        end if
        select insertion point before line (x + 1)
    end tell
end tell

MoveLineUp.scpt:

tell application "TextWrangler"
    set x to startLine of selection
    if x = 1 then
        beep
        return
    end if
    tell text 1 of window 1
        set oldCount to count of lines
        set myline to contents of line x
        delete line x
        if x = 2 then
            if length of line 1 = 0 then
                make line at beginning with data "
"
            end if
            make line at beginning with data myline
        else
            if length of line (x - 2) = 0 then
                make line at line (x - 2) with data "
"
                make line at line (x - 1) with data myline
            else
                make line at line (x - 2) with data myline
            end if
        end if
        select insertion point before line (x - 1)
    end tell
end tell