sed przekształca 4 spacje na 2

Jak przekonwertować 4 spacje na 2 spacje sed? Czy to możliwe?

Znalazłem to, ale konwertuje tabulatory na spacje:

sed -r ':f; s|^(\t*)\s{4}|\1\t|g; t f' file

Wysłany skrypt konwertuje 4 * n spacji na n tabulatorów, tylko jeśli te spacje są poprzedzone tylko tabulatorami.

Jeśli chcesz zastąpić 4 spacje 2 spacjami, ale tylko z wcięciem, chociaż można to zrobić za pomocą sed, polecam zamiast tego Perla.

perl -pe 's{^((?: {4})*)}{" " x (2*length($1)/4)}e' file

W sed:

sed -e 's/^/~/' -e ': r' -e 's/^\( *\)~    /\1  ~/' -e 't r' -e 's/~//' file

Możesz indentzamiast tego użyć .

Czy prosty sposób nie działa:

sed -r 's/ {4}/  /g'

Jeśli nie, opublikuj dane wejściowe tam, gdzie się nie powiedzie.

Jeśli mają być konwertowane tylko spacje wiodące:

sed 'h;s/[^ ].*//;s/    /  /g;G;s/\n *//'

Z komentarzami:

sed '
  h; # save a copy of the pattern space (filled with the current line)
     # onto the hold space
  s/[^ ].*//; # remove everything starting with the first non-space
              # from the pattern space. That leaves the leading space
              # characters
  s/    /  /g; # substitute every sequence of 4 spaces with 2.
  G; # append a newline and the hold space (the saved original line) to
     # the pattern space.
  s/\n *//; # remove that newline and the indentation of the original
            # line that follows it'

Zobacz także 'ts'ustawienia i :retabpolecenia vima

sed 's/^\( \+\)\1\1\1/\1\1/' file

Działa, dzieląc wiodące spacje na cztery wystąpienia tej samej grupy (więc wszystkie są równe), a następnie zastępując je tylko dwoma wystąpieniami grupy.

sed 's/    \{2,4\}\( \{0,1\}[^ ].*\)*/  \1/g' <input

To powinno tylko ścisnąć wiodące sekwencje przestrzeni.