Czy istnieje sposób na wypchnięcie i usunięcie wszystkich zmiennych środowiskowych w skrypcie wsadowym?

Czy istnieje sposób na wypchnięcie i usunięcie wszystkich zmiennych środowiskowych w skrypcie wsadowym? Na przykład chciałbym zrobić coś takiego:

pushEnvironmentVariables
call "%VS140COMNTOOLS%\vsvars32.bat"
(do some stuff...)
popEnvironmentVariables
pushEnvironmentVariables
call "%VS90COMNTOOLS%\vsvars32.bat"
(do some other stuff...)
popEnvironmentVariables

Użyj setlocal, patrz setlocal /?lub ss64.com/nt/setlocal

Setlocal
call "%VS140COMNTOOLS%\vsvars32.bat"
(do some stuff...)
Endlocal
Setlocal
call "%VS90COMNTOOLS%\vsvars32.bat"
(do some other stuff...)
Endlocal

Aby zapisać bieżący stan zmiennej, możesz to zrobić

set >MyVarStatus.txt

i przywróć później za pomocą

@Echo off
For /f "tokens=1* delims==" %%A in (
  'findstr /V "^Path" MYVarStatus.txt '
) Do Set %%A=%%B

wykluczałoby to zmienne Path.

Trochę za późno na scenę, ale i tak idzie. Poniżej znajduje się implementacja struktury danych stosu w skryptach wsadowych Windows.

Funkcje:

• Przed użyciem stosu należy wywołać podprogram : InitializeStack .
• Wciśnij przedmioty na stos, wywołując podprogram : Push .
• Usuń elementy ze stosu, wywołując podprogram : Pop .
• Zmienna $ Count zawsze będzie zawierała liczbę elementów na stosie.
• Zmienna $ Top zawsze będzie zawierała najnowszy element dodany do stosu.
• Zmienna $ Bottom zawsze będzie zawierać pierwszy element dodany do stosu.
• Możesz zrzucić zawartość stosu, wywołując podprogram : DumpStack .
• Typ elementów, które można wcisnąć na stos, to wszystko, co można przechowywać w zmiennej. Na przykład Call: Push „String 1” , Call: Push „% 1” , Call: Push „% MyVariable%” itp.

Używam stosu w plikach wsadowych do śledzenia wywołań podprogramów. Każdy podprogram w moich plikach wsadowych zaczyna się od Call: Push% 0 , który wypycha nazwę bieżącego podprogramu na stos i kończy się Call: Pop .

Niektórzy mogą go znaleźć nadmierne zabić skryptów wsadowych, ale cieszył się tworząc go i mam nadzieję, że ktoś znajdzie to użyteczne, cieszyć .

@Echo Off
Cls
SetLocal
SetLocal EnableExtensions
SetLocal EnableDelayedExpansion

Call :InitializeStack

Call :Push "String 1"
Call :Push "String 2"
Call :Push "String 3"
Call :Pop

Echo Total items in stack = !$Count!
Echo Top of stack         = !$Top!
Echo Bottom of stack      = !$Bottom!
Call :DumpStack

Goto End

:InitializeStack
:------------------------------------------------------------
Set "$Stack[0]=0"
Set "$Count=!$Stack[0]!"
Set "$Top="
Set "$Bottom="
Exit /b

:DumpStack
:------------------------------------------------------------
If !$Stack[0]! EQU 0 (
  Echo Stack is empty.
) Else (
  Echo.
  Echo Stack Dump
  Echo ----------
  For /l %%a In (!$Stack[0]!,-1,1) Do (Echo !$Stack[%%a]!)
)
Exit /b

:Push <String>
:------------------------------------------------------------
Set /a "$Stack[0]+=1"
Set "$Count=!$Stack[0]!"
Set "$Top=%~1"
Set "$Bottom=!$Stack[1]!"
Set "$Stack[!$Stack[0]!]=!$Top!"
Exit /b

:Pop
:------------------------------------------------------------
If !$Stack[0]! EQU 0 (
  Echo "Stack is empty."
) Else (
  Set "$Stack[!$Stack[0]!]="
  Set /a "$Stack[0]-=1"
  Set "$Count=!$Stack[0]!"
  If !$Stack[0]! GTR 0 (
    For %%a In (!$Stack[0]!) Do Set "$Top=!$Stack[%%a]!"
    Set "$Bottom=!$Stack[1]!"
  ) Else (
    Set "$Top="
    Set "$Bottom="
  )
)Exit /b

:PushAllEnvironmentVariables
:------------------------------------------------------------
For /f "Tokens=* Delims=" %%a In ('Set') Do Call :Push "%%a"
Exit /b

:PopAllEnvironmentVariables
:------------------------------------------------------------
For /l %%a In (!$Stack[0]!,-1,1) Do (Set !$Stack[%%a]!)
Exit /b

:End

Aby wypchnąć wszystkie zmienne środowiskowe, które możesz wywołać: PushAllEnvironmentVariables, aby przywrócić wszystkie zmienne środowiskowe, możesz wywołać: PopAllEnvironmentVariables