Excel: Jak odwołać się do całego wiersza oprócz kilku komórek?

28

Chcę móc sumować wartości całego wiersza z wyjątkiem pierwszych 2 komórek. Więc coś takiego:

=sum(A3:A*infinity*)

Jak mam to zrobic?

microsoft-excel cells Wir
źródło
1
Konieczne może być edytowanie pytania lub przykładu. Chcesz odwołać się do całego wiersza, ale twój przykład sumuje kolumnę danych.
Ellesa
Najlepsza odpowiedź na to pytanie znajduje się tutaj: superuser.com/a/1259946/342034 . Zauważ, że mam na myśli szczególnie odpowiedź, do której linkowałem, przez BBK. Nie przewijaj w górę i nie szukaj odpowiedzi akceptowanych lub najpopularniejszych. Odpowiedź BBK ma tylko dwa pozytywne głosy na ten tekst, ale to naprawdę jedyna prawdziwie poprawna odpowiedź na to pytanie.
Adi Inbar
Możliwy duplikat zaznaczania całej kolumny oprócz pierwszych komórek X (nagłówka) w Excelu
Adi Inbar

Odpowiedzi:

17

Coś podobnego zostało już zadane i powtórzę tę odpowiedź : po prostu wstaw:

=sum(a3:a1048576)

ponieważ jest to maksymalna liczba komórek na kolumnę / wiersz w pakiecie Office 2007 i 2010. (65536 wynosi maks. przed 2007 rokiem). (W przypadku kolumn maksymalna nazwa kolumny to XFD w 2007 i 2010 r. i IV przed 2007 r.)

Joseph Hansen
źródło
Myślę, że to jedyny sposób, aby to zrobić, jeśli sama formuła znajduje się w tym samym wierszu. Dzięki
Eddy
13

Dodaj wszystko, a następnie zabierz te, których nie chcesz uwzględniać:

=SUM(A:A)-A1-A2

Edytować:

Jak zauważył josmh, powyższa formuła zawiedzie z błędem, jeśli A1 lub A2 nie są numeryczne - ale następujące funkcje będą działać:

=SUM(A:A)-SUM(A1,A2)

lub

=SUM(A:A)-SUM(A1:A2)

lub (dla odrobiny zabawy!)

=SUM(A:A,(-1*(SUM(A1))),(-1*SUM((A2))))

Działają, ponieważ funkcja SUM ignoruje pola nienumeryczne

Linker3000
źródło
3
To nie zadziała, jeśli A1 lub A2 to nagłówki zawierające tekst, taki jak „Liczba osób” lub „Cena”. Odejmowanie „ceny” od liczby powoduje błąd formuły.
Joseph Hansen
Wystarczy owinąć i „IFERROR” następnie
James
Przepraszam, jeśli pojawił się komentarz. Pozytywne teraz!
Joseph Hansen
Czy to zadziała, jeśli komórka z formułą znajduje się w tym samym rzędzie, powiedzmy w A1?
Eddy
@Eddy Nie, to utworzy odwołanie cykliczne.
Adi Inbar
5

Aby zsumować cały wiersz :

=sum(1:1)

Zastąp 1 początkowym numerem wiersza, a następnie odpowiednio użyj uchwytu autouzupełniania. Jeśli przeciągniesz formułę w dół, zmieni się ona na „= suma (2: 2)” itd.

Aby zsumować cały wiersz , z wyjątkiem pierwszych 2 kolumn :

=sum(1:1)-sum($a1:$b1)

Pomoże to zmniejszyć rozmiar pliku.

Ellesa
źródło
5

To już ma kilka dobrych odpowiedzi, ale oto metoda, której jeszcze nie widziałem:

=SUM(OFFSET(3:3,0,2,1,COLUMNS(3:3)-2))

Format to SUM(OFFSET(Range, Rows, Cols, [Height], [Width])). Zaczynamy od całego zakresu, przesuwamy go zero rzędów w dół i dwie kolumny ponad, ustawiamy wysokość na 1 i ustawiamy szerokość na jej bieżącą szerokość minus dwa. Dopóki regulacja szerokości jest taka sama jak przesunięcie, działa idealnie. Oto ten sam pomysł, aby zsumować kolumnę zamiast wiersza: (Zauważ, że nie musisz używać Widthparametru, ponieważ chcesz mieć taką samą szerokość jak oryginalny zakres).

=SUM(OFFSET(A:A,2,0,ROWS(A:A)-2))

Zaletą tych formuł w porównaniu z obecnie akceptowaną odpowiedzią jest to, że działają one w dowolnej wersji programu Excel. Nie zmieni również zakresu, jeśli wstawisz komórki z przodu, ponieważ odnosi się do całego wiersza / kolumny. Możesz lub nie chcieć tej funkcji w zależności od konfiguracji danych.

Inżynier Toast
źródło
To właściwie najlepsza odpowiedź. Jest tak blisko, =sum(A3:A*infinity*)jak pozwala Microsoft Excel. Niestety każde odniesienie należy wprowadzić dwukrotnie (jeden dla funkcji OFFSET i drugi dla funkcji ROWS).
Kevin Li
5

Myślałem, że możesz po prostu wykonać następujące czynności: = SUMA (A3: A)

Edycja : Przepraszam, że źle przeczytałem, to jest dla kolumny

W przypadku wierszy zobacz zatwierdzoną odpowiedź.

skube
źródło
1
Pamiętam, jak to robiłem w poprzedniej pracy, którą miałem, ale w mojej wersji pakietu Office 2007 obecnie notacja nie działa w formułach lub jeśli wpiszesz ją w polu Nazwa.
p0lar_bear
1
to właściwie poprawna odpowiedź
voxobscuro,
1
Nie podoba się to w programie Excel dla komputerów Mac 15.36
będzie
W przypadku programu Microsoft Excel 2016 tak powinno być =SUM(A3:A:A).
Keith OYS
W programie Excel 2013 =SUM(A3:A:A)wydaje się być taki sam jak =SUM(A:A). (Dziwi mnie, że nie jest to błąd składniowy.)
Scott
0

Możesz także wybrać komórki w wierszu lub kolumnie, wybierając pierwszą komórkę, a następnie naciskając klawisz CTRL+ SHIFT+ ARROW( RIGHT ARROWlub LEFT ARROWdla wierszy, STRZAŁKA W GÓRĘ lub STRZAŁKA W DÓŁ dla kolumn).

Uwaga Jeśli wiersz lub kolumna zawiera dane, CTRL + SHIFT + STRZAŁKA wybiera wiersz lub kolumnę do ostatnio używanej komórki. Drugie naciśnięcie klawiszy CTRL + SHIFT + STRZAŁKA powoduje zaznaczenie całego wiersza lub kolumny.

PS.
Szkoda, że ​​Excel nie ma tej samej sztuczki, co Arkusze Google . Np. aby wybrać od C2 do C ( nieskończoność ), możesz to zrobić:

SUM(C2:2)
Serge
źródło
Czy jesteś pewien, że to działa? Z pewnością nie działa w programie Excel 2013. Jest to ta sama odpowiedź, którą Skube opublikował ponad 2 lata temu.
Inżynier Toast