Jak wyłączyć podpowiedź w dymku na kartach

Czy istnieje sposób na wyłączenie podpowiedzi w dymku na kartach w Chrome?

Mogą być bardzo denerwujące i rozpraszające, gdy wskaźnik myszy znajduje się na karcie.

Nie możesz wyłączyć tych podpowiedzi w Chrome.

Przez: http://productforums.google.com/forum/#!topic/chrome/ygoNhTB5K1Y https://groups.google.com/forum/#!topic/chromebook-central/gxAnZM-2tpM http://forums.mozillazine.org/viewtopic.php?f=7&t=1562905

Nie mogłem dostać pomysł programu przesuwającego kursor dla ciebie z mojego umysłu, więc rzuciłem razem.

Poniżej znajduje się skrypt AutoHotkey (który można skompilować do samodzielnego pliku wykonywalnego, jeśli jest to pożądane), który wykrywa, kiedy kursor myszy pozostaje bezczynny blisko górnej części okna Chrome, a jeśli tak, przenosi go do prawego dolnego rogu ekran.

Działa zgodnie z oczekiwaniami i zapobiega pojawianiu się podpowiedzi, ale z powodu rozłożonego czasu (wyzwalanie podprogramu i odliczanie podpowiedzi), czasami podpowiedź pojawia się na ułamek sekundy przed przesunięciem kursora. Można to zmniejszyć, zmniejszając timer ( tip zmienna).

Zastanawiam się również nad ulepszeniem skryptu, obsługując timer ręcznie zamiast używać timera AutoHotkey. W ten sposób może odliczać od ostatniego przesunięcia myszy lub naciśnięcia przycisku zamiast tylko każdego x sekund niezależnie.

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;   MoveIdleMouse.ahk
;
; Prevents tooltips from being annoying in Chrome by detecting
; when the mouse is idle while near the top of a Chrome window
; and then moving it to the bottom-right corner of the screen.
;
; https://superuser.com/questions/393738/
;
;   (cl) 2013- Synetech inc., Alec Soroudi
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

#SingleInstance force
#Persistent

; Read the tooltip delay from the registry (this is the amount of time the
; cursor has to hover over something in order to trigger the tooltip)
RegRead, tip, HKCU, Control Panel\Mouse, MouseHoverTime

; Divide it by two to accommodate staggared timing. Adjust as desired.
;tip:=tip/2

; Set specified subroutine to run every so often (before tooltip triggered)
SetTimer, CheckCursor, %tip%

; Get the current mouse cursor position to compare to during first interval
MouseGetPos, x1, y1
return

; This subroutine checks the current cursor position and moves if idle
CheckCursor:
  ; First check if the cursor is over a Chrome window; ignore if not
  IfWinNotActive, ahk_class Chrome_WidgetWin_0
    return

  ; Next, check if any buttons are pressed and ignore if so
  if (GetKeyState("LButton") or GetKeyState("RButton") or GetKeyState("MButton")
      or GetKeyState("XButton1") or GetKeyState("XButton2"))
    return

  ; Get the current mouse position and check if it is both unchanged, and
  ; near the top of Chrome (position is relative to window by default)
  MouseGetPos, x2, y2
  If (((x1 = x2) and (y1 = y2))  and  ((y2 >= 0) and (y2 <= 27)))
  {
    ; Move the cursor to the bottom-right corner of the screen immediately
    ; You can adjust destination position as desired
    MouseMove, A_ScreenWidth+3, A_ScreenHeight+3, 0
  }
  else {
    ; Update current cursor position to compare to during the next interval
    x1 := x2
    y1 := y2
  }
  return