OS X Terminal.app: jak uruchomić nową kartę w tym samym katalogu, co bieżąca karta?

Często muszę otwierać nową kartę w tym samym katalogu, co moja bieżąca karta, aby zrobić coś innego, podczas gdy moja bieżąca karta jest zajęta przez długi proces. Jednak domyślnie po utworzeniu nowej karty Terminal.app zaczyna się od ~ /. Masz pomysł, jak sprawić, by skakał automatycznie?

W OS X 10.7 (Lion) Terminal.app obsługuje natywnie: New Windows/Tabs open in: Same working directory

Należy bardzo ostrożnie przepuszczać łańcuchy przez różne środowiska.

Korzystam z wersji 10.4, więc mój skrypt „tfork” zawsze otwiera nowe okno. Dostosowanie go do użycia karty powinno być łatwe:

#!/bin/sh

# source: http://www.pycs.net/bob/weblog/2004/02/23.html#P49
# Rewritten to use osascript args -> run handler args.
# Added ability to pass additional initial command and args to new shell.
#    Bug: Non ASCII characters are unreliable on Tiger.
#         Tiger's osascript seems to expect args to be encoded in
#         the system's primary encoding (e.g. MacRoman).
#         Once in AppleScript, they are handled OK. Terminal sends them
#         back to the shell as UTF-8.

test $# -eq 0 && set -- : # default command if none given
osascript - "$(pwd)" "$@" <<\EOF
on run args
  set dir to quoted form of (first item of args)
  set cmd_strs to {}
  repeat with cmd_str in rest of args
    set end of cmd_strs to quoted form of cmd_str
  end
  set text item delimiters to " "
  set cmd to cmd_strs as Unicode text
  tell app "Terminal" to do script "cd " & dir & " && " & cmd
end
EOF

Przykład: tfork git log -p ..FETCH_HEAD

Poprawka: cwd już uruchomionego procesu „zajmowania” karty Terminal

Idea „bieżącego katalogu programu zajmującego bieżącą kartę” nie jest tak oczywista, jak można się spodziewać.

Każda karta Terminal ma jedno urządzenie tty, które jest używane przez procesy, które uruchamia (początkowo powłokę, a następnie cokolwiek startuje powłoka).

Każdy (normalny) terminal tty ma jedną grupę procesów na pierwszym planie, którą można uznać za „zajmującą” tty.

Każda grupa procesów może zawierać wiele procesów.

Każdy proces może mieć swój bieżący katalog roboczy (cwd) (niektóre środowiska nadają każdemu wątkowi własny cwd lub ekwiwalent cwd, ale to zignorujemy).

Powyższe fakty ustanawiają rodzaj ścieżki, która od tty do cwd: tty -> grupa procesów pierwszego planu -> procesy grupy procesów pierwszego planu -> cwds.

Pierwszą część (od procesów tty do procesów pierwszoplanowych) problemu można rozwiązać za pomocą danych wyjściowych ps :

ps -o tty,pid,tpgid,pgid,state,command | awk 'BEGIN{t=ARGV[1];ARGC=1} $1==t && $3==$4 {print $2}' ttyp6

(gdzie „ttyp6” to nazwa interesującego nas zestawu)

Mapowanie z procesu (PID) na cwd można wykonać za pomocą lsof :

lsof -F 0n -a -p 2515,2516 -d cwd

(gdzie „2515,2516” to oddzielona przecinkami lista interesujących procesów)

Ale pod Tygrysem nie widzę bezpośredniego sposobu uzyskania nazwy urządzenia tty określonego okna terminalu . Istnieje strasznie brzydki sposób na zdobycie nazwy tty w Tiger. Może Leopard lub Snow Leopard poradzą sobie lepiej.

Złożyłem to wszystko w AppleScript w następujący sposób:

on run
    (* Find the tty. *)
    -- This is ugly. But is seems to work on Tiger. Maybe newer releases can do better.
    tell application "Terminal"
        set w to window 1
        tell w
            set origName to name
            set title displays device name to not title displays device name
            set newName to name
            set title displays device name to not title displays device name
        end tell
    end tell
    set tty to extractTTY(origName, newName)
    if tty is "" then
        display dialog "Could not find the tty for of the current Terminal window." buttons "Cancel" cancel button "Cancel" default button "Cancel"
    end if

    (* Find the PIDs of the processes in the foreground process group on that tty. *)
    set pids to paragraphs of (do shell script "
ps -o pid,tty,tpgid,pgid,state,command |
awk '
    BEGIN   {t=ARGV[1];ARGC=1}
    $2==t && $3==$4 {print $1}
' " & quoted form of tty)
    if pids is {} or pids is {""} then
        display dialog "Could not find the processes for " & tty & "." buttons "Cancel" cancel button "Cancel" default button "Cancel"
    end if

    (* Find the unique cwds of those processes. *)
    set text item delimiters to {","}
    set lsof to do shell script "lsof -F 0n -a -d cwd -p " & quoted form of (pids as Unicode text) without altering line endings
    set text item delimiters to {(ASCII character 0) & (ASCII character 10)}
    set cwds to {}
    repeat with lsofItem in text items of lsof
        if lsofItem starts with "n" then
            set cwd to text 2 through end of lsofItem
            if cwds does not contain cwd then ¬
                set end of cwds to cwd
        end if
    end repeat
    if cwds is {} then
        display dialog "No cwds found!?" buttons "Cancel" cancel button "Cancel" default button "Cancel"
    end if
    if length of cwds is greater than 1 then
        set cwds to choose from list cwds with title "Multiple Distinct CWDs" with prompt "Choose the directory to use:" without multiple selections allowed and empty selection allowed
        if cwds is false then error number -128 -- cancel
    end if

    (* Open a new Terminal. *)
    tell application "Terminal" to do script "cd " & quoted form of item 1 of cwds
end run

to extractTTY(a, b)
    set str to textLeftAfterRemovingMatchingHeadAndTail(a, b)
    set offs to offset of "tty" in str
    if offs > 0 then
        return text offs through (offs + 4) of str
    end if
    return ""
end extractTTY
to textLeftAfterRemovingMatchingHeadAndTail(big, little)
    set text item delimiters to space
    if class of big is not list then set big to text items of big
    if class of little is not list then set little to text items of little
    set {maxLen, minLen} to {length of big, length of little}
    if maxLen < minLen then ¬
        set {big, little, maxLen, minLen} to {little, big, minLen, maxLen}

    set start to missing value
    repeat with i from 1 to minLen
        if item i of big is not equal to item i of little then
            set start to i
            exit repeat
        end if
    end repeat
    if start is missing value then
        if maxLen is equal to minLen then
            return ""
        else
            return items (minLen + 1) through end of big as Unicode text
        end if
    end if

    set finish to missing value
    repeat with i from -1 to -minLen by -1
        if item i of big is not equal to item i of little then
            set finish to i
            exit repeat
        end if
    end repeat
    if finish is missing value then set finish to -(minLen + 1)

    return items start through finish of big as Unicode text
end textLeftAfterRemovingMatchingHeadAndTail

Zapisz go za pomocą Script Editor ( AppleScript Editor w Snow Leopard) i użyj programu uruchamiającego (np. FastScripts ), aby przypisać go do klucza (lub po prostu uruchom go z menu AppleScript (włączonego przez / Applications / AppleScript / AppleScript Utility.app )).

Mam napisali skrypt , który wykorzystuje Chris Johnsen kod jest powyżej i innego skryptu, aby otworzyć nową kartę w bieżącym katalogu z aktualnymi ustawieniami, głównie dlatego, że kolor koordynować swoje terminale. Dzięki Chris, za ten skrypt, używam go od kilku miesięcy i to świetna oszczędność czasu.

(* Ten skrypt otwiera nową kartę Terminal.app w katalogu bieżącej karty z tymi samymi ustawieniami. Jeśli jeszcze tego nie zrobiłeś, musisz włączyć dostęp do urządzeń pomocniczych zgodnie z opisem tutaj: http: // www .macosxautomation.com / applescript / uiscripting / index.html

To prawie cała praca dwóch skryptów razem, dziękuję im:

Skrypt Chrisa Johnsena otwiera nową kartę w bieżącym katalogu: OS X Terminal.app: jak uruchomić nową kartę w tym samym katalogu co bieżąca karta?

„Menu_click” Jacoba Rusa pozwala mi utworzyć kartę z tymi samymi ustawieniami, ponieważ interfejs API terminalu nie: http://hints.macworld.com/article.php?story=20060921045743404

Jeśli zmienisz nazwę profilu terminala, interfejs API AppleScript zwraca starą nazwę do momentu ponownego uruchomienia aplikacji, więc skrypt nie będzie działał na ustawieniach o zmienionej nazwie do tego czasu. Ugh. Konieczność aktywacji Terminala w celu wykonania polecenia menu powoduje wyświetlenie wszystkich okien terminala na pierwszym planie.

*)

-- from http://hints.macworld.com/article.php?story=20060921045743404
-- `menu_click`, by Jacob Rus, September 2006
-- 
-- Accepts a list of form: `{"Finder", "View", "Arrange By", "Date"}`
-- Execute the specified menu item.  In this case, assuming the Finder 
-- is the active application, arranging the frontmost folder by date.

on menu_click(mList)
    local appName, topMenu, r

    -- Validate our input
    if mList's length < 3 then error "Menu list is not long enough"

    -- Set these variables for clarity and brevity later on
    set {appName, topMenu} to (items 1 through 2 of mList)
    set r to (items 3 through (mList's length) of mList)

    -- This overly-long line calls the menu_recurse function with
    -- two arguments: r, and a reference to the top-level menu
    tell application "System Events" to my menu_click_recurse(r, ((process appName)'s ¬
        (menu bar 1)'s (menu bar item topMenu)'s (menu topMenu)))
end menu_click

on menu_click_recurse(mList, parentObject)
    local f, r

    -- `f` = first item, `r` = rest of items
    set f to item 1 of mList
    if mList's length > 1 then set r to (items 2 through (mList's length) of mList)

    -- either actually click the menu item, or recurse again
    tell application "System Events"
        if mList's length is 1 then
            click parentObject's menu item f
        else
            my menu_click_recurse(r, (parentObject's (menu item f)'s (menu f)))
        end if
    end tell
end menu_click_recurse



-- with the noted slight modification, from /superuser/61149/os-x-terminal-app-how-to-start-a-new-tab-in-the-same-directory-as-the-current-ta/61264#61264

on run
    (* Find the tty. *)
    -- This is ugly. But is seems to work on Tiger. Maybe newer releases can do better.
    tell application "Terminal"
        set w to the front window
        tell w
            set origName to name
            set title displays device name to not title displays device name
            set newName to name
            set title displays device name to not title displays device name
        end tell
    end tell
    set tty to extractTTY(origName, newName)
    if tty is "" then
        display dialog "Could not find the tty for of the current Terminal window." buttons "Cancel" cancel button "Cancel" default button "Cancel"
    end if

    (* Find the PIDs of the processes in the foreground process group on that tty. *)
    set pids to paragraphs of (do shell script "
ps -o pid,tty,tpgid,pgid,state,command |
awk '
    BEGIN   {t=ARGV[1];ARGC=1}
    $2==t && $3==$4 {print $1}
' " & quoted form of tty)
    if pids is {} or pids is {""} then
        display dialog "Could not find the processes for " & tty & "." buttons "Cancel" cancel button "Cancel" default button "Cancel"
    end if

    (* Find the unique cwds of those processes. *)
    set text item delimiters to {","}
    set lsof to do shell script "lsof -F 0n -a -d cwd -p " & quoted form of (pids as Unicode text) without altering line endings
    set text item delimiters to {(ASCII character 0) & (ASCII character 10)}
    set cwds to {}
    repeat with lsofItem in text items of lsof
        if lsofItem starts with "n" then
            set cwd to text 2 through end of lsofItem
            if cwds does not contain cwd then ¬
                set end of cwds to cwd
        end if
    end repeat
    if cwds is {} then
        display dialog "No cwds found!?" buttons "Cancel" cancel button "Cancel" default button "Cancel"
    end if
    if length of cwds is greater than 1 then
        set cwds to choose from list cwds with title "Multiple Distinct CWDs" with prompt "Choose the directory to use:" without multiple selections allowed and empty selection allowed
        if cwds is false then error number -128 -- cancel
    end if

    (* Open a new Terminal. *)

    -- Here is where I substituted the menu_click call to use the current settings

    tell application "Terminal"
        activate
        tell window 1
            set settings to name of current settings in selected tab
        end tell
    end tell
    menu_click({"Terminal", "Shell", "New Tab", settings})

    tell application "Terminal" to do script "cd " & quoted form of item 1 of cwds in selected tab of window 1
end run

to extractTTY(a, b)
    set str to textLeftAfterRemovingMatchingHeadAndTail(a, b)
    set offs to offset of "tty" in str
    if offs > 0 then
        return text offs through (offs + 6) of str
    end if
    return ""
end extractTTY
to textLeftAfterRemovingMatchingHeadAndTail(big, little)
    set text item delimiters to space
    if class of big is not list then set big to text items of big
    if class of little is not list then set little to text items of little
    set {maxLen, minLen} to {length of big, length of little}
    if maxLen < minLen then ¬
        set {big, little, maxLen, minLen} to {little, big, minLen, maxLen}

    set start to missing value
    repeat with i from 1 to minLen
        if item i of big is not equal to item i of little then
            set start to i
            exit repeat
        end if
    end repeat
    if start is missing value then
        if maxLen is equal to minLen then
            return ""
        else
            return items (minLen + 1) through end of big as Unicode text
        end if
    end if

    set finish to missing value
    repeat with i from -1 to -minLen by -1
        if item i of big is not equal to item i of little then
            set finish to i
            exit repeat
        end if
    end repeat
    if finish is missing value then set finish to -(minLen + 1)

    return items start through finish of big as Unicode text
end textLeftAfterRemovingMatchingHeadAndTail

Jak wspomniano w innym miejscu , jeśli używasz Oh My Zsh , powinieneś po prostu dodać terminalappwtyczkę. W pliku .zshrc (zakładając, że już używasz wtyczki git:

plugins=(terminalapp git)

Używam do tego tego skryptu aliasu / powłoki.

# modified from http://www.nanoant.com/programming/opening-specified-path-in-terminals-new-tab
alias twd=new_terminal_working_directory
function new_terminal_working_directory() {
osascript <<END 
        tell application "Terminal"
            tell application "System Events" to tell process "Terminal" to keystroke "t" using command down
        do script "cd $(pwd)" in first window
    end tell
END
}

http://www.entropy.ch/blog/Mac+OS+X/2008/06/27/Terminal-Tricks- komunikacjitermczech-revisited-with-tabs.html

tab -t $PWD