Jak utworzyć skrót za pomocą skryptu wsadowego? [duplikować]

Jak mogę utworzyć skrót do pliku D:\myfile.extensionna pulpicie za pomocą skryptu wsadowego?

Możesz to osiągnąć bez zewnętrznych narzędzi, tworząc tymczasowy VBScript:

@echo off

set SCRIPT="%TEMP%\%RANDOM%-%RANDOM%-%RANDOM%-%RANDOM%.vbs"

echo Set oWS = WScript.CreateObject("WScript.Shell") >> %SCRIPT%
echo sLinkFile = "%USERPROFILE%\Desktop\myshortcut.lnk" >> %SCRIPT%
echo Set oLink = oWS.CreateShortcut(sLinkFile) >> %SCRIPT%
echo oLink.TargetPath = "D:\myfile.extension" >> %SCRIPT%
echo oLink.Save >> %SCRIPT%

cscript /nologo %SCRIPT%
del %SCRIPT%

(Pomysł zaczerpnięty stąd .)

Spowoduje to utworzenie myshortcut.lnkna pulpicie, wskazując na D:\myfile.extension.

Możesz podać dodatkowe właściwości przed zapisaniem łącza, modyfikując następujące wartości:

oLink.Arguments
oLink.Description
oLink.HotKey
oLink.IconLocation
oLink.WindowStyle
oLink.WorkingDirectory

Zobacz, jak utworzyć skrót na pulpicie za pomocą Windows Script Host, aby zobaczyć kilka przykładów.

@echo off
echo [InternetShortcut] >> "%AllUsersProfile%\desktop\NOTEPAD.url"
echo URL="C:\WINDOWS\NOTEPAD.EXE" >> "%AllUsersProfile%\desktop\NOTEPAD.url"
echo IconFile=C:\WINDOWS\system32\SHELL32.dll >> "%AllUsersProfile%\desktop\NOTEPAD.url"
echo IconIndex=20 >> "%AllUsersProfile%\desktop\NOTEPAD.url"

Ten kod tworzy skrót w folderze pulpitu „Wszyscy użytkownicy” o nazwie NOTEPAD.url wskazujący na aplikację NotePad, a także przypisuje ikonę z SHELL32.dll. Zmień ścieżkę i nazwę pliku na lokalizację D: / i nazwę. I upewnij się, że nazwa pliku .url pozostaje taka sama we wszystkich liniach kodu.

istnieje zewnętrzny skrót shortcut.exe, który może to zrobić w następujący sposób:

shortcut /a:c /f:"c:\users\me\desktop\myshortcut.lnk" /t:"c:\program files\skype\skype.exe"

który może utworzyć skrót skype na pulpicie

jest to darmowy program do pobrania, ale nie mogę znaleźć jego linku, więc spróbuję go przesłać i opublikować link

tutaj jest :

shortcut.exe według Marty List