Narzędzie Windows do renderowania, który klawisz naciskam na ekranie [zamknięty]

Prowadzę szkolenie dużej grupy osób zdalnie i będę obejmował wiele klawiszy skrótu do aplikacji.

Widziałem ekranowe naciśnięcia klawiszy MousePose ; czy istnieje podobny produkt dla systemu Windows?

Inne funkcje MousePose (fantazyjne wskaźniki myszy itp.) Nie są dla mnie naprawdę przydatne, tylko OSD naciśnięć klawiszy.

KeyPosé to darmowa alternatywa dla MousePosé dla Windows. Możesz to zobaczyć w akcji w screencastie .

Oto przykładowy zrzut ekranu:

Bardzo polecam Carnac . To darmowy projekt hostowany na GitHub.

Narzędzie do rejestrowania i prezentacji za pomocą klawiatury do prezentacji, screencastów i aby pomóc Ci stać się lepszym użytkownikiem klawiatury.

Jest ładnie wykonany, ładnie zaprojektowany, a także otwarty na GitHub .

Znajdź wersję dla rozwidleń z poprawkami i wizualizacją wprowadzania myszy tutaj: https://github.com/bfritscher/carnac/releases/tag/v3-beta

Chciałbym udostępnić moje narzędzie - keycastow.

https://brookhong.github.io/2014/04/28/keycast-on-windows.html

W tym celu napisałem skrypt AutoHotkey_L.

Aby go uruchomić, użyj AutoHotkey_L ( bezpośredni dl ), to FOSS. Ponadto dzięki AutoHotkey możesz skompilować skrypt do EXE (po prostu ).Ahk2Exe.exe /inDisplayPressedKeyOnScreen.ahk/outDisplayPressedKeyOnScreen.exe

Może wyświetlać wciśnięte klawisze podobne do OSD lub standardowej końcówki narzędzia w pobliżu kursora myszy. Wyświetla również kliknięcia przycisku myszy i przewijanie kół.

(zauważ, że kadrowanie i rozmycie odbywa się w celach ilustracyjnych, sam skrypt wyświetla tylko tekst bez żadnych zakłóceń)

Oto skrypt (skopiuj i wklej do notatnika, zapisz jako DisplayPressedKeysOnScreen.ahk):

#NoEnv
#SingleInstance force
#InstallKeybdHook

Global KeyStates, MouseState, ClickCount, IdleDelay, LargeDisplay

IdleDelay=3000

LargeDisplay=1
; 0 = Tooltip near mouse pointer
; 1 = Big pane at screen bottom

If LargeDisplay
{
;Initializing GUI
;modded func originated from http://www.autohotkey.com/board/topic/8190-osd-function/

SysGet Monitor, Monitor

GUIx := MonitorLeft
GUIw := MonitorRight - MonitorLeft
GUIh := (MonitorBottom - MonitorTop) * GUIw * 0.00003
If (GUIh > ((MonitorBottom - MonitorTop) * 0.3))
    GUIh := (MonitorBottom - MonitorTop) * 0.3

opacity=230
fname="Tahoma"
fsize:=GUIh * 0.65 ; really, pixel = 0.75 point, but with 0.75 lowercase letter with lower part (like "g") get cut
fcolor=cccccc
bcolor=222222
fformat="600"

Gui +LastFound +AlwaysOnTop +ToolWindow -Caption
Gui Margin, 0, 0 ;pixels of space to leave at the left/right and top/bottom sides of the window when auto-positioning.
Gui Color, ffffff ;changes background color
Gui Font, s%fsize% w%fformat%, %fname%

;    0x80 = SS_NOPREFIX -> Ampersand (&) is shown instead of underline one letter for Alt+letter navigation
Gui Add, Text, c%bcolor% Center +0x80 w%GUIw% h%GUIh% BackgroundTrans VblkOsdCtrlName, tesT test test
Gui Add, Text, c%fcolor% Center +0x80 w%GUIw% h%GUIh% BackgroundTrans VblkOsdCtrlName2 xp-3 yp-3 , tesT test test

WinSet ExStyle, +0x20 ; WS_EX_TRANSPARENT -> mouse klickthrough
WinSet TransColor, ffffff %opacity%
}


TrayTip %A_ScriptName%, To Exit`, press the Right Windows logo key.

Loop
{
Input SingleKey, L1 V M I B, {LControl}{RControl}{LAlt}{RAlt}{LShift}{RShift}{LWin}{AppsKey}{F1}{F2}{F3}{F4}{F5}{F6}{F7}{F8}{F9}{F10}{F11}{F12}{Left}{Right}{Up}{Down}{Home}{End}{PgUp}{PgDn}{Del}{Ins}{BS}{Capslock}{Numlock}{PrintScreen}{Pause}
GetKeyStates()

;    IfInString ErrorLevel, EndKey
;   CollectedText .= (CollectedText =="" ? "" : " + " ) . SubStr(ErrorLevel, 8)
If SingleKey
{
    SingleKeyText=
    If (SingleKey==Chr(27))
    SingleKeyText=Esc
    Else If (SingleKey==Chr(32))
    SingleKeyText=Space

    If (GetKeyState("LControl", "P") || GetKeyState("RControl", "P"))
    {
    If (SingleKey==Chr(10) && EnterPressed)
        SingleKeyText=Enter
    Else If (SingleKey >= Chr(1) && SingleKey <= Chr(26)) ; With "M" in Input, Ctrl-A through Ctrl-Z correspond to Chr(1) through Chr(26)
        SingleKeyText := Chr(Asc("A")-1+Asc(SingleKey))
    } Else {
    If (SingleKey==Chr(10))
        SingleKeyText=Enter
    }

    If Not SingleKeyText
    SingleKeyText:=SingleKey
    ShowKeys(KeyStates . SingleKeyText)
;    . (MouseState ? "`n" . MouseState : "")
    EnterPressed=0
    GoSub ClearMouseState
} Else {
    ShowKeys(SubStr(KeyStates, 1, -3) . (MouseState ? " + " . MouseState : ""))
}
SetTimer TooltipOff, % -IdleDelay
}

RWin::
ExitApp

~*Enter::
EnterPressed=1
return

~*LButton::
~*RButton::
~*MButton::
~*XButton1::
~*XButton2::
MouseState := "Mouse " . SubStr(A_ThisHotkey, 3) . " Pressed"
MouseTooltip()
return

~*WheelDown::
~*WheelUp::
~*WheelLeft::
~*WheelRight::
MouseState := "Mouse " . SubStr(A_ThisHotkey, 3)
MouseTooltip()
return

~*LButton Up::
~*RButton Up::
~*MButton Up::
~*XButton1 Up::
~*XButton2 Up::
;    MsgBox %A_PriorHotkey%`n%A_ThisHotkey%
If (A_PriorHotkey == SubStr(A_ThisHotkey, 1, -3) && A_TimeSincePriorHotkey < 200)
{
    ClickCount++
    Suffix := " Clicked " . ClickCount . "x"
} Else {
    ClickCount:=0
    Suffix := " Released"
}
MouseState := "Mouse " . SubStr(A_ThisHotkey, 3, -3) . Suffix
MouseTooltip()
return

MouseTooltip(){
GetKeyStates()
ShowKeys(KeyStates . MouseState)
SetTimer ClearMouseState,  % -IdleDelay
SetTimer TooltipOff, % -IdleDelay
}

ClearMouseState:
MouseState=
ClickCount=0
return
TooltipOff:
If LargeDisplay
    Gui Hide
Else
    Tooltip
return

GetKeyStates() {
KeyStates := ""
    . ( GetKeyState("LControl", "P") ? "LControl + " : "" )
    . ( GetKeyState("RControl", "P") ? "RControl + " : "" )
    . ( GetKeyState("LAlt", "P") ? "LAlt + " : "" )
    . ( GetKeyState("RAlt", "P") ? "RAlt + " : "" )
    . ( GetKeyState("LShift", "P") ? "LShift + " : "" )
    . ( GetKeyState("RShift", "P") ? "RShift + " : "" )
    . ( GetKeyState("LWin", "P") ? "LWin + " : "" )
    . ( GetKeyState("AppsKey", "P") ? "AppsKey + " : "" )
    . ( GetKeyState("F1", "P") ? "F1 + " : "" )
    . ( GetKeyState("F2", "P") ? "F2 + " : "" )
    . ( GetKeyState("F3", "P") ? "F3 + " : "" )
    . ( GetKeyState("F4", "P") ? "F4 + " : "" )
    . ( GetKeyState("F5", "P") ? "F5 + " : "" )
    . ( GetKeyState("F6", "P") ? "F6 + " : "" )
    . ( GetKeyState("F7", "P") ? "F7 + " : "" )
    . ( GetKeyState("F8", "P") ? "F8 + " : "" )
    . ( GetKeyState("F9", "P") ? "F9 + " : "" )
    . ( GetKeyState("F10", "P") ? "F10 + " : "" )
    . ( GetKeyState("F11", "P") ? "F11 + " : "" )
    . ( GetKeyState("F12", "P") ? "F12 + " : "" )
    . ( GetKeyState("Left", "P") ? "Left + " : "" )
    . ( GetKeyState("Right", "P") ? "Right + " : "" )
    . ( GetKeyState("Up", "P") ? "Up + " : "" )
    . ( GetKeyState("Down", "P") ? "Down + " : "" )
    . ( GetKeyState("Home", "P") ? "Home + " : "" )
    . ( GetKeyState("End", "P") ? "End + " : "" )x
    . ( GetKeyState("PgUp", "P") ? "PgUp + " : "" )
    . ( GetKeyState("PgDn", "P") ? "PgDn + " : "" )
    . ( GetKeyState("Del", "P") ? "Del + " : "" )
    . ( GetKeyState("Ins", "P") ? "Ins + " : "" )
    . ( GetKeyState("BS", "P") ? "BS + " : "" )
    . ( GetKeyState("Capslock", "P") ? "Capslock + " : "" )
    . ( GetKeyState("Numlock", "P") ? "Numlock + " : "" )
    . ( GetKeyState("PrintScreen", "P") ? "PrintScreen + " : "" )
    . ( GetKeyState("Pause", "P") ? "Pause + " : "" )
}

ShowKeys(text) {
If LargeDisplay
{
    Global blkOsdCtrlName, blkOsdCtrlName2, MonitorLeft, MonitorRight, MonitorBottom, MonitorTop, GUIx, GUIy, GUIh

    CoordMode Mouse, Screen
    MouseGetPos MouseX, MouseY

    If ((!GUIy) || (MouseX >= MonitorLeft && MouseX <= MonitorRight && MouseY >= GUIy && MouseY <= (GUIy+GUIh)) ) {
    If (MouseY < (MonitorTop + (MonitorBottom - MonitorTop) / 2) )
        GUIy := MonitorBottom - (MonitorBottom - MonitorTop) * 0.2
    Else
        GUIy := MonitorTop + (MonitorBottom - MonitorTop) * 0.2
    }

    GuiControl Text, blkOsdCtrlName, %text%
    GuiControl Text, blkOsdCtrlName2, %text%

    Gui, Show, x%GUIx% y%GUIy% NoActivate
} Else {
    Tooltip % text
}
}

Za pomocą klawiatury ekranowej można wyświetlać naciśnięcia klawiszy w systemie Windows. Po wpisaniu na klawiaturze fizycznej na ekranie jeden z nich podświetlany jest ten klawisz.

Wskaźnik prezentacji jest najlepszą alternatywą dla MousePosé dla Windows. Zapewnia efekt wskaźnika, efekt kliknięcia myszą, naciśnięcia klawiszy, a nawet pozwala swobodnie rysować na ekranie, ale nie blokować ekranu. To naprawdę zaleta programu.

PointerFocus może wyświetlać naciśnięcia klawiszy.

Napisałem małą aplikację dla systemu Windows o nazwie QiPress . Posiada elementy sterujące do zmiany wyglądu, wyświetlania lub ignorowania niektórych grup kluczy, a nawet dodawania tekstu statycznego (na przykład własnego imienia lub nazwy firmy). Pozycjonowanie jest możliwe poprzez wyłączenie pop-upu i przeciąganie pop-upu. Istnieją inne funkcje, których prawdopodobnie nie potrzebujesz, ale obejmują one głównie to, czego chcesz.

Możesz użyć PassMark KeyboardTest (bezpłatna 30-dniowa wycena, a następnie 24,00 USD do zakupu).

FYI:

• Podobne pytanie zadano na SO: Jak wyświetlać wciśnięte skróty klawiaturowe na ekranie podczas prezentacji lub screencastów
• Podobne pytanie zadano dla OS X: https://apple.stackexchange.com/q/62168/20338
• Powiązane pytanie zostało zadane na temat rekomendacji oprogramowania (OP prosi program o wyświetlenie klawiszy, które użytkownik aktualnie naciska podczas korzystania z innych programów. Powinien pokazać wszystkie naciśnięte klawisze, a gdy tylko użytkownik zwolni klawisz - powinien zniknąć. ): Narzędzie do wyświetlania na ekranie aktualnie naciśniętych klawiszy