Jak mogę wyświetlić podgląd formuł TeX wbudowanych w dowolnych trybach?

Jak mogę uzyskać podgląd TeXa w trybach innych niż AUCTeX lub tryb org? Bardzo chciałbym zobaczyć równania TeX w Jabber, Erc i Markdown. Jeśli kiedykolwiek przestawię się na Emacsa na e-maile, prawdopodobnie chciałbym zobaczyć tam również podgląd.

Próbowałem ponownie użyć lateksu podglądu AUCTeX, ale nie udało mi się i zrezygnowałem.

Tryb Org zapewnia również tę samą funkcję . Okazało się, że weechat zdołał ponownie go użyć, aby automatycznie wyświetlić podgląd lateksu.

Wyodrębniłem część podglądu z Weechat w osobnym pliku, który można uzyskać w tym repozytorium . Jest również dostępny jako pxpakiet na MELPA (właśnie go przesłałem).

Istnieją 4 punkty wejścia, które można nazwać interaktywnie:

• px-preview: renderuj wszystkie fragmenty lateksu w bieżącym buforze.
• px-preview-region: renderuj fragmenty w regionie.
• px-remove: usuń wszystkie podglądy z bieżącego bufora (przywróć tekst).
• px-toggle: przełącza wyświetlanie podglądu w bieżącym buforze.

Tak długo, jak działa podgląd w trybie org, ten powinien działać.

Ponieważ kod jest wciąż dość mały, dołączę go poniżej, ale proszę zainstalować pakiet lub skorzystać z repo.

;;; px.el --- preview inline latex -*- lexical-binding: t -*-

;; Most of this code comes from weechat-latex.el which in turn uses
;; org-mode previewer.

;; Copyright (C) 2014 Aurélien Aptel <[email protected]>
;; Copyright (C) 2013 Rüdiger Sonderfeld <[email protected]>

;; This program is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with this program.  If not, see <http://www.gnu.org/licenses/>.

(require 'org)

(defvar px-temp-file-prefix "px-"
  "Prefix for temporary files.")

(defvar px-temp-directory-prefix "px-"
  "Prefix for temporary directory.")

(defvar px-image-program org-latex-create-formula-image-program
  "Program to convert LaTeX fragments.
See `org-latex-create-formula-image-program'")

(defvar px-temp-dir nil
  "The temporary directory used for preview images.")

(defun px--create-preview (at)
  "Wrapper for `org-format-latex'.
The parameter AT should be nil or in (TYPE . POINT) format.  With TYPE being a
string showing the matched LaTeX statement (e.g., ``$'') and POINT being the
POINT to replace.  If AT is nil replace statements everywhere."
  (org-format-latex px-temp-file-prefix
                    px-temp-dir
                    'overlays
                    "Creating images...%s"
                    at 'forbuffer
                    px-image-program))

(defun px--set-temp-dir ()
  "Set `px-temp-dir' unless it is already set."
  (unless px-temp-dir
    (setq px-temp-dir
          (make-temp-file px-temp-directory-prefix
                          'directory))))

(defun px-preview ()
  "Preview LaTeX fragments."
  (interactive)
  (save-excursion
    (let ((inhibit-read-only t))
      (px--set-temp-dir)
      (org-remove-latex-fragment-image-overlays)
      (px--create-preview nil))))

(defun px-preview-region (beg end)
  "Preview LaTeX fragments in region."
  (interactive "r")
  (let* ((math-regex (assoc "$" org-latex-regexps))
         (regex (nth 1 math-regex))
         (n (nth 2 math-regex))
         matches)
    (save-excursion
      (goto-char beg)
      (while (re-search-forward regex end t)
        (setq matches (cons (cons "$" (match-beginning n)) matches)))
      (let ((inhibit-read-only t))
        (px--set-temp-dir)
        (dolist (i matches)
          (px--create-preview i))))))


(defun px-remove ()
  "Remove LaTeX preview images."
  (interactive)
  (let ((inhibit-read-only t))
    (org-remove-latex-fragment-image-overlays)))

(defun px-is-active? ()
  "Are LaTeX Previews currently displayed?"
  org-latex-fragment-image-overlays)

(defun px-toggle ()
  "Toggle display of LaTeX preview."
  (interactive)
  (if (px-is-active?)
      (px-remove)
    (px-preview)))


(provide 'px)

Jest też to, texfrag.elco działa od razu po dodaniu komentarzy doxygen prog-mode.

Możesz zainstalować texfrag.elz melpa-stablepoprzez M-x package-install RET texfrag RET.

Uruchom, M-x texfrag-mode RETaby aktywować podgląd. Otrzymasz menu Podgląd ze wszystkimi elementami pakietu podglądu AUCTeX.

Uwaga: texfragdziała to również w przypadku edycji źródła HTML, eww i trybu org.