Czy chcesz uzyskać nazwę bieżącego folderu za pomocą polecenia DOS?

Czy można uzyskać nazwę bieżącego folderu (nie bieżącą ścieżkę katalogu) za pomocą polecenia DOS? Jeśli tak to jak?

Najbliżej było to, ale to nie robi:

for /f "delims=\" %%a in ("%CD%") do set CURR=%%a
echo.DIR: %CURR%

Uwaga: powyższa próba polegała na tym, że próbowałem tokenizować ciąg i uzyskać ostatni zestaw tokenów jako zmienną CURR.

Najkrótsza droga, jaką znalazłem:

for %I in (.) do echo %~nxI

lub w skrypcie .bat:

for %%I in (.) do echo %%~nxI

lub w .bat z Uzyskaj wartość w zmiennej.

for %%I in (.) do set CurrDirName=%%~nxI
echo %CurrDirName%

Objaśnienie: http://www.robvanderwoude.com/ntfor.php

nx oznacza tylko nazwę pliku i rozszerzenie

Jeśli chcesz poznać bieżącą lokalizację pliku wsadowego (i jeśli twój system Windows nie jest bardzo starą wersją), wpisz for /?okno „DOS box”. Przewiń w dół. Czytać.

Dowiesz się, że można teraz czytać (od wewnątrz pliku wsadowego) tych zmiennych:

%0      - as the name how this batchfile was called
%~d0    - as the drive letter where this batchfile is located ('\\' in case of share)
%~p0    - as path (without the drive letter) where this batchfile is located
%~n0    - as filename (without suffix) of this batchfile
%~x0    - as filename's suffix (without filename) of this batchfile
%~a0    - as this batchfile's file attributes
%~t0    - as this batchfile's date+time
%~z0    - as this batchfile's filesize
%~dpnx0 - as this batchfile's fully qualified path+filename
[... and then some more ...]

Działa to w wielu przypadkach. Załóżmy, że plik wsadowy jest nazywany mytest.bat. Możesz to nazwać na różne sposoby:

1. ..\..\to\mytest.bat ............................... (ścieżka względna)
2. d:\path\to\mytest.bat........................... (pełna ścieżka)
3. \\fileserver\sharename\mytest.bat... (ścieżka do zdalnego udostępniania)

... i zawsze otrzymasz odpowiednią wartość w swoich zmiennych.

Osobiście podobała mi się odpowiedź Toma, dopóki nie zmagała się z kropkami w nazwach reż. To dało mi wskazówkę:

for /f "delims=\" %%a in ("%cd%") do echo topmost dir: %%~nxa

Odpowiedź Toma jest dobra, ale jeśli masz nazwę katalogu z kropką (tj. Wxwidgets-2.9.4), otrzymasz tylko pełną nazwę. Wynikiem tego byłby wynik wxwidgets-2.9, ponieważ .4 został potraktowany jako rozszerzenie (Tak, mimo że jest to nazwa katalogu!).

Aby uzyskać pełną nazwę wyjściową, musisz dodać rozszerzenie na końcu:

FOR %I IN (.) DO Echo %~nI%~xI

oraz w trybie pliku wsadowego:

FOR %%I IN (.) DO Echo %%~nI%%~xI

Lub, zamiast tego, ustaw zmienną w pliku wsadowym:

FOR %%I IN (.) DO SET CurrentD=%%~nI%%~xI

Innym sposobem jest:

set "MyPath=%~dpnx0" & call set "MyPath=%%MyPath:\%~nx0=%%" 
echo MyPath=%MyPath%  

działa z „.” i spacje w nazwie ścieżki

Co to robi?

1. umieść całą nazwę pliku (driveelet-path-filename-extension) w MyPathVar

2. usuń nazwę pliku i rozszerzenie z MyPathvar

Działa również ze ścieżkami UNC. Jeśli potrzebujesz ukośnika na końcu ścieżki. Usuń \po MyPathw drugim poleceniu set, np.

set "MyPath=%%MyPath:%~nx0=%%"

Możesz przekształcić bieżący katalog w zmienną. Jednowarstwowy:

set a=%cd%

Sprawdź z

echo %a%

poprostu

for %%d in ("%CD%") do echo %%~nxd

lub

set "sPath=."
for %%d in ("%sPath%") do set "sDirName=%%~nxd"

Uważaj na odwrotny koniec końca ścieżki, nie musi to być odwrotny koniec końca.

Moja odpowiedź w tym wątku składa się z 3 prostych linii:

@echo off
SET "CDIR=%~dp0"
:: for loop requires removing trailing backslash from %~dp0 output
SET "CDIR=%CDIR:~0,-1%"
FOR %%i IN ("%CDIR%") DO SET "PARENTFOLDERNAME=%%~nxi"
ECHO Parent folder: %PARENTFOLDERNAME%
ECHO Full path: %~dp0
pause>nul

To działa dla mnie z pliku wsadowego. Zwraca bieżącą nazwę katalogu roboczego.

pushd %1 & for %%i in (.) do @echo %%~ni