Wysyłaj masowe wiadomości e-mail po otrzymaniu wiadomości e-mail z określonego adresu w programie Outlook lub Thunderbird

Chcę filtru lub reguły, która pozwala mi wysyłać masowe wiadomości e-mail do około 200 odbiorców, gdy wiadomość e-mail zostanie odebrana z określonego adresu. Na przykład, gdy klient poczty e-mail otrzyma wiadomość e-mail od [email protected], chcę, aby ponownie wysłała wiadomość e-mail do wszystkich osób w mojej książce adresowej.

Próbowałem ustawić reguły zarówno w klientach pocztowych Outlook, jak i Thunderbird, ale jedyną dostępną opcją jest „Prześlij”, a nie „Wyślij ponownie” lub „Wyślij” e-mail. istnieje dodatkowy problem polegający na tym, że wszyscy adresaci pojawiają się na liście adresów. Chcę, aby wszyscy adresaci byli UDW.

Czy jest na to jakiś sposób?

Możesz utworzyć regułę, aby przesyłać dalej do listy dystrybucyjnej UDW.

Edytuj 2015 02 23

Chociaż powyższe jest technicznie prawdziwe. To nie jest tak proste, jak myślałem. W oknie dialogowym nie ma opcji UDW dla adresów przy przekazywaniu według reguły. Moja wersja to 2010.

Możesz ustawić bcc w regule z opcją uruchomienia skryptu zamiast za pomocą okna dialogowego.

Option Explicit

Sub Forward_BCC_DL(item As Object)

Dim newForward As MailItem
Dim myRecipient As Recipient

If item.Class = olMail Then

    Set newForward = item.Forward

    Set myRecipient = newForward.Recipients.Add("Name of Distribution List with the quotes")
    myRecipient.Type = olBCC

    newForward.Recipients.ResolveAll
    newForward.Display  ' Comment out with a leading apostrophe once tested
    'newForward.Send    ' Remove leading apostrophe once tested

End If

ExitRoutine:
    Set newForward = Nothing
    Set myRecipient = Nothing

End Sub

Private Sub Forward_BCC_DL_Test()
' To test
'  open a message then run this code
Dim curritem As Object
Set curritem = ActiveInspector.currentItem
Forward_BCC_DL curritem
End Sub

Jeśli nie znasz VBA, będzie to pomocne.

Rozpoczęcie pracy z VBA w programie Outlook 2010

Jak korzystać z edytora VBA programu Outlook

Edytuj 2015 02 23 - Koniec

Edytuj 2015 02 24

Prawdopodobnie lepiej jest utworzyć listę dystrybucyjną, jak opisano powyżej, ale spowoduje to powolne pobieranie wszystkich kontaktów.

Option Explicit

Sub Forward_BCC_All(mail As MailItem)

    Dim ContactsFolder As folder
    Dim Contact As Object
    Dim objMail As MailItem
    'Dim j As Long
    Dim objRecip As Recipient

    Set ContactsFolder = Session.GetDefaultFolder(olFolderContacts)

    Set objMail = mail.Forward
    'j = 0

    For Each Contact In ContactsFolder.Items

        'j = j + 1

        With objMail
            'Debug.Print j & ": " & Contact
            Set objRecip = .Recipients.Add(Contact)
            objRecip.Type = olBCC
        End With

    Next

    'Debug.Print "Resolving contacts slowly"

    objMail.Recipients.ResolveAll
    objMail.Display

ExitRoutine:
    Set objMail = Nothing
    Set ContactsFolder = Nothing
    Set Contact = Nothing

End Sub

Private Sub Forward_BCC_All_test()
Dim currItem As MailItem
Set currItem = ActiveInspector.currentItem
Forward_BCC_All currItem
End Sub

Edytuj 2015 02 24 - Koniec