Rozwiąż wszystkie aliasy w wierszu polecenia zsh

Zagnieżdżałem aliasy i chcę je wszystkie rozwiązać przed wykonaniem polecenia. W jaki sposób mogę to zrobić?

Jeśli jest funkcja, która nie jest powiązana z żadnym klawiszem, to też M-x foobarjest dla mnie w porządku. Mogę nawet użyć polecenia zewnętrznego ( type, command, which, cokolwiek). Próbowałem wszystkiego z wątku. Dlaczego nie użyć „który”? Czego więc użyć? ale nic nie działa.

Zauważ, że Ctrl-Alt-E in bashnie tylko rozwija aliasy. Rozszerza także zmienne, podstawianie poleceń (!), Podstawianie procesów (!), Interpretację arytmetyczną i usuwa cudzysłowy (nie generuje nazw plików (globbing) ani interpretacji tyldy).

Nie zawsze udaje się rozwinąć aliasy. Tak więc, chociaż ma swoje zastosowania, ważne jest, aby zdać sobie sprawę, że jego wynik potencjalnie zmienia znaczenie wiersza poleceń, ma skutki uboczne i jest potencjalnie niebezpieczny.

Na przykład w:

$ a=';w' b=1
$ alias foo=bar
$ b=2; echo $b $a; cd /tmp/dir && for i do foo $(pwd) <(ls); done

Jeśli nacisnę M-C-Etutaj, to daje mi:

$ b=2; echo 1 ;w; cd /tmp/dir && for i do foo / /dev/fd/63; done

Co daje mi zupełnie inną linię poleceń (i wyobraź sobie, co by się stało, gdybym miał rm -rf *zamiast pwdwyżej) i nie rozszerza fooaliasu.

Dzięki zsh, aby rozwinąć uwagę Gillesa na temat rozszerzonych funkcji aliasów, możesz:

expand-aliases() {
  unset 'functions[_expand-aliases]'
  functions[_expand-aliases]=$BUFFER
  (($+functions[_expand-aliases])) &&
    BUFFER=${functions[_expand-aliases]#$'\t'} &&
    CURSOR=$#BUFFER
}

zle -N expand-aliases
bindkey '\e^E' expand-aliases

Spowoduje to rozwinięcie aliasów tylko wtedy, gdy bieżący wiersz poleceń jest poprawny pod względem składniowym (dlatego też pełni funkcję sprawdzania składni).

W przeciwieństwie do bashMCE, rozwiązuje również w pełni aliasy. Na przykład, jeśli masz:

$ alias ll='ls -l'; alias ls='ls --color'
$ ll

Zostanie rozszerzony do:

$ ls --color -l

Zauważ, że kanonizuje również składnię, więc rzeczy takie jak:

$ for i (*) cmd $i; foo

zostanie zmieniony na:

$ for i in *
        do
                cmd $i
        done
        foo

Jeśli umieścisz wiersz polecenia w definicji funkcji, a następnie wydrukujesz funkcję, aliasy zostaną rozwinięte. Otrzymasz również znormalizowane białe znaki.

% alias foo='bar -1'
% alias bar='qux -2'
% f () foo -3
% which f
f () {
        qux -2 -1 -3
}

Aby umieścić to wszystko w interaktywnym poleceniu, możesz utworzyć widget ZLE. Możesz zdefiniować funkcję bezpośrednio, umieszczając jej kod we wpisie w functionstablicy; dostaniesz efekt normalizacji podczas czytania.

normalize-command-line () {
  functions[__normalize_command_line_tmp]=$BUFFER
  BUFFER=${${functions[__normalize_command_line_tmp]#$'\t'}//$'\n\t'/$'\n'}
  ((CURSOR == 0 || CURSOR = #BUFFER)
  unset 'functions[__normalize_command_line_tmp]'
}
zle -N normalize-command-line
bindkey … normalize-command-line

Otrzymujesz ten sam efekt normalizacji w preexechaku . Aliasy są również rozwijane w momencie automatycznego ładowania funkcji ( autoload -Ujest to powszechnie stosowane w celu uniknięcia rozszerzenia aliasu).

Funkcja _expand_aliasuzupełniania rozwija słowo pod kursorem, jeśli jest to alias. Używa aliasestablicy . To nie jest rekurencyjne. Możesz zaimplementować bardziej ogólny ekspander aliasów aliases, ale jest to nieco trudne, ponieważ ustalenie lokalizacji, w których aliasy są rozwijane, jest ściśle związane ze składnią powłoki.

Jeśli masz wiele zagnieżdżonych fantazyjnych aliasów i nie masz pewności, co z nimi robi zsh oraz w jakiej kolejności są przekazywane polecenia, możesz zawsze uruchomić zsh z -xopcją. Spowoduje to wydrukowanie poleceń i argumentów podczas ich wykonywania.

Pamiętaj jednak, że ta opcja jest przeznaczona raczej do debugowania, więc drukuje wiele niepotrzebnych rzeczy zaraz po zsh -xwywołaniu (w zasadzie każda funkcja / widget / wtyczka twojego .zshrc), a podczas wykonywania polecenia może być również pełna, szczególnie jeśli zdefiniowałeś preexeci precmdzaczepisz.

Powinienem również wspomnieć, że drukuje tylko te polecenia, które są ostatecznie wykonywane, a oddzielne polecenia są drukowane osobno, więc po

alias a='echo a'
alias b='echo b'
alias c='echo c'
alias d='echo d'
a && b || c; d

Zobaczysz

+zsh:1> echo a
a
+zsh:1> echo b
b
+zsh:1> echo d
d