Dlaczego moje oświadczenie IF nie widzi globalnego?

Jestem raczej nowy w programowaniu Arduino. Mam problem z kompilacją następującego fragmentu kodu:

const int relay1 = 10;  //Power Relay 1
const int relay2 = 11;  //Power Relay 2
const int relay3 = 12;  //Toggle Relay
const int button1 = 3;  
const int button2 = 4;
const int button3 = 5;

//---Button States---\\
int button1State;   //Current state of Button 1
int button2State;   //Current state of Button 2
int button3State;   //Current state of Button 3
int button1State_prev = LOW;  //Previous state of Button 1
int button2State_prev = LOW;  //Previous state of Button 2
int button3State_prev = LOW;  //Previous state of Button 3

//---General Variables---\\
int userSelection = 0;
int interlockState = 0;
int platformState = 0;

//---Interval-Tracking Variables---\\
unsigned long lastTime_Debounce1 = 0;   //Button 1 debounce time
unsigned long lastTime_Debounce2 = 0;   //Button 2 debounce time

//---Activity Delays---\\
const unsigned int relayDelay = 10;           //Delay between relay actions (ms)
const unsigned int debounceDelay = 60;        //Delay for button de-bouncing (ms)

void setup() {
  //Configure Pins
  pinMode(relay1, OUTPUT);
  pinMode(relay2, OUTPUT);
  pinMode(relay3, OUTPUT);
  pinMode(button1, INPUT);
  pinMode(button2, INPUT);
  pinMode(button3, INPUT);

  digitalWrite(relay1, LOW);
  digitalWrite(relay2, LOW);
  digitalWrite(relay3, LOW);
}

void loop() {
  //Read value of each input pin
  int button1Reading = digitalRead(button1);  //Current reading of Button 1
  int button2Reading = digitalRead(button2);  //Current reading of Button 2
  int button3Reading = digitalRead(button3);  //Current reading of Button 3

  //Debounce Button1
  if (button1Reading != button1State_prev) {
    lastTime_Debounce1 = millis();
  }
  button1State_prev = button1Reading;
  if ((millis() - lastTime_Debounce1) > debounceDelay) {
    if (button1Reading != button1State) {
      button1State = button1Reading;
    }
  }

  //Debounce Button2
  if (button2Reading != button2State_prev) {
    lastTime_Debounce2 = millis();
  }
  button2State_prev = button2Reading;
  if ((millis() - lastTime_Debounce2) > debounceDelay) {
    if (button2Reading != button2State) {
      button2State = button2Reading;
    }
  }

Z jakiegoś powodu kompilator jest przekonany, że zmienna lastTime_Debounce1w drugiej instrukcji IF, w wierszu 54, nie została zadeklarowana w zakresie. Nie rozumiem, jak to jest możliwe, ponieważ zmienna, o której mowa, jest zdefiniowaną i zainicjowaną globalną.

Jeśli skomentuję pierwsze trio instrukcji IF (obsługa przycisku 1), drugie trio (obsługa przycisku 2) nie będzie miało problemu z kompilacją, nawet jeśli robi dokładnie to samo w dokładnie ten sam sposób.

Sprawdzałem wszystkich zwykłych podejrzanych: pisownię, nawiasy klamrowe, średniki, a nawet pojedynczo komentowałem bloki kodu, ale nie mogę znaleźć źródła problemu. Korzystam z Arduino 1.8.2 IDE.

Czy ktoś może wskazać błąd, którego mi brakuje?

Problem stanowi odwrotny ukośnik w twoich komentarzach. Zgodnie z definicjami języka C ++, \na końcu linii jest interpretowana jako „kontynuacja linii”. W ten sposób twój komentarz jest kontynuowany w następnym wierszu, a twoja deklaracja zmiennej i inicjalizacja są komentowane.

Jest to widoczne podczas otwierania kodu za pomocą dobrego programu do wyróżniania składni, takiego jak Notepad ++.

Usunięcie wszystkich \\z końca wiersza komentarza rozwiązuje problem.

Uwaga dodatkowa: więcej informacji można znaleźć na stronie /programming//a/30290133/5296568 . Odwrotne ukośniki na końcu linii są w rzeczywistości przydatne, gdy są używane w wieloliniowych definicjach makr.