Zastępstwo tekstu na mowę programu Word

Wydaje się, że Microsoft zdecydował się na usunięcie tekstu na mowę z programu Word 2007. Czy istnieje porządna wymiana, najlepiej nie wymagająca osobnej aplikacji? Chciałbym, żeby czytał bezpośrednio ze słowa.

To również nie jest pytanie o dostępność. Chciałbym tylko móc usłyszeć to, co na głos piszę. Sprawia, że ​​słabe sformułowanie staje się bardziej oczywiste.

Tak, Microsoft zrobił to ponownie. Tekst na mowę został usunięty z programu Word 2007.
Na szczęście istnieje dość prosty sposób na zaimplementowanie go za pomocą odrobiny kodu makro.

Artykuł Słowo tekst na mowę opisuje, jak dodać do Worda dwa przyciski używające makr VBA, SpeakText i StopSpeaking.

Tekst na mowę w MS Word 2007

Poniżej znajdują się makra umożliwiające włączenie syntezatora mowy. Makra te należy umieścić w „normal.dot”, więc zostanie załadowane wraz z aplikacją MS Word.

Naciśnij kombinację klawiszy Alt + F11, aby przejść do edytora makr i wkleić ten kod. Musisz dodać trzy przyciski do paska narzędzi szybkiego dostępu. Możesz to zrobić, klikając małą strzałkę w dół z napisem „Dostosuj pasek narzędzi szybkiego dostępu” na pasku tytułu słowa MS, w którym znajdziesz przyciski Zapisz, Cofnij i Ponów. Wybierz „Więcej poleceń” z menu rozwijanego, aby otworzyć okno „Opcje programu Word”. Wybierz „Dostosuj” w menu po lewej stronie, a „Wybierz polecenia z” należy ustawić na „Makra”. Dodaj wszystkie trzy makra, aby utworzyć trzy przyciski na pasku narzędzi szybkiego dostępu. Teraz twoje słowo MS jest włączone TTS.

Option Explicit
Dim speech As SpVoice
Dim i As Integer

Sub SpeakText()
On Error Resume Next
If i = 0 Then
  Set speech = New SpVoice
  If Len(Selection.Text) > 1 Then 'speak selection
  speech.Speak Selection.Text, _
  SVSFlagsAsync + SVSFPurgeBeforeSpeak
  Else 'speak whole document
  speech.Speak ActiveDocument.Range(0, _
    ActiveDocument.Characters.Count).Text, _
    SVSFlagsAsync + SVSFPurgeBeforeSpeak
  End If
Else
  If i = 1 Then
  speech.Resume
  i = 0
  End If
End If
End Sub

Sub StopSpeaking()
On Error Resume Next
speech.Speak vbNullString, SVSFPurgeBeforeSpeak
Set speech = Nothing
i = 0
End Sub

Sub PauseSpeaking()
On Error Resume Next
If i = 0 Then
  speech.pause
  i = 1
Else
  If i = 1 Then
  speech.Resume
  i = 0
  End If
End If
End Sub

Źródło

Zawsze możesz spróbować skopiować / wkleić tekst do Przeczytaj proszę . Ma darmowe i płatne wersje, a darmowe wersje działają świetny! Po prostu zainstaluj, skopiuj wklej swój tekst, a wyłączysz się! :)