Czy w programie Outlook2010 można wyświetlić aktualnie drzemiące przypomnienia?

Czy w programie Outlook 2010 jest jakiś sposób na pobranie listy elementów, które są obecnie odłożone? Na przykład, powiedzmy, że za dwa tygodnie ustawiłem przypomnienie, aby wyskoczyło w piątek na ważne spotkanie obiadowe w następny poniedziałek (lubię przypominać sobie o poniedziałkowych zadaniach przed weekendem). Kiedy przypomnienie pojawi się w piątek, odkładam je na trzy dni, aby pojawiło się ponownie przed obiadem w poniedziałek. Potem mija poniedziałek, a moja pamięć jest niewyraźna i jestem trochę paranoikiem, że przypadkowo odrzuciłem przypomnienie w piątek zamiast prawidłowo go odkładać. Nadal widzę pierwotne spotkanie w moim kalendarzu, ale muszę się upewnić, że pojawi się przypomnienie, kiedy się tego spodziewam, aby nie przegapić spotkania.

Czy w programie Outlook 2010 jest jakiś sposób, aby pobrać listę przypomnień, które są obecnie odłożone? Byłoby to również pomocne w przypadkach, w których wykonuję zadanie, którego przypomnienie odłożyłem do później, a teraz chcę wyciągnąć odłożone przypomnienie i anulować je.

Sub SnoozedReminders()

' http://www.jpsoftwaretech.com/check-your-outlook-reminders-in-vba/

Dim MyReminder As Outlook.Reminder
Dim MyReminders As Outlook.Reminders
Dim Report As String
Dim i As Long

Set MyReminders = Outlook.Reminders

i = 0

For Each MyReminder In MyReminders

    If HasReminderFired(MyReminder) = True Then
        i = i + 1
        Report = Report & i & ": " & MyReminder.Caption & vbCr & _
            "     Snoozed to " & MyReminder.NextReminderDate & vbCr & vbCr
    End If

Next MyReminder

CreateReportAsEmail "Snoozed Items", Report

End Sub


Function HasReminderFired(rmndr As Outlook.Reminder) As Boolean
    HasReminderFired = (rmndr.OriginalReminderDate <> rmndr.NextReminderDate)
End Function


' VBA SubRoutine which displays a report inside an email
' Programming by Greg Thatcher, http://www.GregThatcher.com

Public Sub CreateReportAsEmail(Title As String, Report As String)

    On Error GoTo On_Error

    Dim Session As Outlook.Namespace
    Dim mail As MailItem
    Dim MyAddress As AddressEntry
    Dim Inbox As Outlook.folder 

    Set Session = Application.Session
    Set Inbox = Session.GetDefaultFolder(olFolderInbox)
    Set mail = Inbox.items.Add("IPM.Mail")

    mail.Subject = Title
    mail.Body = Report

    mail.Save
    mail.Display

Exiting:
    Set Session = Nothing
    Set Inbox = Nothing
    Set mail = Nothing
    Exit Sub

On_Error:
    MsgBox "error=" & Err.Number & " " & Err.Description
    Resume Exiting

End Sub

Jeśli nie znasz VBA, zobacz stronę z objaśnieniami Slipstick . Znajdziesz informacje o:

• ustawienia bezpieczeństwa makr;
• gdzie umieścić kod (Możesz użyć zwykłego modułu z Insert | Module); i
• jak stworzyć przycisk.

Zgodnie z tym postem na forum Wyświetl odłożone elementy nie można wyświetlić listy odłożonych elementów. Post sugeruje, że możesz zobaczyć ograniczoną liczbę pomocnych informacji, tworząc niestandardowy widok, który wyświetla niektóre pola przypomnień.

Spróbuj kliknąć kartę Kalendarz, wybierz Widok i Zmień widok. Następnie wybierz Lista. Wygląda na to, że wyświetla listę wszystkich przypomnień.