Rozdziel ciąg tekstowy na osobne kolumny w programie Excel

Potrzebuję formuły Excel, aby rozdzielić wiele nazw w jednej kolumnie na trzy. Jedna pojedyncza komórka zawiera obecnie: Jackson Hakel Brynn Holohan John Holohan. Potrzebuję trzech kolumn z imieniem i nazwiskiem, tj .:

Column1          Column 2          Column3
Jackson Hakel    Brynn Holohan     John Holohan.

Z ograniczeniem / założeniem, że pomiędzy każdym imieniem i nazwiskiem jest jedna spacja, to się powtarza dla 3 nazwisk i nie ma tam czwartego imienia, spróbuj wykonać następujące czynności.

Zakładając, że Twoje dane znajdują się w komórce B4

Komórka C4

=LEFT(B4,SEARCH(" ",B4,SEARCH(" ",B4)+1)-1)

Komórka D4

=LEFT((RIGHT(B4,LEN(B4)-LEN(C4)-1)),SEARCH(" ",(RIGHT(B4,LEN(B4)-LEN(C4)-1)),SEARCH(" ",(RIGHT(B4,LEN(B4)-LEN(C4)-1)))+1)-1)

Komórka E4

=RIGHT(B4,LEN(B4)-(LEN(C4)+LEN(D4)+2))

Pokażę ci bardzo prosty przykład, z którego powinieneś być w stanie skorzystać podobnie w swoim przypadku. Rozdzieliłem formuły, aby ułatwić naukę.

Najpierw zacznę od niektórych danych, podzielonych przez spację taką jak ty. Zasadniczo chcesz rozgraniczać swoje dane w każdej innej przestrzeni, więc to właśnie zrobię.

Najpierw znajduję lokalizację pierwszego miejsca:

Po drugie, znajduję lokalizację drugiej przestrzeni, zaczynając od miejsca, w którym znaleźliśmy pierwszą:

Teraz, gdy znamy położenie drugiej spacji, po prostu przytnij oryginalny tekst do drugiej spacji:

Na koniec pokaż pozostały tekst z przyciętym frontem:

Teraz, aby dalej dzielić, po prostu powtórz poprzednie metody z ostatniej komórki. Jak wspomniałem na początku, formuły są podzielone na części, dzięki czemu można się uczyć, ale w celu uproszczenia zajmowanej przestrzeni można łączyć formuły.

Mam nadzieję że to pomoże!

W przypadku danych w A1 , w B1 wprowadź:

=TRIM(MID(SUBSTITUTE($A1," ",REPT(" ",999)),COLUMNS($A:A)*999-998,999)) & " " & TRIM(MID(SUBSTITUTE($A1," ",REPT(" ",999)),COLUMNS($A:B)*999-998,999))

W C1 wprowadź:

=TRIM(MID(SUBSTITUTE($A1," ",REPT(" ",999)),COLUMNS($A:C)*999-998,999)) & " " & TRIM(MID(SUBSTITUTE($A1," ",REPT(" ",999)),COLUMNS($A:D)*999-998,999))

a w D1 wprowadź:

=TRIM(MID(SUBSTITUTE($A1," ",REPT(" ",999)),COLUMNS($A:E)*999-998,999)) & " " & TRIM(MID(SUBSTITUTE($A1," ",REPT(" ",999)),COLUMNS($A:F)*999-998,999))