Jak zmienić domyślny edytor HTML IE na Notepad2 w systemie Windows 7

tak, że gdy oglądam źródło, to jest to notatnik2, który otwiera dokument w górę. Mam już pobrany notatnik2.

Możesz to zrobić bezpośrednio dodając / edytując Registry Keys.

Rodzaj regedit.exe w biegu.

W inny sposób poniżej NIE TESTOWANE kod vbscript: -

NOTE: Please be careful, while playing with registry keys.

KOD:

Set WshShell = CreateObject("WScript.Shell")
Set fs = CreateObject("Scripting.FileSystemObject")
Dim MyKey, EditorName, KeyToAdd, rtn, MyKeySelf
MyKey = Inputbox("Type the application name with full path", "Add a HTML Editor", "C:\Windows\Notepad.exe")

if trim(MyKey) = "" then WScript.Quit

MyKeySelf = """" + MyKey + """" & " " & """" + "%1" + """"

if not fs.fileexists(MyKey) then
    rtn = msgbox("Specified file is missing, do you want to continue anyway?", 36, "Add a HTML Editor")
        if rtn = 6 then
            Call AddEditor
        else
            WScript.Quit
        end if
else
    Call AddEditor
end if

Sub AddEditor()
    EditorName = fs.GetFileName(MyKey)
    KeyToAdd = "HKCR\.htm\openwithlist\" & EditorName & "\"
    WshShell.RegWrite KeyToAdd,"","REG_SZ"
    KeyToAdd = "HKCR\Applications\" & EditorName & "\shell\edit\command\"
    WshShell.RegWrite KeyToAdd,MyKeySelf,"REG_SZ"

    rtn = msgbox("Added... Do you want to set it as the default HTML Editor?", 36, "Add a HTML Editor")
    if rtn = 6 then
        Call SetAsDefaultEditor
    end if  
end sub

Sub SetAsDefaultEditor()
    On Error resume next
    KeyToAdd = "HKCU\Software\Microsoft\Internet Explorer\Default HTML Editor\shell\edit\command\"
    WshShell.RegWrite KeyToAdd,MyKeySelf,"REG_SZ"
    KeyToAdd = "HKCU\Software\Microsoft\Shared\HTML\Default Editor\shell\edit\command\"
    WshShell.RegWrite KeyToAdd,MyKeySelf,"REG_SZ"
    WshShell.Regdelete "HKCU\Software\Microsoft\Internet Explorer\Default HTML Editor\Description"
    WshShell.Regdelete "HKCU\Software\Microsoft\Internet Explorer\Default HTML Editor\shell\edit\ddeexec\Topic\"
    WshShell.Regdelete "HKCU\Software\Microsoft\Internet Explorer\Default HTML Editor\shell\edit\ddeexec\Application\"
    WshShell.Regdelete "HKCU\Software\Microsoft\Internet Explorer\Default HTML Editor\shell\edit\ddeexec\"
end sub

Set WshShell = Nothing
Set fs = Nothing