Testowanie LS_COLORS w zsh

Kilka lat temu znalazłem interesujący fragment kodu, który drukuje każdy typ pliku w odpowiednim kolorze zgodnie z ustawionymi kolorami LS_COLORS. Niestety nie pamiętam już linku.

Oto fragment kodu, o którym test_colors.shmowa

eval $(echo "no:global default;fi:normal file;di:directory;ln:symbolic link;pi:named pipe;so:socket;do:door;bd:block device;cd:character device;or:orphan symlink;mi:missing file;su:set uid;sg:set gid;tw:sticky other writable;ow:other w\
ritable;st:sticky;ex:executable;"|sed -e 's/:/="/g; s/\;/"\n/g')                                                                                                                                                                            
{                                                                                                                                                                                                                                           
  IFS=:                                                                                                                                                                                                                                     
  for i in $LS_COLORS                                                                                                                                                                                                                       
  do                                                                                                                                                                                                                                        
    echo -e "\e[${i#*=}m$( x=${i%=*}; [ "${!x}" ] && echo "${!x}" || echo "$x" )\e[m"                                                                                                                                                       
  done                                                                                                                                                                                                                                      
}   

Fragment działa świetnie w bash, ale nie w zsh, i nie wiem dlaczego. Po uruchomieniu zshpojawia się następujący błąd:

> sh .test_colors.sh
.eval_colors:1: * not found
[00:fi=00:di=01;34:ln=01;36:pi=40;33:so=01;35:do=01;35:bd=40;33;01:cd=40;33;01:or=40;31;01:su=37;41:sg=30;43:tw=30;42:ow=34;42:st=37;44:ex=01;32:*.tar=01;31:*.tgz=01;31:*.arj=01;31:*.taz=01;31:*.lzh=01;31:*.zip=01;31:*.z=01;31:*.Z=01;31:*.gz=01;31:*.bz2=01;31:*.deb=01;31:*.rpm=01;31:*.jar=01;31:*.jpg=01;35:*.jpeg=01;35:*.gif=01;35:*.bmp=01;35:*.pbm=01;35:*.pgm=01;35:*.ppm=01;35:*.tga=01;35:*.xbm=01;35:*.xpm=01;35:*.tif=01;35:*.tiff=01;35:*.png=01;35:*.mov=01;35:*.mpg=01;35:*.mpeg=01;35:*.avi=01;35:*.fli=01;35:*.gl=01;35:*.dl=01;35:*.xcf=01;35:*.xwd=01;35:*.flac=01;35:*.mp3=01;35:*.mpc=01;35:*.ogg=01;35:*.wav=01;35:m

Aktualizacja (1 listopada 2011 r.)

Skrypt przetestowałem poniżej przez @ Stéphane Gimeneza. Zauważyłem, że niektóre postacie wydają się nie uciekać poprawnie. Jakieś myśli dlaczego?

Odpowiedź: Zobacz komentarze do odpowiedzi @ Stéphane Gimenez.

To samo napisano dla zsh w znacznie czystszy sposób:

#!/bin/zsh

typeset -A names
names[no]="global default"
names[fi]="normal file"
names[di]="directory"
names[ln]="symbolic link"
names[pi]="named pipe"
names[so]="socket"
names[do]="door"
names[bd]="block device"
names[cd]="character device"
names[or]="orphan symlink"
names[mi]="missing file"
names[su]="set uid"
names[sg]="set gid"
names[tw]="sticky other writable"
names[ow]="other writable"
names[st]="sticky"
names[ex]="executable"

for i in ${(s.:.)LS_COLORS}
do
    key=${i%\=*}
    color=${i#*\=}
    name=${names[(e)$key]-$key}
    printf '\e[%sm%s\e[m\n' $color $name
done

Trzeba uciec =się ${i%=*}bo inaczej przyrostek wzór =*ulega =ekspansji , więc =jest interpretowany jako nazwa polecenia. To jest przyczyna * not foundbłędu.

Zsh domyślnie nie dzieli słów na podstawienia zmiennych, więc $LS_COLORSrozwija się do pojedynczego słowa. Aby forpętla działała na częściach oddzielonych dwukropkami $LS_COLORS, użyj for i in $=LS_COLORS. Lub więcej idiomatically w zsh, nie używać IFS, ale zamiast podać wyraźnie, jak podzielić: for i in ${(s.:.)LS_COLORS}.

Składnia ${!x}oznaczająca „wartość zmiennej, której nazwą jest $x”, jest specyficzna dla bash. Zsh ma odpowiadający konstrukcji z P rozszerzalności Parametr znacznik : ${(P)x}.